[gentoo-commits] repo/gentoo:master commit in: dev-python/zope-interface/

["Michał Górny" <mgorny@gentoo.org>]

commit:     2fb75581c291cd4366e033f1dfb768a13846808c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May  4 16:56:40 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May  7 18:43:18 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2fb75581

dev-python/zope-interface: Use dev-python/namespace-zope

 .../zope-interface/zope-interface-4.4.0-r1.ebuild  | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-python/zope-interface/zope-interface-4.4.0-r1.ebuild b/dev-python/zope-interface/zope-interface-4.4.0-r1.ebuild
new file mode 100644
index 00000000000..2c219319fbd
--- /dev/null
+++ b/dev-python/zope-interface/zope-interface-4.4.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Interfaces for Python"
+HOMEPAGE="https://pypi.python.org/pypi/zope.interface https://github.com/zopefoundation/zope.interface"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND="dev-python/namespace-zope[${PYTHON_USEDEP}]"
+DEPEND=">=dev-python/setuptools-33.1.1[${PYTHON_USEDEP}]
+	test? ( dev-python/zope-event[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}"
+		append-flags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}