From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-988802-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 81478139083
for <garchives@archives.gentoo.org>; Thu, 7 Dec 2017 14:39:19 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 98777E0FF6;
Thu, 7 Dec 2017 14:39:18 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 60053E0FF6
for <gentoo-commits@lists.gentoo.org>; Thu, 7 Dec 2017 14:39:17 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 3EB9633BF24
for <gentoo-commits@lists.gentoo.org>; Thu, 7 Dec 2017 14:39:16 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id D7535AE6B
for <gentoo-commits@lists.gentoo.org>; Thu, 7 Dec 2017 14:39:14 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1512657523.a7d2f1dc751ea2b9cb55fcc98548854bc2d25a81.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-wireless/blueman/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-wireless/blueman/Manifest net-wireless/blueman/blueman-2.1_alpha2.ebuild
X-VCS-Directories: net-wireless/blueman/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: a7d2f1dc751ea2b9cb55fcc98548854bc2d25a81
X-VCS-Branch: master
Date: Thu, 7 Dec 2017 14:39:14 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: ab20c18a-255e-4d6f-811b-109180439953
X-Archives-Hash: 94f688addd85717f7701cf58e807d148
commit: a7d2f1dc751ea2b9cb55fcc98548854bc2d25a81
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 7 14:11:28 2017 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Dec 7 14:38:43 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7d2f1dc
net-wireless/blueman: Bump to 2.1_alpha2
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.1_alpha2.ebuild | 126 +++++++++++++++++++++++++
2 files changed, 127 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 05210a2c147..7f35fb6ea43 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,3 +1,4 @@
DIST blueman-2.0.3.tar.xz 1942832 SHA256 243605e4401c2d21f4706965ef100dac907658d480ace37cbdf863c1c8a45825 SHA512 aaa6bad3321102b09f1cf69f0a3bc7d848bb6674821aa3cb6848243efcd1c1a2b37e20118bf8368b22e32ed1066b57ff187d3a672f2e41122c82d6526bfc888a WHIRLPOOL 0e5ede56e64287e7d500a1836a3eea21efd4f6b1dedd9c5376179309279ecd3d7e84e622c2d167ec5eadc1801c83303c0f2a3988f9eca3422302344414e348d9
DIST blueman-2.0.4.tar.xz 1951988 SHA256 e92dd9c27f75a1485b548f7a8b159946a4af154b90fb82f5a0f614b66a01430f SHA512 98dbe0ac706cf8d33ada6e520c0952fbb930aaa4ec62e35e989f60880287634c2ee947a47b4883063a0aabf27069210774432416278b190b1ca5e1c93d42f614 WHIRLPOOL 13bc27b281b0d17610ac974b46b6d4a290276aa3c8238e6768b763f998ec1bd34af4aa4ea199307ff2d50d4b886e1ea2931a6be6795e68e390d7df7548c48fc8
DIST blueman-2.1.alpha1.tar.xz 1958092 SHA256 df48a28e68117065c00215b6a1060467c80f0cb5ddc2989ea4818c9e78d62909 SHA512 a9180e2cd9596c4e0bde497b0ddf62514dc232d944433f4ae365bc0249a2dd0524bdc9907fbffe604fcb7479fd7b504f304e53688cc552cf7c9184b94413784c WHIRLPOOL 2dc349e6f91db30f5d0c90dec5fdb5dfdcecaacfc2db6ea000726f17b52a01fd6813794cb83588e874eb15b542c8f2404aeb51e1deb97a31419f97750b55190b
+DIST blueman-2.1.alpha2.tar.xz 977344 BLAKE2B c5d3d0a96c1220596647ade310263342cdaaeef511a2fb36973d182025330a29b41fb805ce54e10a2f48c1c66312006858789233f8f0a93923952bb03ac32b19 SHA512 bde4922a93087d07fd99b165255ded8d9465866e62662f644beaafe363d5618a107abbd9d951cfbd034b02b6ece11fb8117efdd5d453632e4a2fea13d3825643
diff --git a/net-wireless/blueman/blueman-2.1_alpha2.ebuild b/net-wireless/blueman/blueman-2.1_alpha2.ebuild
new file mode 100644
index 00000000000..91c37c77c4a
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1_alpha2.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+inherit gnome2-utils linux-info python-single-r1 systemd
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+ KEYWORDS=""
+else
+ SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+ KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+COMMON_DEPEND="
+ dev-python/pygobject:3
+ >=net-wireless/bluez-5:=
+ ${PYTHON_DEPS}"
+DEPEND="${COMMON_DEPEND}
+ dev-python/cython[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${COMMON_DEPEND}
+ dev-python/dbus-python[${PYTHON_USEDEP}]
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/gnome-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ appindicator? ( dev-libs/libappindicator:3[introspection] )
+ network? (
+ net-firewall/iptables
+ sys-apps/net-tools
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8
+ )
+ )
+ policykit? ( sys-auth/polkit )
+ pulseaudio? ( media-sound/pulseaudio[bluetooth] )
+ !net-wireless/gnome-bluetooth
+"
+
+S=${WORKDIR}/${P/_/.}
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+ ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+ linux-info_pkg_setup
+ fi
+}
+
+pkg_setup() {
+ pkg_pretend
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ [[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ --docdir=/usr/share/doc/${PF}
+ --disable-runtime-deps-check
+ --disable-static
+ # TODO: replace upstream with sane system/user unitdir getters
+ --with-systemdunitdir="$(systemd_get_utildir)"
+ $(use_enable appindicator)
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ python_fix_shebang "${D}"
+ rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+ gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ gnome2_schemas_update
+}