[gentoo-commits] repo/gentoo:master commit in: net-im/pidgin/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     537cb9899b69046682bbf4866d69ad6f03d70e7b
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 10 11:14:23 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Mar 10 11:30:03 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=537cb989

net-im/pidgin: Security bump to version 2.12.0 (bug #612188).

Package-Manager: Portage-2.3.4, Repoman-2.3.2

 net-im/pidgin/Manifest             |   1 +
 net-im/pidgin/pidgin-2.12.0.ebuild | 268 +++++++++++++++++++++++++++++++++++++
 2 files changed, 269 insertions(+)

diff --git a/net-im/pidgin/Manifest b/net-im/pidgin/Manifest
index 077e205c62a..0a23d64282e 100644
--- a/net-im/pidgin/Manifest
+++ b/net-im/pidgin/Manifest
@@ -1,3 +1,4 @@
 DIST pidgin-2.10.9-irc_join_sleep.patch 534 SHA256 ee061505d04c994a36ea1d5eef346b7cbb2512afafa4985a678205ea69d87857 SHA512 8de0d6f05e48cd5a3e894576e06c7fb82e4bfc778cce8bb179fa22e2a05f5c2390a0e4c5b626ee4b910a18eab170d8f4be200f435ce408a86575af99e51e3bdf WHIRLPOOL 7aa9aa9e5ee7d97445da2c330329c6bfd4ad21347f43220e8377b7ec40eb5eac417be08cddfcdd48c7f847aac00a0f9ab39d0add09f1bee519f96f7586bdf5c9
 DIST pidgin-2.11.0.tar.bz2 10037480 SHA256 f72613440586da3bdba6d58e718dce1b2c310adf8946de66d8077823e57b3333 SHA512 d6a9bb8075b475e5204d730075b432ca0f1cb91b6337f98e506587132581e6928a826b47e0b94fb9eaedc79c5be0a8237c4671fc26dba97dedad1adb74c9abfa WHIRLPOOL e7f91d92bece8611986c35f17d3d263a197f8c7cf71d514d1f409fbe31fd57cf8a1beabab3d028a0882a79a115ae021b2e64dd2c6b3ec6c29a783a3df28af948
+DIST pidgin-2.12.0.tar.bz2 9270704 SHA256 8c3d3536d6d3c971bd433ff9946678af70a0f6aa4e6969cc2a83bb357015b7f8 SHA512 e87b39888432982ee36332fd14b272f49f7974de9e8694f7fe3bec2821748d6e6026ac5a63615a93386a033d6ee7c4de5ae0a86b725f63b9cc55650f0ab94b06 WHIRLPOOL 7dc2ed772825169a10b5cf74ef370c1f2c0916a340e472e40b0681a9924fd57f9d67e1701051f571f79d8201ef0d8143e81d87e402aff651f63e6b9b39c80b48
 DIST pidgin-eds-3.6.patch.bz2 2352 SHA256 321185dd5f44e502f671b17e84fa1ca2e08a3f7c79ed211c0bb92710700bcc41 SHA512 a0195679ab55ed9c7ea18ace6dbf0fc994698f1f4eea9d8335dfdcdcd6a68975c0191bd22f150bf5a9a0a691ce7e9e73d79598e1e8be541efa1d9824a633d877 WHIRLPOOL 5c1d3e933bdfa4b1f20f98dbf8b5c1669eb857b9db60dacae488fa04331300618df2f1265e4fb2e58ed31b24229df0edb8c30970d8172fd65ca7fa03bc0e3805

diff --git a/net-im/pidgin/pidgin-2.12.0.ebuild b/net-im/pidgin/pidgin-2.12.0.ebuild
new file mode 100644
index 00000000000..dca95d403d4
--- /dev/null
+++ b/net-im/pidgin/pidgin-2.12.0.ebuild
@@ -0,0 +1,268 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GENTOO_DEPEND_ON_PERL=no
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools flag-o-matic gnome2 toolchain-funcs multilib perl-module python-single-r1
+
+DESCRIPTION="GTK Instant Messenger client"
+HOMEPAGE="http://pidgin.im/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.bz2
+	https://dev.gentoo.org/~polynomial-c/${PN}-eds-3.6.patch.bz2
+	https://gist.githubusercontent.com/imcleod/77f38d11af11b2413ada/raw/46e9d6cb4d2f839832dad2d697bb141a88028e04/pidgin-irc-join-sleep.patch -> ${PN}-2.10.9-irc_join_sleep.patch"
+
+LICENSE="GPL-2"
+SLOT="0/2" # libpurple version
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="dbus debug doc eds gadu gnutls +gstreamer +gtk idn meanwhile pie"
+IUSE+=" networkmanager nls perl silc tcl tk spell sasl ncurses"
+IUSE+=" groupwise prediction python +xscreensaver zephyr zeroconf" # mono"
+IUSE+=" aqua"
+
+# dbus requires python to generate C code for dbus bindings (thus DEPEND only).
+# finch uses libgnt that links with libpython - {R,}DEPEND. But still there is
+# no way to build dbus and avoid libgnt linkage with python. If you want this
+# send patch upstream.
+# purple-url-handler and purple-remote require dbus-python thus in reality we
+# rdepend on python if dbus enabled. But it is possible to separate this dep.
+RDEPEND="
+	>=dev-libs/glib-2.16
+	>=dev-libs/libxml2-2.6.18
+	ncurses? (
+		sys-libs/ncurses:0=[unicode]
+		dbus? ( ${PYTHON_DEPS} )
+		python? ( ${PYTHON_DEPS} )
+	)
+	gtk? (
+		>=x11-libs/gtk+-2.10:2[aqua=]
+		x11-libs/libSM
+		xscreensaver? ( x11-libs/libXScrnSaver )
+		spell? ( >=app-text/gtkspell-2.0.2:2 )
+		eds? ( >=gnome-extra/evolution-data-server-3.6:= )
+		prediction? ( >=dev-db/sqlite-3.3:3 )
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		>=net-libs/farstream-0.2.7:0.2
+	)
+	zeroconf? ( net-dns/avahi[dbus] )
+	dbus? (
+		>=dev-libs/dbus-glib-0.71
+		>=sys-apps/dbus-0.90
+		dev-python/dbus-python
+	)
+	perl? ( >=dev-lang/perl-5.16:= )
+	gadu? (
+		|| (
+			>=net-libs/libgadu-1.11.0[ssl,gnutls]
+			>=net-libs/libgadu-1.11.0[-ssl]
+		)
+	)
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		dev-libs/nspr
+		dev-libs/nss
+	)
+	meanwhile? ( net-libs/meanwhile )
+	silc? ( >=net-im/silc-toolkit-1.0.1 )
+	tcl? ( dev-lang/tcl:0= )
+	tk? ( dev-lang/tk:0= )
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	networkmanager? ( net-misc/networkmanager )
+	idn? ( net-dns/libidn )
+	!<x11-plugins/pidgin-facebookchat-1.69-r1"
+	# Mono support crashes pidgin
+	#mono? ( dev-lang/mono )"
+
+# We want nls in case gtk is enabled, bug #
+NLS_DEPEND=">=dev-util/intltool-0.41.1 sys-devel/gettext"
+
+DEPEND="$RDEPEND
+	dev-lang/perl
+	dev-perl/XML-Parser
+	virtual/pkgconfig
+	gtk? (
+		x11-proto/scrnsaverproto
+		${NLS_DEPEND}
+	)
+	dbus? ( ${PYTHON_DEPS} )
+	doc? ( app-doc/doxygen )
+	!gtk? ( nls? ( ${NLS_DEPEND} ) )"
+
+DOCS="AUTHORS HACKING NEWS README ChangeLog"
+
+REQUIRED_USE="
+	dbus? ( ${PYTHON_REQUIRED_USE} )
+	networkmanager? ( dbus )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+# Enable Default protocols
+DYNAMIC_PRPLS="irc,jabber,oscar,simple"
+
+# List of plugins
+#   app-accessibility/pidgin-festival
+#   net-im/librvp
+#   x11-plugins/guifications
+#	x11-plugins/msn-pecan
+#   x11-plugins/pidgin-encryption
+#   x11-plugins/pidgin-extprefs
+#   x11-plugins/pidgin-hotkeys
+#   x11-plugins/pidgin-latex
+#   x11-plugins/pidgintex
+#   x11-plugins/pidgin-libnotify
+#	x11-plugins/pidgin-mbpurple
+#	x11-plugins/pidgin-bot-sentry
+#   x11-plugins/pidgin-otr
+#   x11-plugins/pidgin-rhythmbox
+#   x11-plugins/purple-plugin_pack
+#   x11-themes/pidgin-smileys
+#	x11-plugins/pidgin-knotify
+# Plugins in Sunrise:
+#	x11-plugins/pidgin-audacious-remote
+#	x11-plugins/pidgin-autoanswer
+#	x11-plugins/pidgin-birthday-reminder
+#	x11-plugins/pidgin-blinklight
+#	x11-plugins/pidgin-convreverse
+#	x11-plugins/pidgin-embeddedvideo
+#	x11-plugins/pidgin-extended-blist-sort
+#	x11-plugins/pidgin-gfire
+#	x11-plugins/pidgin-lastfm
+#	x11-plugins/pidgin-sendscreenshot
+#	x11-plugins/pidgimpd
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10.0-gold.patch"
+	"${WORKDIR}/${PN}-eds-3.6.patch"
+	"${FILESDIR}/${PN}-2.10.9-fix-gtkmedia.patch"
+	"${FILESDIR}/${PN}-2.10.10-eds-3.6-configure.ac.patch"
+	"${FILESDIR}/${PN}-2.10.11-tinfo.patch"
+	"${DISTDIR}/${PN}-2.10.9-irc_join_sleep.patch" # 577286
+)
+
+pkg_setup() {
+	if ! use gtk && ! use ncurses ; then
+		elog "You did not pick the ncurses or gtk use flags, only libpurple"
+		elog "will be built."
+	fi
+	if use python || use dbus ; then
+		python-single-r1_pkg_setup
+	fi
+
+	# dbus is enabled, no way to disable linkage with python => python is enabled
+	#REQUIRED_USE="gtk? ( nls ) dbus? ( python )"
+	if use gtk && ! use nls; then
+		ewarn "gtk build => nls is enabled!"
+	fi
+	if use dbus && ! use python; then
+		elog "dbus is enabled, no way to disable linkage with python => python is enabled"
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Stabilize things, for your own good
+	strip-flags
+	replace-flags -O? -O2
+	use pie && append-cflags -fPIE -pie
+
+	local myconf=()
+
+	use gadu 	&& DYNAMIC_PRPLS+=",gg"
+	use groupwise 	&& DYNAMIC_PRPLS+=",novell"
+	use silc 	&& DYNAMIC_PRPLS+=",silc"
+	use meanwhile 	&& DYNAMIC_PRPLS+=",sametime"
+	use zephyr 	&& DYNAMIC_PRPLS+=",zephyr"
+	use zeroconf 	&& DYNAMIC_PRPLS+=",bonjour"
+
+	if use gnutls; then
+		einfo "Disabling NSS, using GnuTLS"
+		myconf+=( --enable-nss=no --enable-gnutls=yes )
+		myconf+=( --with-gnutls-includes="${EPREFIX}/usr/include/gnutls" )
+		myconf+=( --with-gnutls-libs="${EPREFIX}/usr/$(get_libdir)" )
+	else
+		einfo "Disabling GnuTLS, using NSS"
+		myconf+=( --enable-gnutls=no --enable-nss=yes )
+	fi
+
+	if use dbus || { use ncurses && use python ; } ; then
+		myconf+=( --with-python=${PYTHON} )
+	else
+		myconf+=( --without-python )
+	fi
+
+	local myeconfargs=(
+		--disable-mono
+		--with-dynamic-prpls="${DYNAMIC_PRPLS}"
+		--with-system-ssl-certs="${EPREFIX}/etc/ssl/certs/"
+		--x-includes="${EPREFIX}"/usr/include/X11
+		$(use_enable ncurses consoleui)
+		$(use_enable gtk gtkui)
+		$(use_enable gtk sm)
+		$(usex gtk '--enable-nls' "$(use_enable nls)")
+		$(use gtk && use_enable xscreensaver screensaver)
+		$(use gtk && use_enable prediction cap)
+		$(use gtk && use_enable eds gevolution)
+		$(use gtk && use_enable spell gtkspell)
+		$(use_enable perl)
+		$(use_enable tk)
+		$(use_enable tcl)
+		$(use_enable debug)
+		$(use_enable dbus)
+		$(use_enable meanwhile)
+		$(use_enable gstreamer)
+		$(use_with gstreamer gstreamer 1.0)
+		$(use_enable gstreamer farstream)
+		$(use_enable gstreamer vv)
+		$(use_enable sasl cyrus-sasl )
+		$(use_enable doc doxygen)
+		$(use_enable networkmanager nm)
+		$(use_enable zeroconf avahi)
+		$(use_enable idn)
+		${myconf[@]}
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use gtk; then
+		# Fix tray pathes for e16 (x11-wm/enlightenment) and other
+		# implementations that are not complient with new hicolor theme yet, #323355
+		local pixmapdir
+		for d in 16 22 32 48; do
+			pixmapdir=${ED}/usr/share/pixmaps/pidgin/tray/hicolor/${d}x${d}/actions
+			mkdir "${pixmapdir}" || die
+			pushd "${pixmapdir}" >/dev/null || die
+			for f in ../status/*; do
+				ln -s ${f} || die
+			done
+			popd >/dev/null
+		done
+	fi
+	use perl && perl_delete_localpod
+
+	if use python && use dbus ; then
+		python_fix_shebang "${D}"
+		python_optimize
+	fi
+
+	dodoc ${DOCS} finch/plugins/pietray.py
+	docompress -x /usr/share/doc/${PF}/pietray.py
+
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
+
+src_test() {
+	emake check
+}