[gentoo-commits] repo/gentoo:master commit in: net-libs/farstream/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     c5ef5cc9fe706c9811291f2c36448bc7b7c01a06
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 22 19:03:06 2018 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Aug 22 19:20:00 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5ef5cc9

net-libs/farstream: add missing gst-plugins-srtp runtime dep

Closes: https://bugs.gentoo.org/664174
Package-Manager: Portage-2.3.48, Repoman-2.3.10

 net-libs/farstream/farstream-0.2.8-r2.ebuild | 65 ++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/net-libs/farstream/farstream-0.2.8-r2.ebuild b/net-libs/farstream/farstream-0.2.8-r2.ebuild
new file mode 100644
index 00000000000..e199f1c8e30
--- /dev/null
+++ b/net-libs/farstream/farstream-0.2.8-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1
+
+DESCRIPTION="Audio/video conferencing framework specifically designed for instant messengers"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/Farstream"
+SRC_URI="https://freedesktop.org/software/farstream/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+introspection test upnp"
+SLOT="0.2/5" # .so version
+
+# Tests need shmsink from gst-plugins-bad, which isn't packaged
+# FIXME: do an out-of-tree build for tests if USE=-msn
+RESTRICT="test"
+
+COMMONDEPEND="
+	>=media-libs/gstreamer-1.4:1.0
+	>=media-libs/gst-plugins-base-1.4:1.0
+	>=dev-libs/glib-2.32:2
+	>=net-libs/libnice-0.1.8
+	introspection? ( >=dev-libs/gobject-introspection-0.10.11:= )
+	upnp? ( >=net-libs/gupnp-igd-0.2:= )
+"
+RDEPEND="${COMMONDEPEND}
+	>=media-libs/gst-plugins-bad-1.4:1.0
+	>=media-libs/gst-plugins-good-1.4:1.0
+	media-plugins/gst-plugins-srtp:1.0
+	media-plugins/gst-plugins-libnice:1.0
+"
+DEPEND="${COMMONDEPEND}
+	${PYTHON_DEPS}
+	>=dev-util/gtk-doc-am-1.18
+	virtual/pkgconfig
+	test? (
+		media-libs/gst-plugins-base:1.0[vorbis]
+		media-libs/gst-plugins-good:1.0 )
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	plugins="fsrawconference,fsrtpconference,fsmsnconference,fsrtpxdata,fsfunnel,fsrtcpfilter,fsvideoanyrate"
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable upnp gupnp) \
+		--with-plugins=${plugins}
+}
+
+src_compile() {
+	# Prevent sandbox violations, bug #539224
+	# https://bugzilla.gnome.org/show_bug.cgi?id=744135
+	# https://bugzilla.gnome.org/show_bug.cgi?id=744134
+	addpredict /dev
+	gnome2_src_compile
+}