[gentoo-commits] repo/gentoo:master commit in: net-analyzer/mtr/

["Fabian Groffen" <grobian@gentoo.org>]

commit:     e5099643edcd981586507f486a885fd797cd7be3
Author:     Fabian Groffen <grobian <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  4 21:15:03 2017 +0000
Commit:     Fabian Groffen <grobian <AT> gentoo <DOT> org>
CommitDate: Sat Feb  4 21:15:56 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5099643

net-analyzer/mtr: fix filecaps problem in Prefix, bug #599604

Package-Manager: portage-2.3.3

 net-analyzer/mtr/mtr-0.87-r1.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 net-analyzer/mtr/mtr-9999.ebuild    | 10 ++++++-
 2 files changed, 69 insertions(+), 1 deletion(-)

diff --git a/net-analyzer/mtr/mtr-0.87-r1.ebuild b/net-analyzer/mtr/mtr-0.87-r1.ebuild
new file mode 100644
index 00000000..50bfe44
--- /dev/null
+++ b/net-analyzer/mtr/mtr-0.87-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools eutils fcaps flag-o-matic
+
+DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
+HOMEPAGE="http://www.bitwizard.nl/mtr/"
+SRC_URI="ftp://ftp.bitwizard.nl/mtr/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="gtk ipv6"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gtk+:2
+	)
+"
+DEPEND="
+	${RDEPEND}
+	sys-devel/autoconf
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS FORMATS NEWS README SECURITY TODO )
+FILECAPS=( cap_net_raw usr/sbin/mtr )
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.80-impl-dec.patch
+	"${FILESDIR}"/${PN}-0.87-ipv6.patch
+	"${FILESDIR}"/${PN}-0.87-tinfo.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# In the source's configure script -lresolv is commented out. Apparently it
+	# is needed for 64bit macos still.
+	[[ ${CHOST} == *-darwin* ]] && append-libs -lresolv
+
+	econf \
+		$(use_enable ipv6) \
+		$(use_with gtk) \
+		--disable-gtktest
+}
+
+pkg_postinst() {
+	if use prefix && [[ ${CHOST} == *-darwin* ]] ; then
+		ewarn "mtr needs root privileges to run.  To grant them:"
+		ewarn " % sudo chown root ${EPREFIX}/usr/sbin/mtr"
+		ewarn " % sudo chmod u+s ${EPREFIX}/usr/sbin/mtr"
+	fi
+}

diff --git a/net-analyzer/mtr/mtr-9999.ebuild b/net-analyzer/mtr/mtr-9999.ebuild
index 797b07c..47d97b0 100644
--- a/net-analyzer/mtr/mtr-9999.ebuild
+++ b/net-analyzer/mtr/mtr-9999.ebuild
@@ -29,7 +29,7 @@ DEPEND="
 "
 
 DOCS=( AUTHORS FORMATS NEWS README SECURITY TODO )
-FILECAPS=( cap_net_raw /usr/sbin/mtr )
+FILECAPS=( cap_net_raw usr/sbin/mtr )
 PATCHES=(
 	"${FILESDIR}"/${PN}-9999-tinfo.patch
 )
@@ -58,3 +58,11 @@ src_configure() {
 		$(use_with gtk) \
 		$(use_with ncurses)
 }
+
+pkg_postinst() {
+	if use prefix && [[ ${CHOST} == *-darwin* ]] ; then
+		ewarn "mtr needs root privileges to run.  To grant them:"
+		ewarn " % sudo chown root ${EPREFIX}/usr/sbin/mtr"
+		ewarn " % sudo chmod u+s ${EPREFIX}/usr/sbin/mtr"
+	fi
+}