[gentoo-commits] repo/gentoo:master commit in: app-emulation/libvirt/

["Matthias Maier" <tamiko@gentoo.org>]

commit:     a16940bd81e81b2b89ff45c5f894fd81a4346f76
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 14 15:48:41 2017 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Fri Apr 14 15:55:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a16940bd

app-emulation/libvirt: bump to version 3.2.0, bug #615162

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 app-emulation/libvirt/Manifest             |   1 +
 app-emulation/libvirt/libvirt-3.2.0.ebuild | 382 +++++++++++++++++++++++++++++
 2 files changed, 383 insertions(+)

diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index 49763d3925a..84b6a1f9c40 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -4,3 +4,4 @@ DIST libvirt-2.1.0.tar.xz 13212368 SHA256 1a799562337472ab00f76aa30a53d54c623c96
 DIST libvirt-2.3.0.tar.xz 13224384 SHA256 e430e69b27d3f6c97255e638617b59b179618d531d81ac7dfe0783a1c1eeafd1 SHA512 b815704a7d021895e94f34551f783b053f4dce3d6f792e0734b98745b8bd895ddb30250b3cf9b1ecc61bb2f09073a51bc75edb2745591d22d6a7ef2935eac701 WHIRLPOOL d27df68a6464e763fb119d8926ba9d4ad1e47fa37e08aa14adeb3684d2675bb0d7be69b17e22e98fffe281393d37a4c7fdd318e1641e0a6767fcab63d5a790e5
 DIST libvirt-2.5.0.tar.xz 13638636 SHA256 819dffefbfd6ae95dfe1b28cfdee15ebcf9f91bbd732157488a57705bf81cb1e SHA512 256d6cae635851d710ffa3bdfd6b4d744687610b899a65821829af0f66a65e9c4ae287c8651534b40fc04f6525920b3704e90028a6f906af141cd61f2e79d10c WHIRLPOOL 64ef68bba5b2b47ef8c191c3cadc8121267fc07f6fdc40f7969b3762bab222872b987ad8d04b22c2f6d6629d7599a7ff3263b3491f0143d59a172b269d81284c
 DIST libvirt-3.1.0.tar.xz 13906204 SHA256 7879029a0fcac4e58dbeec66f0bc77771565c4b6667212c8f6251eefb03732a9 SHA512 e08c82aa3c06b2ea7615b71937fa16e7ae52cb82350bacaefcac1a872471bbbf993e20b4b14f5bb4d7c539be18c42b377df9100b493d3873b5fd5f1f67449e17 WHIRLPOOL 7fdb068a95575499115eb542342e2d133c3d877df3190f40f97de4f2f0af67fdc722c3d1bcaeea14306dcf94ff4a013bd5e60736e7866de3ae56e662df7c5dc4
+DIST libvirt-3.2.0.tar.xz 14057340 SHA256 9481a083b567a07927f239553dd70b5c0d1bff5b9b4ec61be1899981c646209e SHA512 35a9db3d59a3817d15fd6a586a2a73860b3d8a2d2ff37dbea1b4045fe1514c3535fce2eeba0f09df2d0bb9072ed9f1078ca9bad61a37c586eb019ddad3f898c4 WHIRLPOOL 499eb2cbf1367c99c106a747c76087f6ed980cc057cdb10cefe50a8a823a294f67925c98b1baa6ac7e12dcc20c90145b9a0c1e0927772e3b4a046bb4414391a0

