[gentoo-commits] repo/gentoo:master commit in: dev-qt/qtlockedfile/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     f407fc982fc2981b9809cae438475a67b4b00043
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 19 20:42:52 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Feb 22 10:47:48 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f407fc98

dev-qt/qtlockedfile: Drop USE qt4,qt5, bump EAPI 6

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 .../qtlockedfile-2.4.1_p20150629-r1.ebuild         | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20150629-r1.ebuild b/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20150629-r1.ebuild
new file mode 100644
index 00000000000..a413f124f18
--- /dev/null
+++ b/dev-qt/qtlockedfile/qtlockedfile-2.4.1_p20150629-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils
+
+MY_P=qt-solutions-${PV#*_p}
+
+DESCRIPTION="QFile extension with advisory locking functions"
+HOMEPAGE="https://code.qt.io/cgit/qt-solutions/qt-solutions.git/"
+SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.xz"
+
+LICENSE="|| ( LGPL-2.1 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="doc"
+
+DEPEND="
+	dev-qt/qtcore:5
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}/${PN}"
+
+src_prepare() {
+	default
+
+	echo 'SOLUTIONS_LIBRARY = yes' > config.pri
+	echo 'QT -= gui' >> src/qtlockedfile.pri
+
+	sed -i -e "s/-head/-${PV%.*}/" common.pri || die
+	sed -i -e '/SUBDIRS+=example/d' ${PN}.pro || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+
+	# libraries
+	dolib.so lib/*
+
+	# headers
+	insinto "$(qt5_get_headerdir)"/QtSolutions
+	doins src/QtLockedFile src/${PN}.h
+
+	# .prf files
+	insinto "$(qt5_get_mkspecsdir)"/features
+	doins "${FILESDIR}"/${PN}.prf
+
+	default
+}