[gentoo-commits] repo/gentoo:master commit in: media-video/dvbackup/

[gentoo-commits] repo/gentoo:master commit in: media-video/dvbackup/

[Mikle Kolyada]

commit:     feac73e9b606720175885e4fc8e240cdf16f17dd
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 26 19:30:11 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Thu Jul 26 19:30:27 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=feac73e9

media-video/dvbackup: Drop old

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 media-video/dvbackup/dvbackup-0.0.4-r1.ebuild | 52 ---------------------------
 1 file changed, 52 deletions(-)

diff --git a/media-video/dvbackup/dvbackup-0.0.4-r1.ebuild b/media-video/dvbackup/dvbackup-0.0.4-r1.ebuild
deleted file mode 100644
index dabe40404d6..00000000000
--- a/media-video/dvbackup/dvbackup-0.0.4-r1.ebuild
+++ /dev/null
@@ -1,52 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="2"
-
-inherit eutils
-
-DESCRIPTION="A small utility for creating backups on DV tapes"
-HOMEPAGE="http://dvbackup.sourceforge.net/"
-SRC_URI="mirror://sourceforge/dvbackup/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE=""
-
-DEPEND="sys-libs/glibc
-	dev-libs/popt
-	sys-libs/zlib"
-
-RDEPEND="${DEPEND}
-	media-libs/libdv"
-
-src_prepare() {
-	local i
-
-	epatch "${FILESDIR}/${P}-gcc4.diff"
-
-	# fix Makefile to respect $LDFLAGS
-	sed -i -e 's:gcc \$(CFLAGS):\$(CC) \$(CFLAGS) \$(LDFLAGS):g' \
-		-e 's:^\(CFLAGS=\):#\1:g' Makefile
-
-	# convert LATIN1 docs to UTF-8
-	for i in ChangeLog ReleaseNotes; do
-		if [ -f "${i}" ]; then
-			echo ">>> Converting ${i} to UTF-8"
-			iconv -f LATIN1 -t UTF8 -o "${i}~" "${i}" && mv -f "${i}~" "${i}" || rm -f "${i}~"
-		fi
-	done
-}
-
-src_compile() {
-	emake dvbackup || die "emake failed"
-}
-
-src_install() {
-	dobin dvbackup
-	insinto /usr/share/${PN}
-	doins underrun-ntsc.dv underrun-pal.dv
-	dodoc AUTHORS ChangeLog ReleaseNotes
-	dohtml dvbackup.html
-}

[gentoo-commits] repo/gentoo:master commit in: media-video/dvbackup/

[Mikle Kolyada]

commit:     d811ce8fb18c2065687b305f252d54f06aac2bd6
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 26 19:29:42 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Thu Jul 26 19:30:26 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d811ce8f

media-video/dvbackup: revision bump (EAPI=7)

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 media-video/dvbackup/dvbackup-0.0.4-r2.ebuild | 53 +++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/media-video/dvbackup/dvbackup-0.0.4-r2.ebuild b/media-video/dvbackup/dvbackup-0.0.4-r2.ebuild
new file mode 100644
index 00000000000..a053819d163
--- /dev/null
+++ b/media-video/dvbackup/dvbackup-0.0.4-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A small utility for creating backups on DV tapes"
+HOMEPAGE="http://dvbackup.sourceforge.net/"
+SRC_URI="mirror://sourceforge/dvbackup/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="sys-libs/glibc
+	dev-libs/popt
+	sys-libs/zlib"
+
+RDEPEND="${DEPEND}
+	media-libs/libdv"
+
+src_prepare() {
+	default
+
+	local i
+
+	eapply "${FILESDIR}/${P}-gcc4.diff"
+
+	# fix Makefile to respect $LDFLAGS
+	sed -i -e 's:gcc \$(CFLAGS):\$(CC) \$(CFLAGS) \$(LDFLAGS):g' \
+		-e 's:^\(CFLAGS=\):#\1:g' Makefile || die "sed failed"
+
+	# convert LATIN1 docs to UTF-8
+	for i in ChangeLog ReleaseNotes; do
+		if [ -f "${i}" ]; then
+			echo ">>> Converting ${i} to UTF-8"
+			iconv -f LATIN1 -t UTF8 -o "${i}~" "${i}" && mv -f "${i}~" "${i}" || rm -f "${i}~"
+		fi
+	done
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" dvbackup
+}
+
+src_install() {
+	dobin dvbackup
+	insinto /usr/share/${PN}
+	doins underrun-ntsc.dv underrun-pal.dv
+	dodoc AUTHORS dvbackup.html ChangeLog ReleaseNotes
+}