[gentoo-commits] repo/gentoo:master commit in: sys-process/psmisc/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     fbc71b8200b4e63a54e904ffd7555b5babf18024
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 11 19:14:03 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Jun 11 19:15:01 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fbc71b82

sys-process/psmisc: EAPI-6 revbump.

Package-Manager: Portage-2.3.40, Repoman-2.3.9

 sys-process/psmisc/psmisc-23.1-r1.ebuild | 51 ++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/sys-process/psmisc/psmisc-23.1-r1.ebuild b/sys-process/psmisc/psmisc-23.1-r1.ebuild
new file mode 100644
index 00000000000..87dc7a307bc
--- /dev/null
+++ b/sys-process/psmisc/psmisc-23.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="A set of tools that use the proc filesystem"
+HOMEPAGE="http://psmisc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="ipv6 nls selinux X"
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7:0=
+	nls? ( virtual/libintl )
+	selinux? ( sys-libs/libselinux )"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2.2.6b
+	nls? ( sys-devel/gettext )"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable selinux)
+		--disable-harden-flags
+		$(use_enable ipv6)
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# peekfd is a fragile crap hack #330631
+	nonfatal emake -C src peekfd || touch src/peekfd{.o,}
+	emake
+}
+
+src_install() {
+	default
+
+	use X || rm -f "${ED%/}"/usr/bin/pstree.x11
+
+	[[ -s ${ED%/}/usr/bin/peekfd ]] || rm -f "${ED%/}"/usr/bin/peekfd
+	[[ -e ${ED%/}/usr/bin/peekfd ]] || rm -f "${ED%/}"/usr/share/man/man1/peekfd.1
+
+	# fuser is needed by init.d scripts; use * wildcard for #458250
+	dodir /bin
+	mv "${ED%/}"/usr/bin/*fuser "${ED%/}"/bin || die
+}