public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: app-admin/ulogd/
Date: Fri,  5 Oct 2018 21:39:57 +0000 (UTC)	[thread overview]
Message-ID: <1538775569.16845911f3f2ff7bac82f3a11847b46a71a79b77.asturm@gentoo> (raw)

commit:     16845911f3f2ff7bac82f3a11847b46a71a79b77
Author:     Ilya Tumaykin <itumaykin <AT> gmail <DOT> com>
AuthorDate: Thu Oct  4 19:32:45 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Oct  5 21:39:29 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=16845911

app-admin/ulogd: remove old

Signed-off-by: Ilya Tumaykin <itumaykin <AT> gmail.com>
Package-Manager: Portage-2.3.50, Repoman-2.3.11
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-admin/ulogd/ulogd-2.0.7.ebuild | 137 -------------------------------------
 1 file changed, 137 deletions(-)

diff --git a/app-admin/ulogd/ulogd-2.0.7.ebuild b/app-admin/ulogd/ulogd-2.0.7.ebuild
deleted file mode 100644
index a95d6739b24..00000000000
--- a/app-admin/ulogd/ulogd-2.0.7.ebuild
+++ /dev/null
@@ -1,137 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit flag-o-matic linux-info ltprune readme.gentoo-r1 systemd user
-
-DESCRIPTION="A userspace logging daemon for netfilter/iptables related logging"
-HOMEPAGE="https://netfilter.org/projects/ulogd/index.html"
-SRC_URI="https://www.netfilter.org/projects/ulogd/files/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~ia64 ppc x86"
-IUSE="dbi doc json mysql nfacct +nfct +nflog pcap postgres selinux sqlite ulog"
-
-COMMON_DEPEND="
-	|| ( net-firewall/iptables net-firewall/nftables )
-	>=net-libs/libnfnetlink-1.0.1
-	dbi? ( dev-db/libdbi )
-	json? ( dev-libs/jansson )
-	nfacct? (
-		>=net-libs/libmnl-1.0.3
-		>=net-libs/libnetfilter_acct-1.0.1
-	)
-	nfct? ( >=net-libs/libnetfilter_conntrack-1.0.2 )
-	nflog? ( >=net-libs/libnetfilter_log-1.0.0 )
-	mysql? ( virtual/mysql )
-	pcap? ( net-libs/libpcap )
-	postgres? ( dev-db/postgresql:= )
-	sqlite? ( dev-db/sqlite:3 )
-"
-DEPEND="${COMMON_DEPEND}
-	doc? (
-		app-text/linuxdoc-tools
-		app-text/texlive-core
-		dev-texlive/texlive-fontsrecommended
-		virtual/latex-base
-	)
-"
-RDEPEND="${COMMON_DEPEND}
-	selinux? ( sec-policy/selinux-ulogd )
-"
-
-DISABLE_AUTOFORMATTING=1
-DOC_CONTENTS="
-You must have at least one logging stack enabled to make ulogd work.
-Please edit the example configuration located at '${EPREFIX}/etc/ulogd.conf'.
-"
-
-pkg_setup() {
-	linux-info_pkg_setup
-
-	if use nfacct && kernel_is lt 3 3 0; then
-		ewarn "NFACCT input plugin requires a kernel >= 3.3."
-	fi
-
-	if use ulog && kernel_is ge 3 17 0; then
-		ewarn "ULOG target has been removed in the 3.17 kernel release."
-		ewarn "Consider enabling NFACCT, NFCT, or NFLOG support instead."
-	fi
-
-	enewgroup ulogd
-	enewuser ulogd -1 -1 /var/log/ulogd ulogd
-}
-
-src_prepare() {
-	default_src_prepare
-
-	# Change default settings to:
-	# - keep log files in /var/log/ulogd instead of /var/log;
-	# - create sockets in /run instead of /tmp.
-	sed -i \
-		-e "s|var/log|var/log/${PN}|g" \
-		-e 's|tmp|run|g' \
-		ulogd.conf.in || die
-}
-
-src_configure() {
-	append-lfs-flags
-	local myeconfargs=(
-		$(use_with dbi)
-		$(use_with json jansson)
-		$(use_enable nfacct)
-		$(use_enable nfct)
-		$(use_enable nflog)
-		$(use_with mysql)
-		$(use_with pcap)
-		$(use_with postgres pgsql)
-		$(use_with sqlite)
-		$(use_enable ulog)
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_compile() {
-	default_src_compile
-
-	if use doc; then
-		# Prevent access violations from bitmap font files generation.
-		export VARTEXFONTS="${T}/fonts"
-		emake -C doc
-	fi
-}
-
-src_install() {
-	use doc && HTML_DOCS=( doc/${PN}.html )
-
-	default_src_install
-	prune_libtool_files --modules
-	readme.gentoo_create_doc
-
-	doman ${PN}.8
-
-	use doc && dodoc doc/${PN}.{dvi,ps,txt}
-	use mysql && dodoc doc/mysql-*.sql
-	use postgres && dodoc doc/pgsql-*.sql
-	use sqlite && dodoc doc/sqlite3.table
-
-	insinto /etc
-	doins ${PN}.conf
-	fowners root:ulogd /etc/${PN}.conf
-	fperms 640 /etc/${PN}.conf
-
-	newinitd "${FILESDIR}/${PN}.init" ${PN}
-	systemd_dounit "${FILESDIR}/${PN}.service"
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}/${PN}.logrotate" ${PN}
-
-	diropts -o ulogd -g ulogd
-	keepdir /var/log/ulogd
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-}


             reply	other threads:[~2018-10-05 21:40 UTC|newest]

Thread overview: 47+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2018-10-05 21:39 Andreas Sturmlechner [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-07-18 14:46 [gentoo-commits] repo/gentoo:master commit in: app-admin/ulogd/ Petr Vaněk
2025-05-20 14:16 Sam James
2022-11-04  0:07 Sam James
2022-11-03  6:15 Sam James
2021-09-25 19:08 Sam James
2021-05-03 20:59 Andreas Sturmlechner
2021-04-26 19:22 Sam James
2021-04-26 19:15 Sam James
2021-04-26 19:11 Sam James
2021-03-26 15:55 Sam James
2021-03-26 15:55 Sam James
2018-10-05 21:39 Andreas Sturmlechner
2018-07-28  8:53 Michał Górny
2018-06-27 21:54 Sergei Trofimovich
2018-06-25 23:20 Thomas Deutschmann
2018-06-25  9:53 Jason Zaman
2018-04-30  0:02 Anthony G. Basile
2017-01-04 17:46 David Seifert
2017-01-02  9:59 Patrice Clement
2016-12-21 10:30 Thomas Deutschmann
2016-12-21  9:57 Tobias Klausmann
2016-10-18 12:31 Patrice Clement
2016-10-18 12:31 Patrice Clement
2016-08-30 16:29 Patrice Clement
2016-08-30 16:29 Patrice Clement
2016-06-27  0:52 Göktürk Yüksek
2016-06-27  0:52 Göktürk Yüksek
2016-06-27  0:52 Göktürk Yüksek
2016-05-09 12:22 Ian Delaney
2016-04-16  8:40 Patrice Clement
2016-04-04  9:00 Ian Delaney
2016-03-10  8:12 Patrice Clement
2016-03-05 11:39 Patrice Clement
2016-01-23 17:50 Patrice Clement
2015-12-26 10:36 Agostino Sarubbo
2015-12-25 15:13 Agostino Sarubbo
2015-11-26 10:07 Patrice Clement
2015-11-23 15:18 Patrice Clement
2015-11-06  7:21 Michał Górny
2015-10-31  9:36 Ian Delaney
2015-09-28  7:55 Patrice Clement
2015-09-27 18:10 Patrice Clement
2015-09-27 18:10 Patrice Clement
2015-09-25 14:13 Agostino Sarubbo
2015-09-24 10:36 Agostino Sarubbo
2015-09-09 22:56 Manuel Rüger

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1538775569.16845911f3f2ff7bac82f3a11847b46a71a79b77.asturm@gentoo \
    --to=asturm@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox