[gentoo-commits] repo/gentoo:master commit in: kde-frameworks/kdelibs/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     8f507129070c14bda56fc9fee5362aaab4dfe19b
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 12 09:58:26 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 12 11:36:28 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f507129

kde-frameworks/kdelibs: 4.14.36 version bump

Zero code changes, bumping for enchant subslot.

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 kde-frameworks/kdelibs/Manifest               |   1 +
 kde-frameworks/kdelibs/kdelibs-4.14.36.ebuild | 249 ++++++++++++++++++++++++++
 2 files changed, 250 insertions(+)

diff --git a/kde-frameworks/kdelibs/Manifest b/kde-frameworks/kdelibs/Manifest
index 6aabd6c588b..cf76b7fe71a 100644
--- a/kde-frameworks/kdelibs/Manifest
+++ b/kde-frameworks/kdelibs/Manifest
@@ -1,2 +1,3 @@
 DIST kdelibs-4.14.34.tar.xz 11644736 SHA256 777d3433555b3257fe67167723020bb7f0da7b16daeace9910751e4b9bf9bcfb SHA512 57ba1591e6996af79f03e8a3d4d0c278c027ad65c717fcbdb857df68a3df47ddec6b7c34dfd682d590bfa9ed6800974b53ff29aa7ab73522caebc9897cbd81c0 WHIRLPOOL 7c1f318edadb6625acef33891e8fb751dd0c783a05f0e4bb2b77376791c43fbfee20bf8b72aab719bcfd8d271294263f2fc57912fd09edb38589a37d8a01c968
 DIST kdelibs-4.14.35.tar.xz 11642928 SHA256 9732bd7408de1d063b555ec849d74aa53598efe6b4113258af3270fcab5af303 SHA512 78ec1e34a4683b367b5df93992273b9b7f8d2471000feb0881df933bb3dc1d4b5b27a2343ca57957c20efcc46590a20be7ea763ff6960b004af91c96bac89ae0 WHIRLPOOL 89bc91f2c2c58d7bef99825122afde40cfef1aad734ad84187e09b0b7c189aedfd54480ddd93e2bad440ef978c169e3d8d3de2b397ffed8eb9daec8c533b7a4b
+DIST kdelibs-4.14.36.tar.xz 11644668 SHA256 e129d228afdcd72b68eec0e440899f284e1e48bf54f798ec5369c5b75676a523 SHA512 8578160d204c358c96623f6c233623ea8589aa3ae623b1c6b9f7bd8e687e1e7cdff390602d871195c92bfbe11862cc4a88f2d058450b60b647cd339575349c64 WHIRLPOOL cad8e9c68c3a27d118a38e8c0b63ba5c73e7f4ec5e0b68d0d4be27552cc3fd34078049a1402f02c5880ffe185944c9c092671c9720ec3a60263168444819cc4a

