[gentoo-commits] repo/gentoo:master commit in: app-office/lyx/

["Jonas Stein" <jstein@gentoo.org>]

commit:     f1dcb260fe9ccf807bfe46939a48d8f585ab2311
Author:     Jonas Stein <jstein <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 23 00:32:08 2017 +0000
Commit:     Jonas Stein <jstein <AT> gentoo <DOT> org>
CommitDate: Thu Nov 23 00:38:44 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f1dcb260

app-office/lyx: Fix fdo, eutils, die

migrate from 'fdo-mime' to 'xdg'
let eapi helper die on its own
removed obsolete eutils

Package-Manager: Portage-2.3.15, Repoman-2.3.5

 app-office/lyx/Manifest            |   2 +-
 app-office/lyx/lyx-2.2.3-r2.ebuild | 194 +++++++++++++++++++++++++++++++++++++
 2 files changed, 195 insertions(+), 1 deletion(-)

diff --git a/app-office/lyx/Manifest b/app-office/lyx/Manifest
index 040ea868330..6a9cbfad5be 100644
--- a/app-office/lyx/Manifest
+++ b/app-office/lyx/Manifest
@@ -1,4 +1,4 @@
 DIST lyx-2.0.8.1.tar.xz 10481988 SHA256 fa0a9c6070554e0d12d24e9b3c4a1e5fc2ee853b3fbe83e2a415635cdc973c59 SHA512 17e313d3118dfe439f5251384f2fffdb45ffef5ec515953b7af0762d35c8e156a9338de698cea91cf8b3cedca1fc08364d8f3c50c9345f304d57004af695f901 WHIRLPOOL 6a9ef2df39861d373e1c6288f5443f910632a09ed4d84e409efe06459f2f39d3c30462b3a26aafe37c5216b765882e7ab5189e7d164b71def97f50877784754c
 DIST lyx-2.1.5.tar.xz 10361112 SHA256 2e677591aebdd484efb7d2920357f1358f9525ab1feaa59a63a8cf92b7ee2cf3 SHA512 6f8c62ff96458d0c8c8057ae1e587be4c63bd3bdf2d4f095c24d447017034eda8c6b645efbd258f0956a9bbfe5fde2f90df36515be7b8a94cb63674bc3a58672 WHIRLPOOL 46ee376a7ef9594d22c0c5385e07221dbc5fb3ae1c8e3e754cbc11f53d665d2c9db66a250716fc03384f23ec7133556cca0c500555c471bb7be288c47fc13db5
 DIST lyx-2.2.2.tar.xz 15490148 SHA256 a85c3d7412c4069f8a1f5af4eb172948ae9a50394602f6318ab5c8e990aa5568 SHA512 5057a06f0c37cb2beadb92414eec495ba0619f6c8a9fb5372a9feb90fe0d8bf850de5c94bbf618c8e27bd64404ae6687c48ee24aa6e1bd35580eb3b77d71d45e WHIRLPOOL 0962289b07f767fee7eb7a9b9ae4da99f04a8c3e63f3fe7d4db798bc339772921534e7b1caefc3c0812cc815995d272dee8e365a7c357965acbebd5d6a1930c3
-DIST lyx-2.2.3.tar.xz 15501856 SHA256 4fcaeb7c202472d9ea21bf826fb30541015fef33e7217eda2be2b5d589c82b57 SHA512 b5a4a16b22680022651a0f3911c2c24bcd3541a573e672e541cb0af6572089e4b0e0ec1cafb40850e75c377e7da5b286d0314886e0c57d55f57645d8e4a07708 WHIRLPOOL c8054e4102189ab435bbbaec0dff0d4c5be4df781b4e1dd664caa87c231803b6a2bd6e89a92b333eae24884771932912a5df046adb7f782a6548a2c4c3b3219a
+DIST lyx-2.2.3.tar.xz 15501856 BLAKE2B 08606f0c18d9cb5891bd7d612361597e3efc7e7855f7607c2620f10ddb22b7078d5085f725911496198d2d8a47ece54cbfe67cfbf4ec8eb15450271cd133b095 SHA512 b5a4a16b22680022651a0f3911c2c24bcd3541a573e672e541cb0af6572089e4b0e0ec1cafb40850e75c377e7da5b286d0314886e0c57d55f57645d8e4a07708

