public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] repo/gentoo:master commit in: net-p2p/resilio-sync/files/, net-p2p/resilio-sync/
@ 2018-01-25 22:47 Patrice Clement
  0 siblings, 0 replies; 2+ messages in thread
From: Patrice Clement @ 2018-01-25 22:47 UTC (permalink / raw
  To: gentoo-commits

commit:     2099c6f6ad76beffe20bb54a552d57ca528e3eca
Author:     Vladimir Pavljuchenkov (SpiderX) <spiderx <AT> spiderx <DOT> dp <DOT> ua>
AuthorDate: Wed Jul 19 18:35:22 2017 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Thu Jan 25 22:46:40 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2099c6f6

net-p2p/resilio-sync-bin: new package.

Resilio Sync is a proprietary peer-to-peer multiplatform file synchronization
tool It can sync files between devices on a local network, or between remote
devices over the Internet via a modified version of the BitTorrent protocol.

Base for ebuild from https://github.com/SpiderX/portage-overlay/tree/master/net-p2p/resilio-sync.

Closes: https://bugs.gentoo.org/486406
Closes: https://github.com/gentoo/gentoo/pull/6901
Package-Manager: Portage-2.3.6, Repoman-2.3.2

 net-p2p/resilio-sync/Manifest                      |  2 +
 net-p2p/resilio-sync/files/resilio-sync-user.confd | 12 ++++
 net-p2p/resilio-sync/files/resilio-sync-user.initd | 27 ++++++++
 .../resilio-sync/files/resilio-sync-user.service   | 13 ++++
 net-p2p/resilio-sync/files/resilio-sync.confd      | 12 ++++
 net-p2p/resilio-sync/files/resilio-sync.initd      | 18 +++++
 net-p2p/resilio-sync/files/resilio-sync.service    | 17 +++++
 net-p2p/resilio-sync/files/resilio-sync.tmpfile    |  1 +
 net-p2p/resilio-sync/metadata.xml                  | 24 +++++++
 net-p2p/resilio-sync/resilio-sync-2.5.12.ebuild    | 78 ++++++++++++++++++++++
 10 files changed, 204 insertions(+)

diff --git a/net-p2p/resilio-sync/Manifest b/net-p2p/resilio-sync/Manifest
new file mode 100644
index 00000000000..6e35938ad7c
--- /dev/null
+++ b/net-p2p/resilio-sync/Manifest
@@ -0,0 +1,2 @@
+DIST resilio-sync_2.5.12-1_amd64.deb 10467196 BLAKE2B e900ac4e8b3862b29674db09d469013a5d12791c090bfd6ecae8f95af6f8ff2f990b8b9cab176b301b7625d6fcee1fcbe33b497f09bca045497a6765ccbb313c SHA512 4056df3d2cbafdb881f1d2929fca13efd258fb7af2cbdc390eae4820af1f5b2b46d410daf2a1ad1233d105edc46c4d5a8e9259e4557c0695b3392884429d95f9
+DIST resilio-sync_2.5.12-1_i386.deb 10333948 BLAKE2B 7a7a6e2bf8375bf5428c27053c22de98e598de07d8709f870152a8b9e2d7254a954b3ceebad69bebf286ef29b3d44b9955f33c4f396a7831041c34b9bd585dd2 SHA512 c15276bbe8818e30cab254a7b1f1222e3a25912d99a05287441548ea3ee3de8964d23a5aed56fd547ee3369f9943129cf7d3a5bd410ce28a9fbd45e13def56b4

diff --git a/net-p2p/resilio-sync/files/resilio-sync-user.confd b/net-p2p/resilio-sync/files/resilio-sync-user.confd
new file mode 100644
index 00000000000..040da8bdf84
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync-user.confd
@@ -0,0 +1,12 @@
+# Config file for /etc/init.d/resilio-sync
+
+# Various options.
+# run `rslsync --help` for valid cmdline options
+#OPTS="--log /var/log/resilio-sync/resilio-sync.log"
+
+# User and group daemon runs as
+#USER="rslsync"
+#GROUP="rslsync"
+
+# Resilio Sync config file
+#CONFIG="/etc/resilio-sync/config.json"

diff --git a/net-p2p/resilio-sync/files/resilio-sync-user.initd b/net-p2p/resilio-sync/files/resilio-sync-user.initd
new file mode 100644
index 00000000000..efcaa2d7778
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync-user.initd
@@ -0,0 +1,27 @@
+#!/sbin/openrc-run
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+USER="${RC_SVCNAME##*.}"
+command="/usr/bin/rslsync"
+name="Resilio Sync for $USER"
+description="Resilio Sync"
+command_user="${USER:-rslsync}:${GROUP:-rslsync}"
+pidfile="${PIDFILE:-/home/$USER/.config/resilio-sync/resilio-sync.pid}"
+config=${CONFIG:-/home/$USER/.config/resilio-sync/config.json}
+command_args="--config $config ${OPTS}"
+start_stop_daemon_args="-q"
+retry="10"
+
+depend() {
+	need net
+}
+
+start_pre() {
+	if [ "$USER" = "resilio-sync-user" ]; then
+		eerror "You are not supposed to run this script directly."
+		eerror "Create a symlink for this script:"
+		eerror "  ln -s $RC_SVCNAME /etc/init.d/$RC_SVCNAME.<user>"
+		return 1
+	fi
+}

diff --git a/net-p2p/resilio-sync/files/resilio-sync-user.service b/net-p2p/resilio-sync/files/resilio-sync-user.service
new file mode 100644
index 00000000000..6c82440ac67
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync-user.service
@@ -0,0 +1,13 @@
+[Unit]
+Description=Resilio Sync service
+Documentation=http://help.getsync.com/
+After=network.target network-online.target
+
+[Service]
+Type=forking
+Restart=on-failure
+PIDFile=%h/.config/resilio-sync/resilio-sync.pid
+ExecStart=/usr/bin/rslsync --config %h/.config/resilio-sync/config.json
+
+[Install]
+WantedBy=multi-user.target

diff --git a/net-p2p/resilio-sync/files/resilio-sync.confd b/net-p2p/resilio-sync/files/resilio-sync.confd
new file mode 100644
index 00000000000..08c4255fe29
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync.confd
@@ -0,0 +1,12 @@
+# Config file for /etc/init.d/resilio-sync
+
+# Various options.
+# run `rslsync --help` for valid cmdline options
+OPTS="--log /var/log/resilio-sync/resilio-sync.log"
+
+# User and group daemon runs as
+USER="rslsync"
+GROUP="rslsync"
+
+# Resilio Sync config file
+#CONFIG="/etc/resilio-sync/config.json"

diff --git a/net-p2p/resilio-sync/files/resilio-sync.initd b/net-p2p/resilio-sync/files/resilio-sync.initd
new file mode 100644
index 00000000000..b9f0380a773
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync.initd
@@ -0,0 +1,18 @@
+#!/sbin/openrc-run
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+command="/usr/bin/rslsync"
+name="Resilio Sync"
+description="Resilio Sync"
+command_user="${USER:-rslsync}::${GROUP:-rslsync}"
+pidfile="/run/resilio-sync/resilio-sync.pid"
+config=${CONFIG:-/etc/resilio-sync/config.json}
+command_args="--config $config ${OPTS}"
+start_stop_daemon_args="-q"
+retry="10"
+
+depend() {
+	need net
+	provide resilio-sync
+}

diff --git a/net-p2p/resilio-sync/files/resilio-sync.service b/net-p2p/resilio-sync/files/resilio-sync.service
new file mode 100644
index 00000000000..32f24a95aa8
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync.service
@@ -0,0 +1,17 @@
+[Unit]
+Description=Resilio Sync service
+Documentation=http://help.getsync.com/
+After=network.target network-online.target
+
+[Service]
+Type=forking
+User=rslsync
+Group=rslsync
+UMask=0002
+Restart=on-failure
+PermissionsStartOnly=true
+PIDFile=/var/run/resilio-sync/resilio-sync.pid
+ExecStart=/usr/bin/rslsync --config /etc/resilio-sync/config.json
+
+[Install]
+WantedBy=multi-user.target

diff --git a/net-p2p/resilio-sync/files/resilio-sync.tmpfile b/net-p2p/resilio-sync/files/resilio-sync.tmpfile
new file mode 100644
index 00000000000..d0f6e0adc42
--- /dev/null
+++ b/net-p2p/resilio-sync/files/resilio-sync.tmpfile
@@ -0,0 +1 @@
+d	/run/resilio-sync	0755	rslsync	rslsync

diff --git a/net-p2p/resilio-sync/metadata.xml b/net-p2p/resilio-sync/metadata.xml
new file mode 100644
index 00000000000..35827ed4235
--- /dev/null
+++ b/net-p2p/resilio-sync/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>spiderx@spiderx.dp.ua</email>
+		<name>Vladimir Pavljuchenkov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+	Resilio Sync is a proprietary peer-to-peer multiplatform file synchronization tool
+	It can sync files between devices on a local network, or between remote devices
+	over the Internet via a modified version of the BitTorrent protocol.
+	</longdescription>
+	<use>
+		<flag name="pax_kernel">Use paxctl to mark binaries</flag>
+	</use>
+	<upstream>
+		<doc>https://help.getsync.com/</doc>
+		<bugs-to>https://help.getsync.com/hc/en-us/requests/new?ticket_form_id=91563</bugs-to>
+	</upstream>
+</pkgmetadata>

diff --git a/net-p2p/resilio-sync/resilio-sync-2.5.12.ebuild b/net-p2p/resilio-sync/resilio-sync-2.5.12.ebuild
new file mode 100644
index 00000000000..908b87b2209
--- /dev/null
+++ b/net-p2p/resilio-sync/resilio-sync-2.5.12.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+BASE_URI="http://linux-packages.resilio.com/${PN}/deb/pool/non-free/r/${PN}/${PN}_${PV}-1_@arch@.deb"
+
+inherit pax-utils readme.gentoo-r1 systemd tmpfiles unpacker user
+
+NAME="rslsync"
+QA_PREBUILT="usr/bin/${NAME}"
+
+DESCRIPTION="Resilient, fast and scalable file synchronization tool"
+HOMEPAGE="https://getsync.com/"
+SRC_URI="amd64? ( ${BASE_URI/@arch@/amd64} )
+	x86? ( ${BASE_URI/@arch@/i386} )"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pax_kernel"
+RESTRICT="mirror"
+
+S="${WORKDIR}"
+
+DOC_CONTENTS="You may need to review /etc/${PN}/config.json\n
+Default metadata path is /var/lib/${PN}/.sync\n
+Default web-gui URL is http://localhost:8888/\n\n"
+
+pkg_setup() {
+	enewgroup ${NAME}
+	enewuser ${NAME} -1 -1 /var/lib/${PN} ${NAME}
+}
+
+src_unpack() {
+	unpacker_src_unpack
+
+	unpack usr/share/man/man1/${PN}.1.gz
+}
+
+src_install() {
+	dobin usr/bin/${NAME}
+	use pax_kernel && pax-mark m "${ED%/}"/usr/bin/${NAME}
+
+	doman ${PN}.1
+
+	dodir /var/log/${PN}
+	keepdir /etc/${PN} /var/lib/${PN}/ /var/lib/${PN}/.sync
+	fperms 0700 /etc/${PN} /var/lib/${PN} /var/lib/${PN}/.sync /var/log/${PN}
+	fowners -R ${NAME}:${NAME} /etc/${PN} /var/lib/${PN} /var/log/${PN}
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	newinitd "${FILESDIR}"/${PN}-user.initd ${PN}-user
+	newconfd "${FILESDIR}"/${PN}-user.confd ${PN}-user
+	systemd_dounit "${FILESDIR}"/${PN}.service
+	systemd_douserunit "${FILESDIR}"/${PN}-user.service
+	newtmpfiles "${FILESDIR}"/resilio-sync.tmpfile resilio-sync.conf
+
+	readme.gentoo_create_doc
+
+	# Generate sample config
+	"${ED%/}"/usr/bin/${NAME} --dump-sample-config > \
+		"${ED%/}"/etc/${PN}/config.json || die "generate config failed"
+	fowners ${NAME}:${NAME} /etc/${PN}/config.json
+	# Uncomment config directives and change their values
+	sed -i \
+		-e "/storage_path/s|//| |g" \
+		-e "/pid_file/s|//| |g" \
+		-e "/storage_path/s|/home/user/.sync|/var/lib/${PN}/.sync|g" \
+		-e "/pid_file/s|resilio/resilio|${PN}/${PN}|g" \
+		"${ED%/}"/etc/${PN}/config.json || die "sed failed for config.json"
+}
+
+pkg_postinst() {
+	tmpfiles_process resilio-sync.conf
+	readme.gentoo_print_elog
+}


^ permalink raw reply related	[flat|nested] 2+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: net-p2p/resilio-sync/files/, net-p2p/resilio-sync/
@ 2018-10-14 10:48 Michał Górny
  0 siblings, 0 replies; 2+ messages in thread
From: Michał Górny @ 2018-10-14 10:48 UTC (permalink / raw
  To: gentoo-commits

commit:     5ff7b4dd3ec48e960617e39a20a1893690082c4a
Author:     Vladimir Pavljuchenkov (SpiderX) <spiderx <AT> spiderx <DOT> dp <DOT> ua>
AuthorDate: Sun Oct  7 09:12:22 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 14 10:45:21 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ff7b4dd

net-p2p/resilio-sync: version bump to 2.6.1, improve init

Signed-off-by: Vladimir Pavljuchenkov <spiderx <AT> spiderx.dp.ua>
Package-Manager: Portage-2.3.49, Repoman-2.3.11
Closes: https://github.com/gentoo/gentoo/pull/10092
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-p2p/resilio-sync/Manifest                      |  2 +
 net-p2p/resilio-sync/files/resilio-sync-user.initd |  4 +-
 .../resilio-sync/files/resilio-sync-user.service   |  2 +-
 net-p2p/resilio-sync/files/resilio-sync.confd      |  4 +-
 net-p2p/resilio-sync/files/resilio-sync.initd      |  7 +-
 net-p2p/resilio-sync/files/resilio-sync.service    |  8 ++-
 net-p2p/resilio-sync/metadata.xml                  |  4 +-
 net-p2p/resilio-sync/resilio-sync-2.6.1.ebuild     | 74 ++++++++++++++++++++++
 8 files changed, 91 insertions(+), 14 deletions(-)

diff --git a/net-p2p/resilio-sync/Manifest b/net-p2p/resilio-sync/Manifest
index 5f5375975bd..91a4a133ffd 100644
--- a/net-p2p/resilio-sync/Manifest
+++ b/net-p2p/resilio-sync/Manifest
@@ -1,2 +1,4 @@
 DIST resilio-sync_2.5.12-1_amd64.deb 10466894 BLAKE2B d9125bfe49738db3a2cab0d66cad9fed2ae712ee613ccd104bc1d8764bd072b082f71fc0102b15d52f791b592d88ffa4f03892e7e4088e3bf4a847b6c15b4296 SHA512 bafc8dbce182253d585185e5d0a27f0a8ca18f768bba65c348752cc089e0e690c8c1848a71cb1b125c67d2c265cbbf13e98d7c99289b0bb0268d43d3e38454d3
 DIST resilio-sync_2.5.12-1_i386.deb 10334238 BLAKE2B 447baf18db1f6c47a6a2518f9ba6a27b0d9a7092cc41d63958a66be6492cab3868a0ecae9faadfa91cfc5f777e1289cb62017519a0994b93ae448042de9b32d3 SHA512 bb46498070f6aa0e3debee839f50a9292116bd5f9105fe75c65d11f9f3199e6e5b8f828b34b364e7f3cb896bf88fd37a255289c68158df7414acf809e4701b32
+DIST resilio-sync_2.6.1-1_amd64.deb 11576892 BLAKE2B 710bd96b91be84bc7210d8efe0d8954a33be878fc948694e7a1c62e7b53b5ac94133a16b89c4872e18798bc03f3508c7c130d4d56a3480c35d30edff5589ef3a SHA512 a37d73a621a740f57b4f2824cc2a3178f365ccc8180a0e814480dde8d1b74b9d54da4e07bd18c89cc6a93c12b526f8a43e08165d3c2f0fdc913e1f38e46eb183
+DIST resilio-sync_2.6.1-1_i386.deb 11465194 BLAKE2B b56e01f79c5beec6a5ebd09724bebd1ce8c6d44eac694cd7fb89dc44823ccba22531b14e241fdd985ae63e6e0f177021becb593923eac8ac0183629e533ac72d SHA512 84676c3fe5fcee484bcd58c6496aba0d2e3c86c339adb90b8b3cef28ae46d7b6f28c5fd0371a2cfe612ab8b3658eca2b9b2f6cfc9caa70aaff95946942a5c749

diff --git a/net-p2p/resilio-sync/files/resilio-sync-user.initd b/net-p2p/resilio-sync/files/resilio-sync-user.initd
index efcaa2d7778..6772f6dc14d 100644
--- a/net-p2p/resilio-sync/files/resilio-sync-user.initd
+++ b/net-p2p/resilio-sync/files/resilio-sync-user.initd
@@ -1,5 +1,5 @@
 #!/sbin/openrc-run
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 USER="${RC_SVCNAME##*.}"
@@ -8,7 +8,7 @@ name="Resilio Sync for $USER"
 description="Resilio Sync"
 command_user="${USER:-rslsync}:${GROUP:-rslsync}"
 pidfile="${PIDFILE:-/home/$USER/.config/resilio-sync/resilio-sync.pid}"
-config=${CONFIG:-/home/$USER/.config/resilio-sync/config.json}
+config="${CONFIG:-/home/$USER/.config/resilio-sync/config.json}"
 command_args="--config $config ${OPTS}"
 start_stop_daemon_args="-q"
 retry="10"

diff --git a/net-p2p/resilio-sync/files/resilio-sync-user.service b/net-p2p/resilio-sync/files/resilio-sync-user.service
index 6c82440ac67..bb57c738b6d 100644
--- a/net-p2p/resilio-sync/files/resilio-sync-user.service
+++ b/net-p2p/resilio-sync/files/resilio-sync-user.service
@@ -1,6 +1,6 @@
 [Unit]
 Description=Resilio Sync service
-Documentation=http://help.getsync.com/
+Documentation=https://help.resilio.com
 After=network.target network-online.target
 
 [Service]

diff --git a/net-p2p/resilio-sync/files/resilio-sync.confd b/net-p2p/resilio-sync/files/resilio-sync.confd
index 08c4255fe29..7d8e9ea27cf 100644
--- a/net-p2p/resilio-sync/files/resilio-sync.confd
+++ b/net-p2p/resilio-sync/files/resilio-sync.confd
@@ -5,8 +5,8 @@
 OPTS="--log /var/log/resilio-sync/resilio-sync.log"
 
 # User and group daemon runs as
-USER="rslsync"
-GROUP="rslsync"
+RSLSYNC_USER="rslsync"
+RSLSYNC_GROUP="rslsync"
 
 # Resilio Sync config file
 #CONFIG="/etc/resilio-sync/config.json"

diff --git a/net-p2p/resilio-sync/files/resilio-sync.initd b/net-p2p/resilio-sync/files/resilio-sync.initd
index 3e64f108e18..8a7263446a5 100644
--- a/net-p2p/resilio-sync/files/resilio-sync.initd
+++ b/net-p2p/resilio-sync/files/resilio-sync.initd
@@ -1,18 +1,17 @@
 #!/sbin/openrc-run
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 command="/usr/bin/rslsync"
 name="Resilio Sync"
 description="Resilio Sync"
-command_user="${USER:-rslsync}:${GROUP:-rslsync}"
+command_user="${RSLSYNC_USER:-rslsync}:${RSLSYNC_GROUP:-rslsync}"
 pidfile="/run/resilio-sync/resilio-sync.pid"
-config=${CONFIG:-/etc/resilio-sync/config.json}
+config="${CONFIG:-/etc/resilio-sync/config.json}"
 command_args="--config $config ${OPTS}"
 start_stop_daemon_args="-q"
 retry="10"
 
 depend() {
 	need net
-	provide resilio-sync
 }

diff --git a/net-p2p/resilio-sync/files/resilio-sync.service b/net-p2p/resilio-sync/files/resilio-sync.service
index 32f24a95aa8..1f1a0b95bc7 100644
--- a/net-p2p/resilio-sync/files/resilio-sync.service
+++ b/net-p2p/resilio-sync/files/resilio-sync.service
@@ -1,15 +1,17 @@
 [Unit]
 Description=Resilio Sync service
-Documentation=http://help.getsync.com/
+Documentation=https://help.resilio.com
 After=network.target network-online.target
 
 [Service]
 Type=forking
-User=rslsync
-Group=rslsync
 UMask=0002
 Restart=on-failure
 PermissionsStartOnly=true
+
+User=rslsync
+Group=rslsync
+
 PIDFile=/var/run/resilio-sync/resilio-sync.pid
 ExecStart=/usr/bin/rslsync --config /etc/resilio-sync/config.json
 

diff --git a/net-p2p/resilio-sync/metadata.xml b/net-p2p/resilio-sync/metadata.xml
index 35827ed4235..1e9a6697329 100644
--- a/net-p2p/resilio-sync/metadata.xml
+++ b/net-p2p/resilio-sync/metadata.xml
@@ -18,7 +18,7 @@
 		<flag name="pax_kernel">Use paxctl to mark binaries</flag>
 	</use>
 	<upstream>
-		<doc>https://help.getsync.com/</doc>
-		<bugs-to>https://help.getsync.com/hc/en-us/requests/new?ticket_form_id=91563</bugs-to>
+		<doc>https://help.resilio.com/</doc>
+		<bugs-to>https://help.resilio.com/hc/en-us/requests/new?ticket_form_id=91563</bugs-to>
 	</upstream>
 </pkgmetadata>

diff --git a/net-p2p/resilio-sync/resilio-sync-2.6.1.ebuild b/net-p2p/resilio-sync/resilio-sync-2.6.1.ebuild
new file mode 100644
index 00000000000..f4738e0d4d9
--- /dev/null
+++ b/net-p2p/resilio-sync/resilio-sync-2.6.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit pax-utils readme.gentoo-r1 systemd tmpfiles unpacker user
+
+QA_PREBUILT="usr/bin/rslsync"
+BASE_URI="http://linux-packages.resilio.com/${PN}/deb/pool/non-free/r/${PN}/${PN}_${PV}-1_@arch@.deb"
+
+DESCRIPTION="Resilient, fast and scalable file synchronization tool"
+HOMEPAGE="https://resilio.com/"
+SRC_URI="amd64? ( ${BASE_URI/@arch@/amd64} )
+	x86? ( ${BASE_URI/@arch@/i386} )"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pax_kernel"
+RESTRICT="bindist mirror"
+
+S="${WORKDIR}"
+
+DOC_CONTENTS="You may need to review /etc/resilio-sync/config.json\\n
+Default metadata path is /var/lib/resilio-sync/.sync\\n
+Default web-gui URL is http://localhost:8888/\\n\\n"
+
+pkg_setup() {
+	enewgroup rslsync
+	enewuser rslsync -1 -1 /var/lib/resilio-sync rslsync
+}
+
+src_unpack() {
+	unpacker_src_unpack
+
+	unpack usr/share/man/man1/resilio-sync.1.gz
+}
+
+src_install() {
+	dobin usr/bin/rslsync
+	use pax_kernel && pax-mark m "${ED%/}"/usr/bin/rslsync
+
+	doman resilio-sync.1
+
+	newinitd "${FILESDIR}"/resilio-sync.initd resilio-sync
+	newconfd "${FILESDIR}"/resilio-sync.confd resilio-sync
+	newinitd "${FILESDIR}"/resilio-sync-user.initd resilio-sync-user
+	newconfd "${FILESDIR}"/resilio-sync-user.confd resilio-sync-user
+	systemd_dounit "${FILESDIR}"/resilio-sync.service
+	systemd_douserunit "${FILESDIR}"/resilio-sync-user.service
+	newtmpfiles "${FILESDIR}"/resilio-sync.tmpfile resilio-sync.conf
+
+	readme.gentoo_create_doc
+
+	# Generate sample config, uncomment config directives and change values
+	insopts -orslsync -grslsync -m0644
+	insinto /etc/resilio-sync
+	newins - config.json < <("${ED%/}"/usr/bin/rslsync --dump-sample-config | \
+		sed \
+			-e "/storage_path/s|//| |g" \
+			-e "/pid_file/s|//| |g" \
+			-e "/storage_path/s|/home/user/.sync|/var/lib/resilio-sync/.sync|g" \
+			-e "/pid_file/s|resilio/resilio|resilio-sync/resilio-sync|g" \
+			|| die "sed failed for config.json" )
+
+	diropts -orslsync -grslsync -m0700
+	keepdir /etc/resilio-sync /var/lib/resilio-sync/ \
+		/var/lib/resilio-sync/.sync /var/log/resilio-sync
+}
+
+pkg_postinst() {
+	tmpfiles_process resilio-sync.conf
+	readme.gentoo_print_elog
+}


^ permalink raw reply related	[flat|nested] 2+ messages in thread
end of thread, other threads:[~2018-10-14 10:48 UTC | newest]

Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2018-10-14 10:48 [gentoo-commits] repo/gentoo:master commit in: net-p2p/resilio-sync/files/, net-p2p/resilio-sync/ Michał Górny
  -- strict thread matches above, loose matches on Subject: below --
2018-01-25 22:47 Patrice Clement

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox