[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-screensaver/

["Kristian Fiskerstrand" <k_f@gentoo.org>]

commit:     0161e52577c0d12c50854c6e2441f2d7ebd7a4e5
Author:     Kristian Fiskerstrand <k_f <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 28 19:51:48 2017 +0000
Commit:     Kristian Fiskerstrand <k_f <AT> gentoo <DOT> org>
CommitDate: Tue Nov 28 19:52:06 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0161e525

gnome-extra/cinnamon-screensaver: Add xinerama use flag

Thanks-To: cronolio
Bug: https://bugs.gentoo.org/636924
Package-Manager: Portage-2.3.13, Repoman-2.3.3

 .../cinnamon-screensaver-3.6.1-r1.ebuild           | 93 ++++++++++++++++++++++
 1 file changed, 93 insertions(+)

diff --git a/gnome-extra/cinnamon-screensaver/cinnamon-screensaver-3.6.1-r1.ebuild b/gnome-extra/cinnamon-screensaver/cinnamon-screensaver-3.6.1-r1.ebuild
new file mode 100644
index 00000000000..57085c813e0
--- /dev/null
+++ b/gnome-extra/cinnamon-screensaver/cinnamon-screensaver-3.6.1-r1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit autotools gnome2 multilib python-single-r1
+
+DESCRIPTION="Screensaver for Cinnamon"
+HOMEPAGE="http://cinnamon.linuxmint.com/"
+SRC_URI="https://github.com/linuxmint/cinnamon-screensaver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="debug doc pam systemd xinerama"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2[dbus]
+	>=x11-libs/gtk+-3.1.4:3[introspection]
+	>=gnome-extra/cinnamon-desktop-2.6.3:0=[systemd=]
+	>=gnome-base/gsettings-desktop-schemas-0.1.7
+	>=gnome-base/libgnomekbd-3.6
+	>=dev-libs/dbus-glib-0.78
+
+	net-libs/webkit-gtk:4[introspection]
+
+	sys-apps/dbus
+	x11-libs/libxklavier
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/libXxf86misc
+	x11-libs/libXxf86vm
+	x11-themes/adwaita-icon-theme
+
+	!systemd? ( sys-auth/elogind )
+
+	${PYTHON_DEPS}
+
+	pam? ( virtual/pam )
+	systemd? ( >=sys-apps/systemd-31:0= )
+	xinerama? ( x11-libs/libXinerama )
+"
+# our cinnamon-1.8 ebuilds installed a cinnamon-screensaver.desktop hack
+RDEPEND="${COMMON_DEPEND}
+	!~gnome-extra/cinnamon-1.8.8.1
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/xapp[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.35
+	gnome-base/gnome-common
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xextproto
+	x11-proto/randrproto
+	x11-proto/scrnsaverproto
+	x11-proto/xf86miscproto
+	doc? (
+		app-text/xmlto
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.4 )
+"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	python_fix_shebang screensavers
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(usex debug --enable-debug ' ') \
+		$(use_enable xinerama)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! has_version x11-misc/xscreensaver; then
+		elog "${PN} can use screensavers from x11-misc/xscreensaver"
+	fi
+
+}