diff --git a/app-office/lyx/lyx-2.2.3-r2.ebuild b/app-office/lyx/lyx-2.2.3-r2.ebuild
new file mode 100644
index 00000000000..d1fbcd95e53
--- /dev/null
+++ b/app-office/lyx/lyx-2.2.3-r2.ebuild
@@ -0,0 +1,194 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit gnome2-utils xdg flag-o-matic font python-single-r1 qmake-utils toolchain-funcs
+
+MY_P="${P/_}"
+
+S="${WORKDIR}/${MY_P}"
+FONT_S="${S}/lib/fonts"
+FONT_SUFFIX="ttf"
+DESCRIPTION="WYSIWYM frontend for LaTeX, DocBook, etc."
+HOMEPAGE="https://www.lyx.org/"
+SRC_URI="ftp://ftp.lyx.org/pub/lyx/stable/2.2.x/${MY_P}.tar.xz
+	ftp://ftp.lyx.org/pub/lyx/devel/lyx-2.2/${MY_P}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="aspell cups debug docbook dia dot enchant gnumeric html +hunspell +latex monolithic-build nls +qt5 rcs rtf subversion svg"
+
+LANGS="ar ca cs da de el en es eu fi fr gl he hu ia id it ja nb nn pl pt_BR pt_PT ro ru sk sr sv tr uk zh_CN zh_TW"
+
+for X in ${LANGS}; do
+	IUSE="${IUSE} linguas_${X}"
+done
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/boost:=
+	dev-texlive/texlive-fontsextra
+	sys-apps/file
+	sys-libs/zlib
+	virtual/imagemagick-tools[png,svg?]
+	aspell? ( app-text/aspell )
+	cups? ( net-print/cups )
+	dia? ( app-office/dia )
+	docbook? ( app-text/sgmltools-lite )
+	dot? ( media-gfx/graphviz )
+	enchant? ( app-text/enchant )
+	gnumeric? ( app-office/gnumeric )
+	html? ( dev-tex/html2latex )
+	hunspell? ( app-text/hunspell )
+	latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+		app-text/noweb
+		app-text/ps2eps
+		app-text/texlive
+		dev-tex/chktex
+		dev-tex/dvipost
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-pictures
+		|| ( dev-texlive/texlive-mathscience dev-texlive/texlive-science )
+		|| ( dev-texlive/texlive-plaingeneric dev-texlive/texlive-genericextra )
+		|| (
+			dev-tex/hevea
+			dev-tex/latex2html
+			dev-tex/tex4ht[java]
+			dev-tex/tth
+		)
+	)
+	linguas_he? ( dev-tex/culmus-latex )
+	!qt5? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)
+	rcs? ( dev-vcs/rcs )
+	rtf? (
+		app-text/unrtf
+		dev-tex/html2latex
+		dev-tex/latex2rtf
+	)
+	subversion? ( dev-vcs/subversion )
+	svg? ( || ( gnome-base/librsvg media-gfx/inkscape ) )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	!qt5? ( dev-qt/qtsvg:4 )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtx11extras:5
+	)
+"
+
+DOCS=( ANNOUNCE NEWS README RELEASE-NOTES UPGRADING )
+
+PATCHES=( "${FILESDIR}"/2.1-python.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	font_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s:python -tt:${EPYTHON} -tt:g" -i lib/configure.py || die
+}
+
+src_configure() {
+	tc-export CXX
+	#bug 221921
+	export VARTEXFONTS=${T}/fonts
+
+	econf \
+		$(use_with aspell) \
+		$(use_enable debug) \
+		$(use_with enchant) \
+		$(use_with hunspell) \
+		$(use_enable monolithic-build) \
+		$(use_enable nls) \
+		$(use_enable qt5) \
+		--with-qt-dir=$(usex qt5 $(qt5_get_libdir)/qt5 $(qt4_get_libdir)) \
+		--disable-stdlib-debug \
+		--without-included-boost \
+		--with-packaging=posix
+}
+
+src_install() {
+	default
+
+	if use linguas_he ; then
+		echo "\bind_file cua" > "${T}"/hebrew.bind
+		echo "\bind \"F12\" \"language hebrew\"" >> "${T}"/hebrew.bind
+
+		insinto /usr/share/lyx/bind
+		doins "${T}"/hebrew.bind
+	fi
+
+	newicon -s 32 "${S}/development/Win32/packaging/icons/lyx_32x32.png" ${PN}.png
+	doicon -s 48 "${S}/lib/images/lyx.png"
+	doicon -s scalable "${S}/lib/images/lyx.svg"
+
+	# fix for bug 91108
+	if use latex ; then
+		dosym ../../../lyx/tex /usr/share/texmf-site/tex/latex/lyx
+	fi
+
+	# fonts needed for proper math display, see also bug #15629
+	font_src_install
+
+	python_fix_shebang "${ED}"/usr/share/${PN}
+
+	if use hunspell ; then
+		dosym ../myspell /usr/share/lyx/dicts
+		dosym ../myspell /usr/share/lyx/thes
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	font_pkg_postinst
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	# fix for bug 91108
+	if use latex ; then
+		texhash
+	fi
+
+	# instructions for RTL support. See also bug 168331.
+	if use linguas_he || use linguas_ar; then
+		elog
+		elog "Enabling RTL support in LyX:"
+		elog "If you intend to use a RTL language (such as Hebrew or Arabic)"
+		elog "You must enable RTL support in LyX. To do so start LyX and go to"
+		elog "Tools->Preferences->Language settings->Language"
+		elog "and make sure the \"Right-to-left language support\" is checked"
+		elog
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	if use latex ; then
+		texhash
+	fi
+}