[gentoo-commits] repo/gentoo:master commit in: app-office/scribus/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     af46709f45c341bda83387568230b9a2ab7eb825
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  6 19:54:55 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Oct  6 20:45:03 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=af46709f

app-office/scribus: Drop 1.5.3-r1

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

 app-office/scribus/Manifest                |   2 -
 app-office/scribus/scribus-1.5.3-r1.ebuild | 250 -----------------------------
 2 files changed, 252 deletions(-)

diff --git a/app-office/scribus/Manifest b/app-office/scribus/Manifest
index cbfcaf580cf..b9ba104e93f 100644
--- a/app-office/scribus/Manifest
+++ b/app-office/scribus/Manifest
@@ -1,4 +1,2 @@
-DIST scribus-1.5.3.patches.tar.xz 5332 BLAKE2B 3e7702da61a0698873175011115d86bc473a4d2d59be4bca894bbde41844029707dda7307f1d07033fde501da03097aed21dcf12991bb978df1156cb6654077a SHA512 aeb8142eca826a3f9cbd25e8e2276a352f24fe65241a2fe737fd26597419ad9a7180b337f77fb6ba6ac83f378b235d38b1eb6fd85d10985d3a1dbd21bbe4773f
-DIST scribus-1.5.3.tar.xz 74222084 BLAKE2B ffb50c728c0669ab8a22c416c143e8dd47c818120247b4cf5a890872857326b53491be99004a344d78ea2cf2b174ae2987ddcddb4cef39a6e95fe1695be45d48 SHA512 487cea685869397bc52acc7be8e8e9f4bad3f594c1f95740207e4d9e26b07461a7fd2a95d5337b38f1b0fa6504a9f6059cca6740c78cc165eab0b779ffdfe980
 DIST scribus-1.5.4-poppler-0.64.0.patch.tar.xz 3020 BLAKE2B 3388efe6498545ffef6604a41b9e697a0cb6cd053c4893f9d64349bb2251400aca7a4f7dd193eb94cf69ca3f4ae1a3ba3ed106127c4fa680f396940d8056e669 SHA512 4577b4b737948a2b41dc0cec90ec95ba260959343e4953929696ceab518a2723a28a891b189caf79435e7fc8f8fc0a1012e7079e890d10549cb2ba426d15b568
 DIST scribus-1.5.4.tar.xz 72832248 BLAKE2B 64797e865ce44fb01f1e29823e3cb46b2b8f1501e8d07e8b265e93a37961582ec4118d0f32d460bc044e32cf7fa6069732f6b9ce60e4dc4b0b42f914b280e637 SHA512 7875ea5f3db5fb116856cf4cf56b4cce2d0b00d9c4820969f52b89e9bf2b36f96eb9e15b368d392be74d4c6d32e971fc28f6ecbf6661fce5e3b9cb61c4d02403

