[gentoo-commits] repo/gentoo:master commit in: app-misc/qlcplus/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     e0069282cab478f4343d4d439b22876f0ee76fb7
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun May 28 19:26:54 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Sep 17 16:17:07 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0069282

app-misc/qlcplus: Drop USE=qt4,qt5, build w/ Qt5 unconditionally, EAPI 6

Drop unneeded qt4-r2 and eutils eclasses
Sort dependencies
Switch to virtx emake check

Package-Manager: Portage-2.3.5, Repoman-2.3.1

 app-misc/qlcplus/qlcplus-4.10.5b-r1.ebuild | 55 ++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/app-misc/qlcplus/qlcplus-4.10.5b-r1.ebuild b/app-misc/qlcplus/qlcplus-4.10.5b-r1.ebuild
new file mode 100644
index 00000000000..9d4d685ddec
--- /dev/null
+++ b/app-misc/qlcplus/qlcplus-4.10.5b-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils udev vcs-snapshot virtualx
+
+DESCRIPTION="QLC+ - Q Light Controller Plus to control DMX interfaces"
+HOMEPAGE="http://www.qlcplus.org/"
+SRC_URI="https://github.com/mcallegari/${PN}/archive/QLC+_${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	|| ( dev-embedded/libftdi:1 dev-embedded/libftdi:0 )
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5
+	dev-qt/qtscript:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	media-libs/alsa-lib
+	media-libs/libmad
+	media-libs/libsndfile
+	sci-libs/fftw:3.0
+	virtual/libusb:0
+	virtual/libusb:1
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	sed -e "s:/etc/udev/rules.d:${EROOT}lib/udev/rules.d:" -i \
+		plugins/hid/hid.pro \
+		plugins/udmx/src/src.pro \
+		plugins/dmxusb/src/src.pro \
+		plugins/spi/spi.pro \
+		plugins/peperoni/unix/unix.pro || die
+	sed -e "/UDEVRULESDIR/s:/etc/udev/rules.d:$(get_udevdir)/rules.d:" \
+		-i variables.pri || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_test() {
+	virtx emake check
+}