[gentoo-commits] repo/gentoo:master commit in: dev-util/pretrace/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     cbf08c1b429afd482285ca9227fb5fbb8739083a
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 22 21:33:24 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Mar 22 21:35:58 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cbf08c1b

dev-util/pretrace: Stop using prepalldocs (#587268), neither einstall, bump EAPI and don't show elog messages everytime

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 dev-util/pretrace/pretrace-0.4-r1.ebuild | 33 ++++++++++++++++++++++++++++++++
 dev-util/pretrace/pretrace-0.4.ebuild    | 32 -------------------------------
 2 files changed, 33 insertions(+), 32 deletions(-)

diff --git a/dev-util/pretrace/pretrace-0.4-r1.ebuild b/dev-util/pretrace/pretrace-0.4-r1.ebuild
new file mode 100644
index 00000000000..998da63f105
--- /dev/null
+++ b/dev-util/pretrace/pretrace-0.4-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit readme.gentoo-r1
+
+DESCRIPTION="start dynamically linked applications under debugging environment"
+HOMEPAGE="http://dev.inversepath.com/trac/pretrace"
+SRC_URI="http://dev.inversepath.com/pretrace/libpretrace-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+S="${WORKDIR}/lib${P}"
+
+DOC_CONTENTS="Remember to execute ptgenmap after modifying pretrace.conf"
+
+PATCHES=(
+	"${FILESDIR}"/${P}--as-needed.diff
+	"${FILESDIR}"/${P}-build.patch #227923
+)
+
+src_install() {
+	dodir /usr/bin /usr/share/man/man3 /usr/share/man/man8
+	emake DESTDIR="${D}" LIBDIR="${D}/usr/$(get_libdir)" PREFIX="${D}/usr" install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}

diff --git a/dev-util/pretrace/pretrace-0.4.ebuild b/dev-util/pretrace/pretrace-0.4.ebuild
deleted file mode 100644
index 00fe92568f8..00000000000
--- a/dev-util/pretrace/pretrace-0.4.ebuild
+++ /dev/null
@@ -1,32 +0,0 @@
-# Copyright 1999-2009 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-inherit eutils multilib
-
-DESCRIPTION="start dynamically linked applications under debugging environment"
-HOMEPAGE="http://dev.inversepath.com/trac/pretrace"
-SRC_URI="http://dev.inversepath.com/pretrace/libpretrace-${PV}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE=""
-
-S="${WORKDIR}/lib${P}"
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}"/${P}--as-needed.diff
-	epatch "${FILESDIR}"/${P}-build.patch #227923
-}
-
-src_install() {
-	dodir /usr/bin /usr/share/man/man{3,8}
-	einstall LIBDIR="${D}/usr/$(get_libdir)" PREFIX="${D}/usr" || die
-	prepalldocs
-}
-
-pkg_postinst() {
-	elog "remember to execute ptgenmap after modifying pretrace.conf"
-}