From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-909277-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 717DD1395E1
for <garchives@archives.gentoo.org>; Tue, 1 Nov 2016 20:13:06 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 92BCB21C06C;
Tue, 1 Nov 2016 20:13:04 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 68EC421C06C
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Nov 2016 20:13:04 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 1FFB9341669
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Nov 2016 20:13:02 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 31E3E303
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Nov 2016 20:13:00 +0000 (UTC)
From: "Dirkjan Ochtman" <djc@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Dirkjan Ochtman" <djc@gentoo.org>
Message-ID: <1478031171.fc1f998e81a751ecc3cd41491e913ed395ef98a4.djc@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-vcs/mercurial/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-vcs/mercurial/Manifest dev-vcs/mercurial/mercurial-4.0.ebuild
X-VCS-Directories: dev-vcs/mercurial/
X-VCS-Committer: djc
X-VCS-Committer-Name: Dirkjan Ochtman
X-VCS-Revision: fc1f998e81a751ecc3cd41491e913ed395ef98a4
X-VCS-Branch: master
Date: Tue, 1 Nov 2016 20:13:00 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 28b50859-9b79-4c30-b7f5-709f56ff1137
X-Archives-Hash: abf6e788252c4c0c0323f0f3a308fc5e
commit: fc1f998e81a751ecc3cd41491e913ed395ef98a4
Author: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 1 20:12:51 2016 +0000
Commit: Dirkjan Ochtman <djc <AT> gentoo <DOT> org>
CommitDate: Tue Nov 1 20:12:51 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fc1f998e
dev-vcs/mercurial: version bump to 4.0
Package-Manager: portage-2.3.0
dev-vcs/mercurial/Manifest | 1 +
dev-vcs/mercurial/mercurial-4.0.ebuild | 135 +++++++++++++++++++++++++++++++++
2 files changed, 136 insertions(+)
diff --git a/dev-vcs/mercurial/Manifest b/dev-vcs/mercurial/Manifest
index f7f5cba..b0f436d 100644
--- a/dev-vcs/mercurial/Manifest
+++ b/dev-vcs/mercurial/Manifest
@@ -2,3 +2,4 @@ DIST mercurial-3.7.3.tar.gz 4636732 SHA256 c099c42d74e2d520b61dd372cd996b0fa7605
DIST mercurial-3.8.4.tar.gz 4775341 SHA256 4b2e3ef19d34fa1d781cb7425506a05d4b6b1172bab69d6ea78874175fdf3da6 SHA512 2ee785f631f9ae346e10ca77251a9ce6d3dacd598588c39f1a69ce1f4b668866f6109d682428512c37c300b26741b74672195538d66845e85cfff5ead886cf4c WHIRLPOOL 1f0a12cc6d00f3544ab00e011a9ff9308fe1652c0598045ddba2a41ba17b55c291da200bce85d4c600d673b8746e936c441ffa7398ad810d1069bd97fb32f2db
DIST mercurial-3.9.1.tar.gz 4797967 SHA256 625e4fc7e85ec2278c2828bdc547fce74091b3bbe4d9eeeba2d61af51195df74 SHA512 d96e45cafd36be692d6ce5259e18140641c24f73d4731ff767df0f39af425b0630c687436fc0f53d5882495ceacacaadd5e19f8f7c701b4b94c48631123b4666 WHIRLPOOL ba4e9374b592d294767046fe7d4297df837d9e92ea2279a7a3654054c058a6b994cade2358d2c35a7d30b6985abd0f7afe55af586ccafbe1dc5b50059bc2712f
DIST mercurial-3.9.2.tar.gz 4798958 SHA256 69046a427c05e83097bf0145a1e37975ae0b6ba4430456e2beca3d2fd96583cf SHA512 2217b492216bc640366bf4bfa65bb50d2b7f384d70c59fd1fb138482cbee4768c83a444233958a7ad95e9cd0dcbe3e676d7ff4a8a4019b9773205f8f2500235e WHIRLPOOL 11763311c2df0a235a8401ea0ea59d06797bbfaa420f9c900a39fa127e34f94cefc27dde96e57449cc659da7e13813ad146c17f5db011068bed5f0f7215e331c
+DIST mercurial-4.0.tar.gz 4850316 SHA256 24be080745230840f214d93e9f9fb4e25510f9abbbec2e56fab18543fedc43a7 SHA512 8c1974a00efc4d0bcdaca1ce86a172528de58857ac0a78d8cac5c1182dcdd340c7f0f680c8dba82d384ffd3557abbfbdc2e473b5b0b8f05160bd6dbb915e76e4 WHIRLPOOL b4dad09ee488a2630ba37e4f24454de0d171a5b480bd5d161c28a1ec03f60f05efdc25c66c9626d638becebae1ace420312660f66cc9fbd834efca9824c5fbd6
diff --git a/dev-vcs/mercurial/mercurial-4.0.ebuild b/dev-vcs/mercurial/mercurial-4.0.ebuild
new file mode 100644
index 00000000..1e1d7b5
--- /dev/null
+++ b/dev-vcs/mercurial/mercurial-4.0.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads"
+
+inherit bash-completion-r1 elisp-common eutils distutils-r1 flag-o-matic
+
+DESCRIPTION="Scalable distributed SCM"
+HOMEPAGE="https://www.mercurial-scm.org/"
+SRC_URI="https://www.mercurial-scm.org/release/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="bugzilla emacs gpg test tk"
+
+RDEPEND="bugzilla? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+ gpg? ( app-crypt/gnupg )
+ tk? ( dev-lang/tk )
+ app-misc/ca-certificates"
+DEPEND="emacs? ( virtual/emacs )
+ test? ( app-arch/unzip
+ dev-python/pygments[${PYTHON_USEDEP}] )"
+
+SITEFILE="70${PN}-gentoo.el"
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.1-po_fixes.patch" )
+
+python_prepare_all() {
+ # fix up logic that won't work in Gentoo Prefix (also won't outside in
+ # certain cases), bug #362891
+ sed -i -e 's:xcodebuild:nocodebuild:' setup.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ strip-flags -ftracer -ftree-vectorize
+ # Note: make it impl-conditional if py3 is supported
+ append-flags -fno-strict-aliasing
+
+ "${PYTHON}" setup.py build_mo || die
+}
+
+python_compile_all() {
+ rm -r contrib/{win32,macosx} || die
+ if use emacs; then
+ cd contrib || die
+ elisp-compile mercurial.el || die "elisp-compile failed!"
+ fi
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ newbashcomp contrib/bash_completion hg
+
+ insinto /usr/share/zsh/site-functions
+ newins contrib/zsh_completion _hg
+
+ rm -f doc/*.?.txt
+ dodoc CONTRIBUTORS
+ cp hgweb*.cgi "${ED}"/usr/share/doc/${PF}/ || die
+
+ dobin hgeditor
+ dobin contrib/hgk
+ python_foreach_impl python_doscript contrib/hg-ssh
+
+ if use emacs; then
+ elisp-install ${PN} contrib/mercurial.el* || die "elisp-install failed!"
+ elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+ fi
+
+ local RM_CONTRIB=(hgk hg-ssh bash_completion zsh_completion wix buildrpm plan9
+ *.el mercurial.spec)
+ for f in ${RM_CONTRIB[@]}; do
+ rm -r contrib/$f || die
+ done
+
+ dodoc -r contrib
+ docompress -x /usr/share/doc/${PF}/contrib
+ doman doc/*.?
+
+ insinto /etc/mercurial/hgrc.d
+ doins "${FILESDIR}/cacerts.rc"
+}
+
+src_test() {
+ pushd tests &>/dev/null || die
+ rm -rf *svn* # Subversion tests fail with 1.5
+ rm -f test-archive* # Fails due to verbose tar output changes
+ rm -f test-convert-baz* # GNU Arch baz
+ rm -f test-convert-cvs* # CVS
+ rm -f test-convert-darcs* # Darcs
+ rm -f test-convert-git* # git
+ rm -f test-convert-mtn* # monotone
+ rm -f test-convert-tla* # GNU Arch tla
+ #rm -f test-doctest* # doctest always fails with python 2.5.x
+ rm -f test-largefiles* # tends to time out
+
+ popd &>/dev/null || die
+ distutils-r1_src_test
+}
+
+python_test() {
+ local TEST_DIR
+
+ rm -rf "${TMPDIR}"/test
+ distutils_install_for_testing
+ cd tests || die
+ "${PYTHON}" run-tests.py --verbose \
+ --tmpdir="${TMPDIR}"/test \
+ --with-hg="${TEST_DIR}"/scripts/hg \
+ || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+
+ elog "If you want to convert repositories from other tools using convert"
+ elog "extension please install correct tool:"
+ elog " dev-vcs/cvs"
+ elog " dev-vcs/darcs"
+ elog " dev-vcs/git"
+ elog " dev-vcs/monotone"
+ elog " dev-vcs/subversion"
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}