[gentoo-commits] repo/gentoo:master commit in: media-libs/bio2jack/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     cde254c5c165e44474a078d0405114bc6bbfa2d4
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  1 19:18:02 2018 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Mon Jan  1 19:19:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cde254c5

media-libs/bio2jack: bumped to eapi 6 and switched from media-sound/jack-audio-connection-kit to virtual/jack

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 media-libs/bio2jack/bio2jack-0.9-r2.ebuild | 45 ++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/media-libs/bio2jack/bio2jack-0.9-r2.ebuild b/media-libs/bio2jack/bio2jack-0.9-r2.ebuild
new file mode 100644
index 00000000000..fd38ec0396d
--- /dev/null
+++ b/media-libs/bio2jack/bio2jack-0.9-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools
+
+DESCRIPTION="A library for porting blocked I/O OSS/ALSA audio applications to JACK"
+HOMEPAGE="http://bio2jack.sourceforge.net/"
+SRC_URI="mirror://sourceforge/bio2jack/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="static-libs"
+
+RDEPEND="media-libs/libsamplerate
+	virtual/jack"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	eapply_user
+
+	# upstream does not provide a real release, it releases a tarball
+	# with a _prebuilt_ copy of bio2jack. Drop all of the built stuff
+	# and recreate autotools from scratch, then build.
+	rm -rf *.a *.o *.la *.lo .libs .deps Makefile config.{log,status} stamp-h1 stamp || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dobin bio2jack-config
+	dodoc AUTHORS ChangeLog NEWS README
+	rm -f "${ED}"usr/lib*/lib*.la
+}