[gentoo-commits] repo/gentoo:master commit in: net-analyzer/prometheus-alertmanager/

["Manuel Rüger" <mrueg@gentoo.org>]

commit:     61d87f417502ffe6d2423846692afc1d7a428f23
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 27 18:54:29 2018 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Tue Feb 27 18:54:29 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61d87f41

net-analyzer/prometheus-alertmanager: Install amtool

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 .../prometheus-alertmanager-0.14.0-r1.ebuild       | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.14.0-r1.ebuild b/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.14.0-r1.ebuild
new file mode 100644
index 00000000000..43de943ea4f
--- /dev/null
+++ b/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.14.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot
+
+EGO_PN="github.com/prometheus/alertmanager"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+ALERTMANAGER_COMMIT="fb713f6"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Alertmanager for alerts sent by client applications such as Prometheus"
+HOMEPAGE="https://github.com/prometheus/alertmanager"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-util/promu"
+
+RESTRICT="test"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${ALERTMANAGER_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GOPATH="${S}" promu build -v --prefix bin || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin bin/*
+	dodoc {README,CHANGELOG,CONTRIBUTING}.md
+	insinto /etc/alertmanager/
+	newins doc/examples/simple.yml config.yml.example
+	popd || die
+	keepdir /var/lib/alertmanager /var/log/alertmanager
+	fowners ${PN}:${PN} /var/lib/alertmanager /var/log/alertmanager
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}