[gentoo-commits] repo/gentoo:master commit in: www-client/dillo/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     9855ea9b17a8da478897a5b515946b3667560b31
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 19 17:53:06 2018 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Aug 19 17:54:44 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9855ea9b

www-client/dillo: Add live ebuild.

Package-Manager: Portage-2.3.47, Repoman-2.3.10

 www-client/dillo/dillo-9999.ebuild | 69 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/www-client/dillo/dillo-9999.ebuild b/www-client/dillo/dillo-9999.ebuild
new file mode 100644
index 00000000000..0d478f4ab15
--- /dev/null
+++ b/www-client/dillo/dillo-9999.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils mercurial multilib toolchain-funcs
+
+DESCRIPTION="Lean FLTK based web browser"
+HOMEPAGE="https://www.dillo.org/"
+SRC_URI="mirror://gentoo/${PN}.png"
+EHG_REPO_URI="https://hg.dillo.org/dillo"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc +gif ipv6 +jpeg +png ssl"
+
+RDEPEND="
+	>=x11-libs/fltk-1.3
+	sys-libs/zlib
+	jpeg? ( virtual/jpeg:0 )
+	png? ( >=media-libs/libpng-1.2:0 )
+	ssl? ( net-libs/mbedtls )
+"
+DEPEND="
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}2-inbuf.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf  \
+		$(use_enable gif) \
+		$(use_enable ipv6) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable ssl) \
+		--docdir="/usr/share/doc/${PF}"
+}
+
+src_compile() {
+	emake AR=$(tc-getAR)
+	if use doc; then
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	dodir /etc
+	default
+
+	use doc && dohtml html/*
+	dodoc AUTHORS ChangeLog README NEWS
+	dodoc doc/*.txt doc/README
+
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} Dillo
+}
+
+pkg_postinst() {
+	elog "Dillo has installed a default configuration into /etc/dillo/dillorc"
+	elog "You can copy this to ~/.dillo/ and customize it"
+}