[gentoo-commits] repo/gentoo:master commit in: dev-libs/libressl/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     6525d9f66f488843f5abba5110d6fb799e9d7b5b
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 10 23:15:04 2017 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Fri Nov 10 23:15:22 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6525d9f6

dev-libs/libressl: revert to gnu autotools builds system, bugs #636836 #636856

Package-Manager: Portage-2.3.8, Repoman-2.3.3

 dev-libs/libressl/libressl-2.6.3-r1.ebuild | 55 ------------------------------
 dev-libs/libressl/libressl-2.6.3-r2.ebuild | 52 ++++++++++++++++++++++++++++
 dev-libs/libressl/metadata.xml             |  1 -
 3 files changed, 52 insertions(+), 56 deletions(-)

diff --git a/dev-libs/libressl/libressl-2.6.3-r1.ebuild b/dev-libs/libressl/libressl-2.6.3-r1.ebuild
deleted file mode 100644
index 973160f6917..00000000000
--- a/dev-libs/libressl/libressl-2.6.3-r1.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit cmake-multilib
-
-DESCRIPTION="Free version of the SSL/TLS protocol forked from OpenSSL"
-HOMEPAGE="https://www.libressl.org"
-SRC_URI="https://ftp.openbsd.org/pub/OpenBSD/LibreSSL/${P}.tar.gz"
-
-LICENSE="ISC openssl"
-# Reflects ABI of libcrypto.so and libssl.so.  Since these can differ,
-# we'll try to use the max of either.  However, if either change between
-# versions, we have to change the subslot to trigger rebuild of consumers.
-SLOT="0/44"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86"
-IUSE="+asm nc static-libs"
-
-RDEPEND="
-	!dev-libs/openssl:0
-	nc? ( !net-analyzer/openbsd-netcat )"
-DEPEND="${RDEPEND}"
-PDEPEND="app-misc/ca-certificates"
-
-src_prepare() {
-	# Correct hardcoded paths to use ca-certificates instead of cert.pem
-	find "${S}"/{apps,crypto,tls} -type f -exec \
-		sed -e 's|/cert.pem|/certs/ca-certificates.crt|' -i {} \; || die
-
-	eapply_user
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DENABLE_ASM=$(usex asm)
-		-DENABLE_NC=$(usex nc)
-		-DOPENSSLDIR="${EPREFIX}"/etc/ssl
-		-DUSE_SHARED=1
-	)
-
-	cmake-multilib_src_configure
-}
-
-multilib_src_install_all() {
-	einstalldocs
-
-	# Delete cert.pem
-	rm "${ED}"/etc/ssl/cert.pem || die
-	scanelf -Xe "${ED}"/usr/lib64/libcrypto.so.42.0.0
-
-	if ! use static-libs ; then
-		find "${D}" -name '*.a' -exec rm -f {} + || die
-	fi
-}

diff --git a/dev-libs/libressl/libressl-2.6.3-r2.ebuild b/dev-libs/libressl/libressl-2.6.3-r2.ebuild
new file mode 100644
index 00000000000..ae81279ce6f
--- /dev/null
+++ b/dev-libs/libressl/libressl-2.6.3-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+DESCRIPTION="Free version of the SSL/TLS protocol forked from OpenSSL"
+HOMEPAGE="http://www.libressl.org/"
+SRC_URI="http://ftp.openbsd.org/pub/OpenBSD/LibreSSL/${P}.tar.gz"
+
+LICENSE="ISC openssl"
+# Reflects ABI of libcrypto.so and libssl.so.  Since these can differ,
+# we'll try to use the max of either.  However, if either change between
+# versions, we have to change the subslot to trigger rebuild of consumers.
+SLOT="0/44"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86"
+IUSE="+asm static-libs"
+
+RDEPEND="!dev-libs/openssl:0"
+DEPEND="${RDEPEND}"
+PDEPEND="app-misc/ca-certificates"
+
+src_prepare() {
+	touch crypto/Makefile.in
+
+	sed -i \
+		-e '/^[ \t]*CFLAGS=/s#-g ##' \
+		-e '/^[ \t]*CFLAGS=/s#-g"#"#' \
+		-e '/^[ \t]*CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*CFLAGS=/s#-O2"#"#' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2"#"#' \
+		configure || die "fixing CFLAGS failed"
+
+	eapply_user
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable asm) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	emake check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}

diff --git a/dev-libs/libressl/metadata.xml b/dev-libs/libressl/metadata.xml
index 9a56130ae30..a7201a6f607 100644
--- a/dev-libs/libressl/metadata.xml
+++ b/dev-libs/libressl/metadata.xml
@@ -11,7 +11,6 @@
 	</longdescription>
 	<use>
 		<flag name="asm">Enables assembly</flag>
-		<flag name="nc">Installs the libtls-based netcat binary</flag>
 	</use>
 	<upstream>
 		<changelog>http://www.libressl.org/releases.html</changelog>