[gentoo-commits] repo/gentoo:master commit in: media-gfx/sane-frontends/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     137e388d3c3439bb738dbc5473890997573470bc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 18 17:02:06 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Feb 18 17:10:50 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=137e388d

media-gfx/sane-frontends: Drop obsolete gimp-1 compat

Cleanup, don't compile in src_configure.

Bug: https://bugs.gentoo.org/647524
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 .../sane-frontends/sane-frontends-1.0.14-r2.ebuild | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/media-gfx/sane-frontends/sane-frontends-1.0.14-r2.ebuild b/media-gfx/sane-frontends/sane-frontends-1.0.14-r2.ebuild
new file mode 100644
index 00000000000..b635cb4ba34
--- /dev/null
+++ b/media-gfx/sane-frontends/sane-frontends-1.0.14-r2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Scanner Access Now Easy"
+HOMEPAGE="http://www.sane-project.org"
+SRC_URI="ftp://ftp.sane-project.org/pub/sane/${P}/${P}.tar.gz
+	ftp://ftp.sane-project.org/pub/sane/old-versions/${P}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gimp"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	media-gfx/sane-backends
+	gimp? ( media-gfx/gimp:2 )
+"
+
+PATCHES=( "${FILESDIR}/MissingCapsFlag.patch" )
+
+src_configure() {
+	econf \
+		--datadir=/usr/share/misc \
+		$(use_enable gimp)
+}
+
+src_install() {
+	local gimpplugindir
+	local gimptool
+	emake DESTDIR="${D}" install
+	if use gimp; then
+		for gimptool in gimptool gimptool-2.0; do
+			if [ -x /usr/bin/${gimptool} ]; then
+				einfo "Setting plugin link for GIMP version	$(/usr/bin/${gimptool} --version)"
+				gimpplugindir=$(/usr/bin/${gimptool} --gimpplugindir)/plug-ins
+				break
+			fi
+		done
+		if [ "/plug-ins" != "${gimpplugindir}" ]; then
+			dodir ${gimpplugindir}
+			dosym xscanimage ${gimpplugindir}/xscanimage
+		else
+			ewarn "No idea where to find the gimp plugin directory"
+		fi
+	fi
+	dodoc AUTHORS Changelog NEWS PROBLEMS README
+}