[gentoo-commits] repo/gentoo:master commit in: app-crypt/libnitrokey/

["David Seifert" <soap@gentoo.org>]

commit:     f64c3b6edee0f8a11bb0862712fb59cd9a17e5bb
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 11 09:36:07 2018 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Wed Apr 11 09:36:07 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f64c3b6e

app-crypt/libnitrokey: Add 3.3 release

Bug: https://bugs.gentoo.org/634474
Package-Manager: Portage-2.3.28, Repoman-2.3.9

 app-crypt/libnitrokey/Manifest               |  1 +
 app-crypt/libnitrokey/libnitrokey-3.3.ebuild | 50 ++++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/app-crypt/libnitrokey/Manifest b/app-crypt/libnitrokey/Manifest
new file mode 100644
index 00000000000..6579ce86131
--- /dev/null
+++ b/app-crypt/libnitrokey/Manifest
@@ -0,0 +1 @@
+DIST libnitrokey-3.3.tar.gz 76581 BLAKE2B 1a662fb94184355dc5cae2f8e3109fc82a96aed06c726e04c4fcfef3aef0423150ac1f4647e4bf3585de7805e70cd67534d72f1255c9f80b57afa2aec36fc9d3 SHA512 fe3b6c7bdeb78f736fe7aa7475880a293c516119ac049ff47ddbaba626f2d70addee4d0cd3a38ea706b94717f51c4fb56f687d5a9bb9f10895836c5adc98b11b

diff --git a/app-crypt/libnitrokey/libnitrokey-3.3.ebuild b/app-crypt/libnitrokey/libnitrokey-3.3.ebuild
new file mode 100644
index 00000000000..32cf1940ee3
--- /dev/null
+++ b/app-crypt/libnitrokey/libnitrokey-3.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+inherit cmake-utils udev
+
+DESCRIPTION="Support library for the Nitrokey"
+HOMEPAGE="https://github.com/Nitrokey/libnitrokey"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Nitrokey/libnitrokey.git"
+
+	# Disable pulling in bundled dependencies
+	EGIT_SUBMODULES=()
+else
+	SRC_URI="https://github.com/Nitrokey/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/hidapi:=
+	virtual/udev"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-cpp/catch-2.2.0 )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_UDEVRULESDIR="$(get_udevdir)"/rules.d
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DBUILD_SHARED_LIBS=ON
+
+		# actual hardware tests
+		#   1. require a connected Nitrokey
+		#   2. may kill data on your Nitrokey
+		# hence the main testsuite is disabled
+		-DCOMPILE_TESTS=OFF
+		-DCOMPILE_OFFLINE_TESTS=$(usex test)
+	)
+	cmake-utils_src_configure
+}