[gentoo-commits] repo/gentoo:master commit in: net-analyzer/netio/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     aaebe8559ec6722a1c735e4ec165ae07a6aa1cf2
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 16 10:12:11 2017 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Thu Nov 16 10:12:11 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aaebe855

net-analyzer/netio: Update HOMEPAGE/SRC_URI by Nico Baggus (bug #637660).

Package-Manager: Portage-2.3.14, Repoman-2.3.6

 net-analyzer/netio/netio-1.32-r1.ebuild | 48 +++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/net-analyzer/netio/netio-1.32-r1.ebuild b/net-analyzer/netio/netio-1.32-r1.ebuild
new file mode 100644
index 00000000000..afba5e9baeb
--- /dev/null
+++ b/net-analyzer/netio/netio-1.32-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="measures net throughput with NetBIOS and TCP/IP protocols"
+HOMEPAGE="https://web.ars.de/netio/"
+SRC_URI="http://web.ars.de/wp-content/uploads/2017/04/${PN}${PV/./}.zip"
+
+LICENSE="free-noncomm"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+RESTRICT="mirror" # bug #391789 comment #1
+
+DEPEND="
+	app-arch/unzip
+	>=sys-apps/sed-4
+"
+
+S="${WORKDIR}"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.26-linux-include.patch
+)
+
+src_prepare() {
+	edos2unix *.c *.h *.doc
+
+	default
+
+	sed -i \
+		-e "s|LFLAGS=\"\"|LFLAGS?=\"${LDFLAGS}\"|g" \
+		-e 's|\(CC\)=|\1?=|g' \
+		-e 's|\(CFLAGS\)=|\1+=|g' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		linux
+}
+
+src_install() {
+	dobin netio
+	dodoc netio.doc
+}