[gentoo-commits] repo/gentoo:master commit in: games-arcade/ceferino/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     75f8655ad8dbf90b30357947ab9cb74d04e02ad1
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 15 18:13:34 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Apr 15 19:00:12 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75f8655a

games-arcade/ceferino: Stop using games.eclass

Package-Manager: Portage-2.3.28, Repoman-2.3.9

 games-arcade/ceferino/ceferino-0.97.8-r2.ebuild | 54 +++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/games-arcade/ceferino/ceferino-0.97.8-r2.ebuild b/games-arcade/ceferino/ceferino-0.97.8-r2.ebuild
new file mode 100644
index 00000000000..736477bbe14
--- /dev/null
+++ b/games-arcade/ceferino/ceferino-0.97.8-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools desktop
+
+DESCRIPTION="Super-Pang clone (destroy bouncing balloons with your grapnel)"
+HOMEPAGE="http://www.loosersjuegos.com.ar/juegos/ceferino"
+SRC_URI="mirror://debian/pool/main/c/ceferino/${PN}_${PV}+svn37.orig.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	>=media-libs/libsdl-1.2[video]
+	>=media-libs/sdl-image-1.2
+	>=media-libs/sdl-mixer-1.2
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+S="${WORKDIR}/${P}+svn37"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}"/${P}-latin1.patch
+	sed -i \
+		-e '/^INCLUDES/s:\$(datadir)/locale:/usr/share/locale:' \
+		src/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_install() {
+	default
+	newicon data/ima/icono.png ${PN}.png
+	make_desktop_entry ceferino "Don Ceferino Hazaña"
+}
+
+pkg_postinst() {
+	if ! has_version "media-libs/sdl-mixer[mod]" ; then
+		ewarn
+		ewarn "To hear music, you will have to rebuild media-libs/sdl-mixer"
+		ewarn "with the \"mod\" USE flag turned on."
+		ewarn
+	fi
+}