diff --git a/app-emulation/libvirt/libvirt-3.2.0.ebuild b/app-emulation/libvirt/libvirt-3.2.0.ebuild
new file mode 100644
index 00000000000..674ea5e9798
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-3.2.0.ebuild
@@ -0,0 +1,382 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils user linux-info systemd readme.gentoo-r1
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://libvirt.org/libvirt.git"
+	SRC_URI=""
+	KEYWORDS=""
+	SLOT="0"
+else
+	# Versions with 4 numbers are stable updates:
+	if [[ ${PV} =~ ^[0-9]+(\.[0-9]+){3} ]]; then
+		SRC_URI="http://libvirt.org/sources/stable_updates/${P}.tar.xz"
+	else
+		SRC_URI="http://libvirt.org/sources/${P}.tar.xz"
+	fi
+	KEYWORDS="~amd64 ~x86"
+	SLOT="0/${PV}"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="http://www.libvirt.org/"
+LICENSE="LGPL-2.1"
+IUSE="
+	apparmor audit +caps +dbus firewalld fuse glusterfs iscsi +libvirtd lvm
+	libssh lxc +macvtap nfs nls numa openvz parted pcap phyp policykit
+	+qemu rbd sasl selinux +udev uml +vepa virtualbox virt-network
+	wireshark-plugins xen zeroconf zfs elibc_glibc
+"
+
+REQUIRED_USE="
+	firewalld? ( virt-network )
+	libvirtd? ( || ( lxc openvz qemu uml virtualbox xen ) )
+	lxc? ( caps libvirtd )
+	openvz? ( libvirtd )
+	policykit? ( dbus )
+	qemu? ( libvirtd )
+	uml? ( libvirtd )
+	vepa? ( macvtap )
+	virt-network? ( libvirtd )
+	virtualbox? ( libvirtd )
+	xen? ( libvirtd )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent
+RDEPEND="
+	app-misc/scrub
+	dev-libs/libgcrypt:0
+	dev-libs/libnl:3
+	>=dev-libs/libxml2-2.7.6
+	|| ( >=net-analyzer/netcat6-1.0-r2 >=net-analyzer/openbsd-netcat-1.105-r1 )
+	>=net-libs/gnutls-1.0.25:0=
+	net-libs/libssh2
+	>=net-misc/curl-7.18.0
+	sys-apps/dmidecode
+	>=sys-apps/util-linux-2.17
+	sys-devel/gettext
+	sys-libs/ncurses:0=
+	sys-libs/readline:=
+	apparmor? ( sys-libs/libapparmor )
+	audit? ( sys-process/audit )
+	caps? ( sys-libs/libcap-ng )
+	dbus? ( sys-apps/dbus )
+	elibc_glibc? ( sys-libs/glibc[rpc(+)] )
+	firewalld? ( net-firewall/firewalld )
+	fuse? ( >=sys-fs/fuse-2.8.6 )
+	glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+	iscsi? ( sys-block/open-iscsi )
+	libssh? ( net-libs/libssh )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2[-device-mapper-only(-)] )
+	nfs? ( net-fs/nfs-utils )
+	numa? (
+		>sys-process/numactl-2.0.2
+		sys-process/numad
+	)
+	openvz? ( sys-kernel/openvz-sources:* )
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2[-device-mapper-only(-)]
+	)
+	pcap? ( >=net-libs/libpcap-1.0.0 )
+	policykit? ( >=sys-auth/polkit-0.9 )
+	qemu? (
+		>=app-emulation/qemu-0.13.0
+		dev-libs/yajl
+	)
+	rbd? ( sys-cluster/ceph )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virt-network? (
+		net-dns/dnsmasq[script]
+		net-firewall/ebtables
+		>=net-firewall/iptables-1.4.10[ipv6]
+		net-misc/radvd
+		sys-apps/iproute2[-minimal]
+	)
+	virtualbox? ( || ( app-emulation/virtualbox >=app-emulation/virtualbox-bin-2.2.0 ) )
+	wireshark-plugins? ( net-analyzer/wireshark:= )
+	xen? (
+		app-emulation/xen
+		app-emulation/xen-tools:=
+	)
+	udev? (
+		virtual/udev
+		>=x11-libs/libpciaccess-0.10.9
+	)
+	zeroconf? ( >=net-dns/avahi-0.6[dbus] )
+	zfs? ( sys-fs/zfs )"
+
+DEPEND="${RDEPEND}
+	app-text/xhtml1
+	dev-lang/perl
+	dev-libs/libxslt
+	dev-perl/XML-XPath
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.0-do_not_use_sysconf.patch
+	"${FILESDIR}"/${PN}-1.2.16-fix_paths_in_libvirt-guests_sh.patch
+	"${FILESDIR}"/${PN}-3.0.0-fix_paths_for_apparmor.patch
+	"${FILESDIR}"/${PN}-1.3.4-glibc-2.23.patch
+	"${FILESDIR}"/${PN}-3.1.0-musl-fix-includes.patch # bug #609488
+)
+
+pkg_setup() {
+	if use qemu; then
+		enewgroup qemu 77
+		enewuser qemu 77 -1 -1 "qemu,kvm"
+	fi
+
+	use policykit && enewgroup libvirt
+
+	# Check kernel configuration:
+	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+="
+		~FUSE_FS"
+
+	use lvm && CONFIG_CHECK+="
+		~BLK_DEV_DM
+		~DM_MULTIPATH
+		~DM_SNAPSHOT"
+
+	use lxc && CONFIG_CHECK+="
+		~BLK_CGROUP
+		~CGROUP_CPUACCT
+		~CGROUP_DEVICE
+		~CGROUP_FREEZER
+		~CGROUP_NET_PRIO
+		~CGROUP_PERF
+		~CGROUPS
+		~CGROUP_SCHED
+		~CPUSETS
+		~IPC_NS
+		~MACVLAN
+		~NAMESPACES
+		~NET_CLS_CGROUP
+		~NET_NS
+		~PID_NS
+		~POSIX_MQUEUE
+		~SECURITYFS
+		~USER_NS
+		~UTS_NS
+		~VETH
+		~!GRKERNSEC_CHROOT_MOUNT
+		~!GRKERNSEC_CHROOT_DOUBLE
+		~!GRKERNSEC_CHROOT_PIVOT
+		~!GRKERNSEC_CHROOT_CHMOD
+		~!GRKERNSEC_CHROOT_CAPS"
+
+	kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
+		~DEVPTS_MULTIPLE_INSTANCES"
+
+	use macvtap && CONFIG_CHECK+="
+		~MACVTAP"
+
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_MARK_T
+		~BRIDGE_NF_EBTABLES
+		~NETFILTER_ADVANCED
+		~NETFILTER_XT_CONNMARK
+		~NETFILTER_XT_MARK
+		~NETFILTER_XT_TARGET_CHECKSUM"
+	# Bandwidth Limiting Support
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_T_NAT
+		~NET_ACT_POLICE
+		~NET_CLS_FW
+		~NET_CLS_U32
+		~NET_SCH_HTB
+		~NET_SCH_INGRESS
+		~NET_SCH_SFQ"
+
+	# Handle specific kernel versions for different features
+	kernel_is lt 3 6 && CONFIG_CHECK+=" ~CGROUP_MEM_RES_CTLR"
+	if kernel_is ge 3 6; then
+		CONFIG_CHECK+=" ~MEMCG ~MEMCG_SWAP "
+		kernel_is lt 4 5 && CONFIG_CHECK+=" ~MEMCG_KMEM "
+	fi
+
+	ERROR_USER_NS="Optional depending on LXC configuration."
+
+	if [[ -n ${CONFIG_CHECK} ]]; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	touch "${S}/.mailmap"
+
+	default
+
+	if [[ ${PV} = *9999* ]]; then
+		# git checkouts require bootstrapping to create the configure script.
+		# Additionally the submodules must be cloned to the right locations
+		# bug #377279
+		./bootstrap || die "bootstrap failed"
+		(
+			git submodule status | sed 's/^[ +-]//;s/ .*//'
+			git hash-object bootstrap.conf
+		) >.git-module-status
+	fi
+
+	# Tweak the init script:
+	cp "${FILESDIR}/libvirtd.init-r16" "${S}/libvirtd.init" || die
+	sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+		-e "s/USE_FLAG_AVAHI/$(usex zeroconf 'use avahi-daemon' '')/" \
+		-e "s/USE_FLAG_ISCSI/$(usex iscsi 'use iscsid' '')/" \
+		-e "s/USE_FLAG_RBD/$(usex rbd 'use ceph' '')/" \
+		-i "${S}/libvirtd.init" || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with apparmor)
+		$(use_with apparmor apparmor-profiles)
+		$(use_with audit)
+		$(use_with caps capng)
+		$(use_with dbus)
+		$(use_with firewalld)
+		$(use_with fuse)
+		$(use_with glusterfs)
+		$(use_with glusterfs storage-gluster)
+		$(use_with iscsi storage-iscsi)
+		$(use_with libvirtd)
+		$(use_with libssh)
+		$(use_with lvm storage-lvm)
+		$(use_with lvm storage-mpath)
+		$(use_with lxc)
+		$(use_with macvtap)
+		$(use_enable nls)
+		$(use_with numa numactl)
+		$(use_with numa numad)
+		$(use_with openvz)
+		$(use_with parted storage-disk)
+		$(use_with pcap libpcap)
+		$(use_with phyp)
+		$(use_with policykit polkit)
+		$(use_with qemu)
+		$(use_with qemu yajl)
+		$(use_with rbd storage-rbd)
+		$(use_with sasl)
+		$(use_with selinux)
+		$(use_with udev)
+		$(use_with uml)
+		$(use_with vepa virtualport)
+		$(use_with virt-network network)
+		$(use_with wireshark-plugins wireshark-dissector)
+		$(use_with xen)
+		$(use_with xen xen-inotify)
+		$(use_with xen libxl)
+		$(use_with zeroconf avahi)
+		$(use_with zfs storage-zfs)
+
+		--without-hal
+		--without-netcf
+		--without-sanlock
+		--without-xenapi
+
+		--with-esx
+		--with-init-script=systemd
+		--with-qemu-group=$(usex caps qemu root)
+		--with-qemu-user=$(usex caps qemu root)
+		--with-remote
+		--with-storage-fs
+		--with-vmware
+
+		--disable-static
+		--disable-werror
+
+		--with-html-subdir=${PF}/html
+		--localstatedir=/var
+	)
+
+	if use virtualbox && has_version app-emulation/virtualbox-ose; then
+		myeconfargs+=( --with-vbox=/usr/lib/virtualbox-ose/ )
+	else
+		myeconfargs+=( $(use_with virtualbox vbox) )
+	fi
+
+	econf "${myeconfargs[@]}"
+
+	if [[ ${PV} = *9999* ]]; then
+		# Restore gnulib's config.sub and config.guess
+		# bug #377279
+		(cd .gnulib && git reset --hard > /dev/null)
+	fi
+}
+
+src_test() {
+	cd "${BUILD_DIR}"
+
+	# remove problematic tests, bug #591416, bug #591418
+	sed -i -e 's#commandtest$(EXEEXT) # #' \
+		-e 's#virfirewalltest$(EXEEXT) # #' \
+		-e 's#nwfilterebiptablestest$(EXEEXT) # #' \
+		-e 's#nwfilterxml2firewalltest$(EXEEXT)$##' \
+		tests/Makefile
+
+	export VIR_TEST_DEBUG=1
+	HOME="${T}" emake check || die "tests failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" \
+		SYSTEMD_UNIT_DIR="$(systemd_get_systemunitdir)" install
+
+	find "${D}" -name '*.la' -delete || die
+
+	# Remove bogus, empty directories. They are either not used, or
+	# libvirtd is able to create them on demand
+	rm -rf "${D}"/etc/sysconfig
+	rm -rf "${D}"/var/cache
+	rm -rf "${D}"/var/run
+	rm -rf "${D}"/var/log
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	systemd_install_serviced \
+		"${FILESDIR}"/libvirtd.service.conf libvirtd.service
+
+	systemd_newtmpfilesd "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+	newinitd "${S}/libvirtd.init" libvirtd || die
+	newinitd "${FILESDIR}/libvirt-guests.init-r2" libvirt-guests || die
+	newinitd "${FILESDIR}/virtlockd.init-r1" virtlockd || die
+	newinitd "${FILESDIR}/virtlogd.init-r1" virtlogd || die
+
+	newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd || die
+	newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests || die
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r2")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# we only ever want to generate this once
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
+	fi
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	readme.gentoo_print_elog
+}