[gentoo-commits] repo/gentoo:master commit in: media-video/smtube/

["Daniel Campbell" <zlg@gentoo.org>]

commit:     61dbfd2cdd29094de8ebd2b5bf4d4a5c7ab4b771
Author:     Daniel Campbell <zlg <AT> gentoo <DOT> org>
AuthorDate: Sun Jun  4 08:17:36 2017 +0000
Commit:     Daniel Campbell <zlg <AT> gentoo <DOT> org>
CommitDate: Sun Jun  4 08:18:08 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61dbfd2c

media-video/smtube: revbump wrt bug 620720

Gentoo-Bug: 620720
Gentoo-Bug-URL: https://bugs.gentoo.org/620720
Package-Manager: Portage-2.3.6, Repoman-2.3.2

 media-video/smtube/smtube-17.5.0-r1.ebuild | 61 ++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/media-video/smtube/smtube-17.5.0-r1.ebuild b/media-video/smtube/smtube-17.5.0-r1.ebuild
new file mode 100644
index 00000000000..36fd97f768d
--- /dev/null
+++ b/media-video/smtube/smtube-17.5.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="bg cs da de en_GB en es eu fr gl he_IL hr hu it ja ko ms nn_NO pl pt_BR pt ru sq sr tr uk zh_CN zh_TW"
+PLOCALE_BACKUP="en"
+
+inherit l10n qmake-utils
+
+DESCRIPTION="YouTube Browser for SMPlayer"
+HOMEPAGE="http://smplayer.sourceforge.net/smtube"
+SRC_URI="mirror://sourceforge/smtube/${P}.tar.bz2"
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-2+"
+SLOT="0"
+
+# Deps in makefile seemed to be -core, -network, -script, -gui, -webkit, but the
+# given packages seem to be deprecated...
+CDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtscript:5
+"
+DEPEND="
+	${CDEPEND}
+	dev-qt/linguist-tools:5
+"
+RDEPEND="
+	${CDEPEND}
+	|| ( media-video/smplayer[streaming] media-video/mpv media-video/mplayer media-video/vlc media-video/totem media-video/gnome-mplayer )
+"
+
+gen_translation() {
+	"$(qt5_get_bindir)"/lrelease ${PN}_${1}.ts
+	eend $? || die "failed to generate $1 translation"
+}
+
+src_compile() {
+	eqmake5 src/${PN}.pro
+	emake
+
+	cd "${S}"/src/translations
+	l10n_for_each_locale_do gen_translation
+}
+
+install_locale() {
+	insinto /usr/share/${PN}/translations
+	doins "${S}"/src/translations/${PN}_${1}.qm
+	eend $? || die "failed to install $1 translation"
+}
+
+src_install() {
+	dobin ${PN}
+	domenu ${PN}.desktop
+	newicon icons/${PN}_64.png ${PN}.png
+	dodoc Changelog
+
+	l10n_for_each_locale_do install_locale
+}