[gentoo-commits] repo/gentoo:master commit in: sci-geosciences/gpsbabel/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     3c84571e219c5428b967f3401953b45bc293f4d1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 15 07:48:10 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Jun 15 07:48:10 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c84571e

sci-geosciences/gpsbabel: Fix icon/.desktop install

Stable revbump to add missing eutils.eclass.

Thanks-to: Siuchung Cheung (Clement) <clement.cc <AT> gmail.com>
Gentoo-bug: 621814

Package-Manager: Portage-2.3.5, Repoman-2.3.1

 sci-geosciences/gpsbabel/gpsbabel-1.5.4-r1.ebuild | 114 ++++++++++++++++++++++
 1 file changed, 114 insertions(+)

diff --git a/sci-geosciences/gpsbabel/gpsbabel-1.5.4-r1.ebuild b/sci-geosciences/gpsbabel/gpsbabel-1.5.4-r1.ebuild
new file mode 100644
index 00000000000..2b4af46ab15
--- /dev/null
+++ b/sci-geosciences/gpsbabel/gpsbabel-1.5.4-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils qmake-utils
+
+DESCRIPTION="GPS waypoints, tracks and routes converter"
+HOMEPAGE="http://www.gpsbabel.org/ https://github.com/gpsbabel/gpsbabel"
+SRC_URI="
+	https://dev.gentoo.org/~asturm/${P}.tar.gz
+	doc? ( http://www.gpsbabel.org/style3.css -> gpsbabel.org-style3.css )"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="amd64 ~ppc x86 ~x86-fbsd"
+IUSE="doc +gui"
+
+RDEPEND="
+	dev-libs/expat
+	dev-qt/qtcore:5
+	sci-libs/shapelib:=
+	sys-libs/zlib[minizip]
+	virtual/libusb:0
+	gui? (
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwebchannel:5
+		dev-qt/qtwebengine:5[widgets]
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+	gui? ( dev-qt/linguist:5 )
+"
+
+DOCS=( AUTHORS README.{contrib,igc,mapconverter,md,xmapwpt} )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.4.3-fix_binary_name.patch"
+	"${FILESDIR}/${P}-disable_statistic_uploading.patch"
+	"${FILESDIR}/${P}-disable_update_check.patch"
+	"${FILESDIR}/${P}-disable_version_check.patch"
+	"${FILESDIR}/${P}-use_system_shapelib.patch"
+	"${FILESDIR}/${P}-use_system_zlib.patch"
+	"${FILESDIR}/${P}-xmldoc.patch"
+)
+
+RESTRICT="test" # bug 421699
+
+src_prepare() {
+	default
+
+	# remove bundled libs and cleanup
+	rm -r shapelib zlib || die
+	sed -i -e "s: zlib\/[a-z]*\.h::g" Makefile.in || die
+
+	mv configure.in configure.ac || die
+	sed -i -e "/^configure:/s/configure.in/configure.ac/" Makefile.in || die
+
+	use doc && cp "${DISTDIR}/gpsbabel.org-style3.css" "${S}"
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with doc doc "${S}"/doc/manual) \
+		LRELEASE=$(qt5_get_bindir)/lrelease \
+		LUPDATE=$(qt5_get_bindir)/lupdate \
+		QMAKE=$(qt5_get_bindir)/qmake \
+		--with-zlib=system
+
+	if use gui; then
+		pushd "${S}/gui" > /dev/null || die
+		lrelease *.ts || die
+		eqmake5
+		popd > /dev/null
+	fi
+}
+
+src_compile() {
+	default
+	if use gui; then
+		pushd "${S}/gui" > /dev/null || die
+		emake
+		popd > /dev/null
+	fi
+
+	if use doc; then
+		perl xmldoc/makedoc || die
+		emake gpsbabel.html
+	fi
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${S}"/${PN}.html "${S}"/${PN}.org-style3.css )
+
+	default
+
+	if use gui; then
+		dobin gui/objects/gpsbabelfe
+		insinto /usr/share/${PN}/translations/
+		doins gui/gpsbabel*_*.qm
+		newicon gui/images/appicon.png ${PN}.png
+		make_desktop_entry gpsbabelfe ${PN} ${PN} "Science;Geoscience"
+	fi
+}