From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-966801-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 9644F1396D0
for <garchives@archives.gentoo.org>; Sat, 12 Aug 2017 23:15:53 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 7F4C41FC0A0;
Sat, 12 Aug 2017 23:15:50 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 4F0A01FC0A0
for <gentoo-commits@lists.gentoo.org>; Sat, 12 Aug 2017 23:15:50 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 53457341911
for <gentoo-commits@lists.gentoo.org>; Sat, 12 Aug 2017 23:15:49 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 912C8771F
for <gentoo-commits@lists.gentoo.org>; Sat, 12 Aug 2017 23:15:45 +0000 (UTC)
From: "Gilles Dartiguelongue" <eva@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Gilles Dartiguelongue" <eva@gentoo.org>
Message-ID: <1502579704.3dc4f4c93150fd4bc9074b0cceb81e0d06f7e858.eva@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-editors/gedit/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-editors/gedit/Manifest app-editors/gedit/gedit-3.22.1.ebuild
X-VCS-Directories: app-editors/gedit/
X-VCS-Committer: eva
X-VCS-Committer-Name: Gilles Dartiguelongue
X-VCS-Revision: 3dc4f4c93150fd4bc9074b0cceb81e0d06f7e858
X-VCS-Branch: master
Date: Sat, 12 Aug 2017 23:15:45 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: b1dd03ea-f62a-4eac-80d5-c5b8f0c78669
X-Archives-Hash: 7f477912636cea76763adc15b747f13b
commit: 3dc4f4c93150fd4bc9074b0cceb81e0d06f7e858
Author: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 12 23:07:31 2017 +0000
Commit: Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Aug 12 23:15:04 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3dc4f4c9
app-editors/gedit: version bump 3.22.0 → 3.22.1
Misc bugfixes. Translation updates.
Package-Manager: Portage-2.3.6, Repoman-2.3.3
app-editors/gedit/Manifest | 1 +
app-editors/gedit/gedit-3.22.1.ebuild | 91 +++++++++++++++++++++++++++++++++++
2 files changed, 92 insertions(+)
diff --git a/app-editors/gedit/Manifest b/app-editors/gedit/Manifest
index 9af2ab9f0f8..e29dbd6f5ba 100644
--- a/app-editors/gedit/Manifest
+++ b/app-editors/gedit/Manifest
@@ -1 +1,2 @@
DIST gedit-3.22.0.tar.xz 2957520 SHA256 063b5a0b5dcc8f540f6e8c3ea1c22cf8a3a19edffc25315a1b6bc51d462b3f45 SHA512 7137fe96cca072c294dea545cb7fafee7ca2da84d8b7756e03a5f5dde6cdca8a3eec6f58136cec0aeeb49c294acd000f01bf3a44447411924aff107dbab26efb WHIRLPOOL 621a9ef89bdaafc490e6b05ac00d91978f175953c37c3d6c141b0513a99bc77b05907dab665d48022f56d0c6a8b9ad8e935c2279d58356d691490b16e533135e
+DIST gedit-3.22.1.tar.xz 2948048 SHA256 aa7bc3618fffa92fdb7daf2f57152e1eb7962e68561a9c92813d7bbb7fc9492b SHA512 7251732f353b1d9dab0fe447fe90b2259df34ff0694d8731ce3be531c21ac82ab6e7f4a07090aeef364640154f4ba6103539a253bc7942952dcf1e331418f0eb WHIRLPOOL 5bb12a567693107ae8b3fc625ae546b0d56e781fe4aa009f3a26ace56ab603bd1d4de80386584837563f8d77b173adf39e5850010a50d4eb3add82bbefb85445
diff --git a/app-editors/gedit/gedit-3.22.1.ebuild b/app-editors/gedit/gedit-3.22.1.ebuild
new file mode 100644
index 00000000000..4484dab3984
--- /dev/null
+++ b/app-editors/gedit/gedit-3.22.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+GNOME2_LA_PUNT="yes" # plugins are dlopened
+PYTHON_COMPAT=( python3_{4,5} )
+VALA_MIN_API_VERSION="0.26"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 multilib python-single-r1 vala virtualx
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gedit"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="+introspection +python spell vala"
+REQUIRED_USE="python? ( introspection ${PYTHON_REQUIRED_USE} )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+
+# X libs are not needed for OSX (aqua)
+COMMON_DEPEND="
+ >=dev-libs/libxml2-2.5.0:2
+ >=dev-libs/glib-2.44:2[dbus]
+ >=x11-libs/gtk+-3.21.3:3[introspection?]
+ >=x11-libs/gtksourceview-3.21.2:3.0[introspection?]
+ >=dev-libs/libpeas-1.14.1[gtk]
+
+ gnome-base/gsettings-desktop-schemas
+ gnome-base/gvfs
+
+ x11-libs/libX11
+
+ introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+ python? (
+ ${PYTHON_DEPS}
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ >=dev-python/pygobject-3:3[cairo,${PYTHON_USEDEP}]
+ dev-libs/libpeas[python,${PYTHON_USEDEP}] )
+ spell? ( >=app-text/gspell-0.2.5:0= )
+"
+RDEPEND="${COMMON_DEPEND}
+ x11-themes/adwaita-icon-theme
+"
+DEPEND="${COMMON_DEPEND}
+ ${vala_depend}
+ app-text/docbook-xml-dtd:4.1.2
+ app-text/yelp-tools
+ >=dev-util/gtk-doc-am-1
+ >=dev-util/intltool-0.50.1
+ >=sys-devel/gettext-0.18
+ virtual/pkgconfig
+"
+# yelp-tools, gnome-common needed to eautoreconf
+
+pkg_setup() {
+ use python && [[ ${MERGE_TYPE} != binary ]] && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ vala_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+
+ gnome2_src_configure \
+ --disable-deprecations \
+ --disable-updater \
+ --enable-gvfs-metadata \
+ $(use_enable introspection) \
+ $(use_enable spell) \
+ $(use_enable python) \
+ $(use_enable vala)
+}
+
+src_test() {
+ "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+ GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check
+}
+
+src_install() {
+ local args=()
+ # manually set pyoverridesdir due to bug #524018 and AM_PATH_PYTHON limitations
+ use python && args+=( pyoverridesdir="$(python_get_sitedir)/gi/overrides" )
+
+ gnome2_src_install "${args[@]}"
+}