[gentoo-commits] repo/gentoo:master commit in: dev-python/guessit/

["Michał Górny" <mgorny@gentoo.org>]

commit:     556adb027e9fa1f28ff9079209e0e0e2548374a8
Author:     Ilya Tumaykin <itumaykin <AT> gmail <DOT> com>
AuthorDate: Thu May 31 17:34:24 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun  7 10:53:49 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=556adb02

dev-python/guessit: verbump to 3.0.0

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/8653

 dev-python/guessit/Manifest             |  1 +
 dev-python/guessit/guessit-3.0.0.ebuild | 47 +++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-python/guessit/Manifest b/dev-python/guessit/Manifest
index 1aa3e484697..f6ce6d2ea48 100644
--- a/dev-python/guessit/Manifest
+++ b/dev-python/guessit/Manifest
@@ -1 +1,2 @@
 DIST guessit-2.1.4.tar.gz 102907 BLAKE2B 3b3652f331498bbb365debf18c74f789b5c9e9c1f711481b0a392c73e9fbfa6628ec58f45ae482ee74cbd4c3d26662f2f1776d9b5fe19f35dec02e438c8b0901 SHA512 c6465c32a68d40698b75addb343d765e47b867dd7f9b8c912f70532a9e9ca54d0e40f70a393880347eea64535a65df5f79d83ea99dc996cd126ba91ca130a879
+DIST guessit-3.0.0.tar.gz 133379 BLAKE2B c9d7c2def91dc301944b951bfa32810b9efd2348fa9a016015dd75c03b407bf3e17cc5cb93baa1d4cc5b6fcb76790972f2bf7c14af2c0cad419f6a98bdda3d6c SHA512 87f19dc1c6b4f46fa1f2682f7c3bab91cf094df06904b8d9771159f346612b9d0adef4aef55315dd00d07787319d17008e936b125941abba5b869df6a91cb1c6

diff --git a/dev-python/guessit/guessit-3.0.0.ebuild b/dev-python/guessit/guessit-3.0.0.ebuild
new file mode 100644
index 00000000000..a0c510a842e
--- /dev/null
+++ b/dev-python/guessit/guessit-3.0.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for guessing information from video filenames"
+HOMEPAGE="https://github.com/guessit-io/guessit https://pypi.org/project/guessit/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/babelfish-0.5.5[${PYTHON_USEDEP}]
+	>=dev-python/rebulk-0.9.0[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/pytest-3.4[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Disable benchmarks as they require unavailable pytest-benchmark.
+	rm guessit/test/test_benchmark.py || die
+	sed -i -e "s|'pytest-benchmark',||g" setup.py || die
+
+	# Disable unconditional dependency on dev-python/pytest-runner.
+	sed -i -e "s|'pytest-runner'||g" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}