diff --git a/kde-frameworks/kdelibs/kdelibs-4.14.36.ebuild b/kde-frameworks/kdelibs/kdelibs-4.14.36.ebuild
new file mode 100644
index 00000000000..bae657f99bd
--- /dev/null
+++ b/kde-frameworks/kdelibs/kdelibs-4.14.36.ebuild
@@ -0,0 +1,249 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+CPPUNIT_REQUIRED="optional"
+DECLARATIVE_REQUIRED="always"
+KDE_HANDBOOK="optional"
+OPENGL_REQUIRED="optional"
+WEBKIT_REQUIRED="optional"
+inherit kde4-base toolchain-funcs flag-o-matic xdg-utils
+
+APPS_VERSION="17.08.1" # Don't forget to bump this
+
+DESCRIPTION="Libraries needed for programs by KDE"
+[[ ${KDE_BUILD_TYPE} != live ]] && \
+SRC_URI="mirror://kde/stable/applications/${APPS_VERSION}/src/${P}.tar.xz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="cpu_flags_x86_3dnow acl altivec +bzip2 debug doc fam jpeg2k kerberos
+libressl lzma cpu_flags_x86_mmx nls openexr plasma +policykit qt3support
+spell cpu_flags_x86_sse cpu_flags_x86_sse2 ssl +udev +udisks +upower zeroconf"
+
+REQUIRED_USE="
+	opengl? ( plasma )
+	udisks? ( udev )
+	upower? ( udev )
+"
+
+# needs the kate regression testsuite from svn
+RESTRICT="test"
+
+COMMONDEPEND="
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	>=dev-libs/libattica-0.4.2
+	dev-libs/libdbusmenu-qt[qt4]
+	dev-libs/libpcre[unicode]
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtcore-${QT_MINIMAL}:4[qt3support?]
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/giflib:=
+	media-libs/libpng:0=
+	media-libs/phonon[qt4]
+	sys-libs/zlib
+	virtual/jpeg:0
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcursor
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXpm
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libXtst
+	x11-misc/shared-mime-info
+	!kernel_SunOS? ( || (
+		sys-libs/libutempter
+		>=sys-freebsd/freebsd-lib-9.0
+	) )
+	acl? ( virtual/acl )
+	bzip2? ( app-arch/bzip2 )
+	fam? ( virtual/fam )
+	jpeg2k? ( media-libs/jasper:= )
+	kerberos? ( virtual/krb5 )
+	openexr? (
+		media-libs/openexr:=
+		media-libs/ilmbase:=
+	)
+	plasma? (
+		app-crypt/qca:2[qt4]
+		>=dev-qt/qtsql-${QT_MINIMAL}:4[qt3support?]
+	)
+	policykit? ( sys-auth/polkit-qt[qt4] )
+	spell? ( app-text/enchant:= )
+	ssl? (
+		libressl? ( dev-libs/libressl:0= )
+		!libressl? ( dev-libs/openssl:0= )
+	)
+	udev? ( virtual/udev )
+	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+"
+DEPEND="${COMMONDEPEND}
+	doc? ( app-doc/doxygen )
+	nls? ( virtual/libintl )
+"
+RDEPEND="${COMMONDEPEND}
+	!dev-qt/qtphonon
+	>=app-crypt/gnupg-2.0.11
+	app-misc/ca-certificates
+	kde-frameworks/kdelibs-env:4
+	sys-apps/dbus[X]
+	x11-apps/iceauth
+	x11-apps/rgb
+	x11-misc/xdg-utils
+	plasma? ( !sci-libs/plasma )
+	udev? ( app-misc/media-player-info )
+	udisks? ( sys-fs/udisks:2 )
+	upower? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )
+"
+PDEPEND="
+	x11-misc/xdg-utils
+	handbook? ( kde-apps/khelpcenter:* )
+	policykit? ( kde-plasma/polkit-kde-agent )
+"
+
+PATCHES=(
+	"${FILESDIR}/dist/01_gentoo_set_xdg_menu_prefix-1.patch"
+	"${FILESDIR}/dist/02_gentoo_append_xdg_config_dirs-1.patch"
+	"${FILESDIR}/${PN}-4.14.5-fatalwarnings.patch"
+	"${FILESDIR}/${PN}-4.14.5-mimetypes.patch"
+	"${FILESDIR}/${PN}-4.4.90-xslt.patch"
+	"${FILESDIR}/${PN}-4.6.3-no_suid_kdeinit.patch"
+	"${FILESDIR}/${PN}-4.8.1-norpath.patch"
+	"${FILESDIR}/${PN}-4.9.3-werror.patch"
+	"${FILESDIR}/${PN}-4.10.0-udisks.patch"
+	"${FILESDIR}/${PN}-4.14.20-FindQt4.patch"
+	"${FILESDIR}/${PN}-4.14.22-webkit.patch"
+	"${FILESDIR}/${PN}-4.14.35-3dnow.patch"
+	"${FILESDIR}/${PN}-4.14.35-kde3support.patch"
+	"${FILESDIR}/${PN}-4.14.35-plasma4.patch"
+	# upstream:
+	"${FILESDIR}/${PN}-4.14.35-enchant2.patch"
+)
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Rename applications.menu (needs 01_gentoo_set_xdg_menu_prefix-1.patch to work)
+	sed -e 's|FILES[[:space:]]applications.menu|FILES applications.menu RENAME kde-4-applications.menu|g' \
+		-i kded/CMakeLists.txt || die "Sed on CMakeLists.txt for applications.menu failed."
+
+	if ! use opengl; then
+		sed -i -e "/if/ s/QT_QTOPENGL_FOUND/FALSE/" \
+			plasma/CMakeLists.txt plasma/tests/CMakeLists.txt includes/CMakeLists.txt \
+			|| die "failed to sed out QT_QTOPENGL_FOUND"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_HSPELL=OFF
+		-DWITH_ASPELL=OFF
+		-DKDE_DEFAULT_HOME=.kde4
+		-DKAUTH_BACKEND=POLKITQT-1
+		-DWITH_Soprano=OFF
+		-DWITH_SharedDesktopOntologies=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Strigi=ON
+		-DBUILD_doc=$(usex handbook)
+		-DHAVE_X86_3DNOW=$(usex cpu_flags_x86_3dnow)
+		-DHAVE_PPC_ALTIVEC=$(usex altivec)
+		-DHAVE_X86_MMX=$(usex cpu_flags_x86_mmx)
+		-DHAVE_X86_SSE=$(usex cpu_flags_x86_sse)
+		-DHAVE_X86_SSE2=$(usex cpu_flags_x86_sse2)
+		-DWITH_ACL=$(usex acl)
+		-DWITH_BZip2=$(usex bzip2)
+		-DWITH_FAM=$(usex fam)
+		-DWITH_Jasper=$(usex jpeg2k)
+		-DWITH_GSSAPI=$(usex kerberos)
+		-DWITH_LibLZMA=$(usex lzma)
+		-DWITH_Libintl=$(usex nls)
+		-DWITH_OpenEXR=$(usex openexr)
+		-DWITH_PLASMA4SUPPORT=$(usex plasma)
+		-DWITH_QCA2=$(usex plasma)
+		-DWITH_PolkitQt-1=$(usex policykit)
+		-DWITH_KDE3SUPPORT=$(usex qt3support)
+		-DWITH_ENCHANT=$(usex spell)
+		-DWITH_OpenSSL=$(usex ssl)
+		-DWITH_UDev=$(usex udev)
+		-DWITH_SOLID_UDISKS2=$(usex udisks)
+		-DWITH_KDEWEBKIT=$(usex webkit)
+		-DWITH_Avahi=$(usex zeroconf)
+	)
+
+	use zeroconf || mycmakeargs+=( -DWITH_DNSSD=OFF )
+
+	kde4-base_src_configure
+}
+
+src_compile() {
+	kde4-base_src_compile
+
+	# The building of apidox is not managed anymore by the build system
+	if use doc; then
+		einfo "Building API documentation"
+		cd "${S}"/doc/api/
+		./doxygen.sh "${S}" || die "APIDOX generation failed"
+	fi
+}
+
+src_install() {
+	kde4-base_src_install
+
+	# use system certificates
+	rm -f "${ED}"/usr/share/apps/kssl/ca-bundle.crt || die
+	dosym ../../../../etc/ssl/certs/ca-certificates.crt /usr/share/apps/kssl/ca-bundle.crt
+
+	if use doc; then
+		einfo "Installing API documentation. This could take a bit of time."
+		cd "${S}"/doc/api/
+		docinto /HTML/en/kdelibs-apidox
+		dohtml -r ${P}-apidocs/*
+	fi
+
+	# We don't package it, so don't install headers
+	rm -r "${ED}"/usr/include/KDE/Nepomuk || die
+
+	einfo Installing environment file.
+	# Since 44qt4 is sourced earlier QT_PLUGIN_PATH is defined.
+	echo "COLON_SEPARATED=QT_PLUGIN_PATH" > "${T}/77kde"
+	echo "QT_PLUGIN_PATH=${EPREFIX}/usr/$(get_libdir)/kde4/plugins" >> "${T}/77kde"
+	doenvd "${T}/77kde"
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+
+	if use zeroconf; then
+		elog
+		elog "To make zeroconf support available in applications make sure that the avahi daemon"
+		elog "is running."
+		elog
+		elog "If you also want to use zeroconf for hostname resolution, emerge sys-auth/nss-mdns"
+		elog "and enable multicast dns lookups by editing the 'hosts:' line in /etc/nsswitch.conf"
+		elog "to include 'mdns', e.g.:"
+		elog "	hosts: files mdns dns"
+		elog
+	fi
+
+	kde4-base_pkg_postinst
+}
+
+pkg_prerm() {
+	# Remove ksycoca4 global database
+	rm -f "${EROOT%/}"/usr/share/kde4/services/ksycoca4 || die
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+
+	kde4-base_pkg_postrm
+}