diff --git a/app-office/scribus/scribus-1.5.3-r1.ebuild b/app-office/scribus/scribus-1.5.3-r1.ebuild
deleted file mode 100644
index b962ce4b717..00000000000
--- a/app-office/scribus/scribus-1.5.3-r1.ebuild
+++ /dev/null
@@ -1,250 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="tk?"
-CMAKE_MAKEFILE_GENERATOR=ninja
-
-inherit cmake-utils eutils flag-o-matic gnome2 python-single-r1 xdg-utils
-
-DESCRIPTION="Desktop publishing (DTP) and layout program"
-HOMEPAGE="https://www.scribus.net/"
-SRC_URI="mirror://sourceforge/project/${PN}/${PN}-devel/${PV}/${P}.tar.xz
-https://dev.gentoo.org/~asturm/distfiles/${P}.patches.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~hppa ppc ppc64 x86"
-IUSE="+boost debug examples graphicsmagick hunspell +minimal osg +pdf scripts templates tk"
-
-#a=$((ls resources/translations/scribus.*ts | sed -e 's:\.: :g' | awk '{print $2}'; ls resources/loremipsum/*xml | sed -e 's:\.: :g' -e 's:loremipsum\/: :g'| awk '{print $2}'; ls resources/dicts/hyph*dic | sed -e 's:\.: :g' -e 's:hyph_: :g' | awk '{print $2}'; ls resources/dicts/README_*txt | sed -e 's:_hyph::g' -e 's:\.: :g' -e 's:README_: :g' | awk '{print $2}') | sort | uniq); echo $a
-# Keep this sorted, otherwise eliminating of duplicates below won't work
-IUSE_L10N=" af ar bg br ca ca_ES cs cs_CZ cy cy_GB da da_DK de de_1901 de_CH de_DE el en_AU en_GB en_US eo es es_ES et eu fa_IR fi fi_FI fr gl he he_IL hr hu hu_HU ia id id_ID is is_IS it ja kab kn_IN ko ku la lt lt_LT nb_NO nl nn_NO pl pl_PL pt pt_BR pt_PT ro ro_RO ru ru_RU_0 sa sk sk_SK sl sl_SI so sq sr sv sv_SE te th_TH tr uk uk_UA zh_CN zh_TW"
-
-map_lang() {
-	local lang=${1/_/-}
-	case $1 in
-		# Retain the following, which have a specific subtag
-		de_*|en_*|pt_*|zh_*) ;;
-		# Consider all other xx_XX as duplicates of the generic xx tag
-		*_*) lang=${1%%_*} ;;
-	esac
-	echo ${lang}
-}
-
-prev_l=
-for l in ${IUSE_L10N}; do
-	l=$(map_lang ${l})
-	[[ ${l} != "${prev_l}" ]] && IUSE+=" l10n_${l}"
-	prev_l=${l}
-done
-unset l prev_l
-
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	tk? ( scripts )"
-
-# osg
-# couple of third_party libs bundled
-COMMON_DEPEND="
-	${PYTHON_DEPS}
-	app-text/libmspub
-	app-text/poppler:=
-	dev-libs/hyphen
-	>=dev-libs/icu-58.2:0=
-	dev-libs/librevenge
-	dev-libs/libxml2
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtopengl:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtquickcontrols:5
-	dev-qt/qtwidgets:5
-	dev-qt/qtxml:5
-	media-libs/fontconfig
-	media-libs/freetype:2
-	>=media-libs/harfbuzz-0.9.42:0=[icu]
-	media-libs/lcms:2
-	media-libs/libcdr
-	media-libs/libfreehand
-	media-libs/libpagemaker
-	media-libs/libpng:0=
-	media-libs/libvisio
-	media-libs/tiff:0
-	net-print/cups
-	sys-libs/zlib[minizip]
-	virtual/jpeg:0=
-	>=x11-libs/cairo-1.10.0[X,svg]
-	boost? ( >=dev-libs/boost-1.62:= )
-	hunspell? ( app-text/hunspell )
-	graphicsmagick? ( media-gfx/graphicsmagick )
-	osg? ( dev-games/openscenegraph )
-	pdf? ( app-text/podofo:0= )
-	scripts? ( dev-python/pillow[tk?,${PYTHON_USEDEP}] )
-	tk? ( dev-python/pillow[tk?,${PYTHON_USEDEP}] )
-"
-RDEPEND="${COMMON_DEPEND}
-	app-text/ghostscript-gpl"
-DEPEND="${COMMON_DEPEND}
-	dev-qt/linguist-tools:5
-	virtual/pkgconfig"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-docdir.patch
-	"${FILESDIR}"/${P}-fpic.patch
-	"${WORKDIR}"/${P}-cmake-openssl.patch
-	"${WORKDIR}"/${P}-poppler-0.58.patch
-	"${WORKDIR}"/${P}-x86-fpic.patch
-	"${WORKDIR}"/${P}-qt-5.11.patch
-)
-
-src_prepare() {
-	rm -r codegen/cheetah || die
-	cat > cmake/modules/FindZLIB.cmake <<- EOF || die
-	find_package(PkgConfig)
-	pkg_check_modules(ZLIB minizip zlib)
-	SET( ZLIB_LIBRARY \${ZLIB_LIBRARIES} )
-	SET( ZLIB_INCLUDE_DIR \${ZLIB_INCLUDE_DIRS} )
-	MARK_AS_ADVANCED( ZLIB_LIBRARY ZLIB_INCLUDE_DIR )
-	EOF
-
-	sed \
-		-e "/^\s*unzip\.[ch]/d" \
-		-e "/^\s*ioapi\.[ch]/d" \
-		-i scribus/CMakeLists.txt Scribus.pro || die
-	rm scribus/ioapi.[ch] || die
-
-	sed \
-		-e 's:\(${CMAKE_INSTALL_PREFIX}\):./\1:g' \
-		-i resources/templates/CMakeLists.txt || die
-
-	edos2unix scribus/ui/propertiespalette_utils.cpp
-
-	cmake-utils_src_prepare
-}
-
-src_configure() {
-	# bug #550818
-	append-cppflags -DHAVE_MEMRCHR
-
-	local _lang lang langs
-	for _lang in ${IUSE_L10N}; do
-		lang=$(map_lang ${_lang})
-		if use l10n_${lang}; then
-			# From the CMakeLists.txt
-			# "#Bit of a hack, preprocess all the filenames to generate our language string, needed for -DWANT_GUI_LANG=en_GB;de_DE , etc"
-			langs+=";${_lang}"
-		else
-			# Don't install localized documentation
-			sed -e "/${_lang}/d" -i doc/CMakeLists.txt || die
-			safe_delete \
-				./resources/dicts/README_${_lang}.txt \
-				./resources/dicts/README_hyph_${_lang}.txt \
-				./resources/dicts/hyph_${_lang}.dic \
-				./resources/loremipsum/${_lang}.xml
-		fi
-		sed -e "/en_EN/d" -i doc/CMakeLists.txt || die
-		safe_delete \
-			./resources/dicts/README_en_EN.txt \
-			./resources/dicts/README_hyph_en_EN.txt \
-			./resources/dicts/hyph_en_EN.dic \
-			./resources/loremipsum/en_EN.xml
-	done
-
-	local mycmakeargs=(
-		-DHAVE_PYTHON=ON
-		-DPYTHON_INCLUDE_PATH="$(python_get_includedir)"
-		-DPYTHON_LIBRARY="$(python_get_library_path)"
-		-DWANT_DISTROBUILD=ON
-		-DDOCDIR="${EPREFIX%/}/usr/share/doc/${PF}/"
-		-DWANT_GUI_LANG="${langs#;};en"
-		-DWANT_CPP11=ON
-		-DWITH_PODOFO="$(usex pdf)"
-		-DWITH_BOOST="$(usex boost)"
-		-DWANT_GRAPHICSMAGICK="$(usex graphicsmagick)"
-		-DWANT_NOOSG="$(usex !osg)"
-		-DWANT_DEBUG="$(usex debug)"
-		-DWANT_HEADERINSTALL="$(usex !minimal)"
-		-DWANT_HUNSPELL="$(usex hunspell)"
-		-DWANT_NOEXAMPLES="$(usex !examples)"
-		-DWANT_NOTEMPLATES="$(usex !templates)"
-		)
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	local lang _lang
-	# en_EN can be deleted always
-	for _lang in ${IUSE_L10N}; do
-		lang=$(map_lang ${_lang})
-		if ! use l10n_${lang}; then
-			safe_delete "${ED%/}"/usr/share/man/${_lang}
-		fi
-	done
-
-	if ! use scripts; then
-		rm "${ED%/}"/usr/share/scribus/scripts/*.py || die
-	elif ! use tk; then
-		rm "${ED%/}"/usr/share/scribus/scripts/{FontSample,CalendarWizard}.py || die
-	fi
-
-	use scripts && \
-		python_fix_shebang "${ED%/}"/usr/share/scribus/scripts && \
-		python_optimize "${ED%/}"/usr/share/scribus/scripts
-
-	mv "${ED%/}"/usr/share/doc/${PF}/{en,html} || die
-	ln -sf html "${ED%/}"/usr/share/doc/${PF}/en || die
-	cat >> "${T}"/COPYING <<- EOF || die
-	${PN} is licensed under the "${LICENSE}".
-	Please visit https://www.gnu.org/licenses/gpl-2.0.html for the complete license text.
-	EOF
-	dodoc "${T}"/COPYING
-	docompress -x /usr/share/doc/${PF}/en /usr/share/doc/${PF}/{AUTHORS,TRANSLATION,LINKS,COPYING}
-	local size
-	for size in 16 32 128 256; do
-		newicon -s $size resources/iconsets/artwork/icon_${size}x${size}.png scribus.png
-	done
-	newicon -s 64 resources/iconsets/artwork/icon_32x32@2x.png scribus.png
-	doicon resources/iconsets/*/scribus.png
-	domenu scribus.desktop
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-	gnome2_icon_cache_update
-}
-
-safe_delete () {
-	local x
-	for x in ${@}; do
-		if [[ -d "${x}" ]]; then
-			ebegin "Deleting ${x} recursively"
-			rm -r "${x}" || die
-			eend $?
-		elif [[ -f "${x}" ]]; then
-			ebegin "Deleting ${x}"
-			rm "${x}" || die
-			eend $?
-		fi
-	done
-}