[gentoo-commits] repo/gentoo:master commit in: dev-python/jeepney/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     7e73ae48bc3c28b105a5f4b7a720c12e5598da2b
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  3 22:29:08 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Sep  5 13:30:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e73ae48

dev-python/jeepney: new pkg, required by dev-python/secretstorage

Package-Manager: Portage-2.3.48, Repoman-2.3.10

 dev-python/jeepney/Manifest             |  1 +
 dev-python/jeepney/jeepney-0.3.1.ebuild | 49 +++++++++++++++++++++++++++++++++
 dev-python/jeepney/metadata.xml         | 13 +++++++++
 3 files changed, 63 insertions(+)

diff --git a/dev-python/jeepney/Manifest b/dev-python/jeepney/Manifest
new file mode 100644
index 00000000000..dba5fd54f6b
--- /dev/null
+++ b/dev-python/jeepney/Manifest
@@ -0,0 +1 @@
+DIST jeepney-0.3.1.tar.gz 22271 BLAKE2B a8de58e4ef4c4d1874c8995e3726a4bfa26a8db4a63040658c4edfd1742fa1c22de52d8cbee4913b1973279938544481fe2c2aef3138dc0ef724f7a99a39c617 SHA512 ad1a2d220a7626a3bdadf6fba6a591d1b498a9f6bb34607860213efddf49bbe67a4dc2d504decd906c560c519302f1fa45b85ba348156e8bec288f525d502e82

diff --git a/dev-python/jeepney/jeepney-0.3.1.ebuild b/dev-python/jeepney/jeepney-0.3.1.ebuild
new file mode 100644
index 00000000000..0f8244e3940
--- /dev/null
+++ b/dev-python/jeepney/jeepney-0.3.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Python 3.4 and older aren't supported
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, pure Python DBus protocol wrapper"
+HOMEPAGE="https://gitlab.com/takluyver/jeepney"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	pytest -vv || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}

diff --git a/dev-python/jeepney/metadata.xml b/dev-python/jeepney/metadata.xml
new file mode 100644
index 00000000000..8e28a357224
--- /dev/null
+++ b/dev-python/jeepney/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">jeepney</remote-id>
+		<remote-id type="gitlab">takluyver/jeepney</remote-id>
+		<bugs-to>https://gitlab.com/takluyver/jeepney/issues</bugs-to>
+	</upstream>
+</pkgmetadata>