From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1018462-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 20BC11382C5
for <garchives@archives.gentoo.org>; Wed, 18 Apr 2018 18:37:54 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 2A18AE01B5;
Wed, 18 Apr 2018 18:37:53 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id EA5D8E01B5
for <gentoo-commits@lists.gentoo.org>; Wed, 18 Apr 2018 18:37:52 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 9D504335C63
for <gentoo-commits@lists.gentoo.org>; Wed, 18 Apr 2018 18:37:51 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 179AD28F
for <gentoo-commits@lists.gentoo.org>; Wed, 18 Apr 2018 18:37:50 +0000 (UTC)
From: "Pacho Ramos" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Pacho Ramos" <pacho@gentoo.org>
Message-ID: <1524076663.2f41b98bf35616593158798ceebe50c37d9735cf.pacho@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/libsdl2/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/libsdl2/libsdl2-2.0.8-r1.ebuild
X-VCS-Directories: media-libs/libsdl2/
X-VCS-Committer: pacho
X-VCS-Committer-Name: Pacho Ramos
X-VCS-Revision: 2f41b98bf35616593158798ceebe50c37d9735cf
X-VCS-Branch: master
Date: Wed, 18 Apr 2018 18:37:50 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 1a8bc28a-ec71-4af1-abf3-738561a7134e
X-Archives-Hash: 2b6138fdf19df91e0d91ec5568e57971
commit: 2f41b98bf35616593158798ceebe50c37d9735cf
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 18 18:34:43 2018 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Wed Apr 18 18:37:43 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f41b98b
media-libs/libsdl2: Fix multiple dependency issues
- libsamplerate was automagic (#642474 by ulm)
- DirectFB is going to die (#606194)
- libXt is not always needed (#590222 by Rafał Mużyło)
Package-Manager: Portage-2.3.28, Repoman-2.3.9
media-libs/libsdl2/libsdl2-2.0.8-r1.ebuild | 169 +++++++++++++++++++++++++++++
1 file changed, 169 insertions(+)
diff --git a/media-libs/libsdl2/libsdl2-2.0.8-r1.ebuild b/media-libs/libsdl2/libsdl2-2.0.8-r1.ebuild
new file mode 100644
index 00000000000..5424e85e492
--- /dev/null
+++ b/media-libs/libsdl2/libsdl2-2.0.8-r1.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic ltprune toolchain-funcs multilib-minimal
+
+MY_P="SDL2-${PV}"
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="http://www.libsdl.org"
+SRC_URI="http://www.libsdl.org/release/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="cpu_flags_x86_3dnow alsa altivec custom-cflags dbus gles haptic libsamplerate +joystick cpu_flags_x86_mmx nas opengl oss pulseaudio +sound cpu_flags_x86_sse cpu_flags_x86_sse2 static-libs +threads tslib udev +video wayland X xinerama xscreensaver"
+REQUIRED_USE="
+ alsa? ( sound )
+ gles? ( video )
+ nas? ( sound )
+ opengl? ( video )
+ pulseaudio? ( sound )
+ wayland? ( gles )
+ xinerama? ( X )
+ xscreensaver? ( X )"
+
+RDEPEND="
+ alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+ dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+ gles? ( >=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},gles2] )
+ libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+ nas? (
+ >=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
+ >=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}] )
+ opengl? (
+ >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+ >=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+ )
+ pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
+ tslib? ( >=x11-libs/tslib-1.0-r3[${MULTILIB_USEDEP}] )
+ udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+ wayland? (
+ >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}]
+ >=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},egl,gles2,wayland]
+ >=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
+ )
+ X? (
+ >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
+ >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+ >=x11-libs/libXxf86vm-1.1.3[${MULTILIB_USEDEP}]
+ xinerama? ( >=x11-libs/libXinerama-1.1.3[${MULTILIB_USEDEP}] )
+ xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
+ )"
+DEPEND="${RDEPEND}
+ X? (
+ >=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
+ >=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}]
+ )
+ virtual/pkgconfig"
+
+MULTILIB_WRAPPED_HEADERS=(
+ /usr/include/SDL2/SDL_config.h
+)
+
+PATCHES=(
+ # https://bugzilla.libsdl.org/show_bug.cgi?id=1431
+ "${FILESDIR}"/${PN}-2.0.6-static-libs.patch
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ default
+ sed -i -e 's/configure.in/configure.ac/' Makefile.in || die
+ mv configure.{in,ac} || die
+ AT_M4DIR="/usr/share/aclocal acinclude" eautoreconf
+}
+
+multilib_src_configure() {
+ use custom-cflags || strip-flags
+
+ # sorted by `./configure --help`
+ local myeconfargs=(
+ $(use_enable static-libs static)
+ --enable-atomic
+ $(use_enable sound audio)
+ $(use_enable video)
+ --enable-render
+ --enable-events
+ $(use_enable joystick)
+ $(use_enable haptic)
+ --enable-power
+ --enable-filesystem
+ $(use_enable threads)
+ --enable-timers
+ --enable-file
+ $(use_enable kernel_Winnt loadso)
+ --enable-cpuinfo
+ --enable-assembly
+ $(use_enable cpu_flags_x86_sse ssemath)
+ $(use_enable cpu_flags_x86_mmx mmx)
+ $(use_enable cpu_flags_x86_3dnow 3dnow)
+ $(use_enable cpu_flags_x86_sse sse)
+ $(use_enable cpu_flags_x86_sse2 sse2)
+ $(use_enable altivec)
+ $(use_enable oss)
+ $(use_enable alsa)
+ --disable-alsa-shared
+ --disable-esd
+ $(use_enable pulseaudio)
+ --disable-pulseaudio-shared
+ --disable-arts
+ $(use_enable libsamplerate)
+ $(use_enable nas)
+ --disable-nas-shared
+ --disable-sndio
+ --disable-sndio-shared
+ $(use_enable sound diskaudio)
+ $(use_enable sound dummyaudio)
+ $(use_enable wayland video-wayland)
+ --disable-wayland-shared
+ --disable-video-mir
+ $(use_enable X video-x11)
+ --disable-x11-shared
+ $(use_enable X video-x11-xcursor)
+ $(use_enable X video-x11-xdbe)
+ $(use_enable xinerama video-x11-xinerama)
+ $(use_enable X video-x11-xinput)
+ $(use_enable X video-x11-xrandr)
+ $(use_enable xscreensaver video-x11-scrnsaver)
+ $(use_enable X video-x11-xshape)
+ $(use_enable X video-x11-vm)
+ --disable-video-cocoa
+ --disable-video-directfb
+ --disable-fusionsound
+ --disable-fusionsound-shared
+ $(use_enable video video-dummy)
+ $(use_enable opengl video-opengl)
+ --disable-video-opengles1
+ $(use_enable gles video-opengles2)
+ --disable-video-vulkan
+ $(use_enable udev libudev)
+ $(use_enable dbus)
+ --disable-ibus
+ $(use_enable tslib input-tslib)
+ --disable-directx
+ --disable-rpath
+ --disable-render-d3d
+ $(use_with X x)
+ )
+
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+ emake V=1
+}
+
+multilib_src_install() {
+ emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+ prune_libtool_files
+ dodoc {BUGS,CREDITS,README,README-SDL,TODO,WhatsNew}.txt docs/README*.md
+}