From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-908422-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 514CD139427
	for <garchives@archives.gentoo.org>; Thu, 27 Oct 2016 21:45:51 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 7CC02E076D;
	Thu, 27 Oct 2016 21:45:47 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 52C66E076D
	for <gentoo-commits@lists.gentoo.org>; Thu, 27 Oct 2016 21:45:47 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 04EB834164A
	for <gentoo-commits@lists.gentoo.org>; Thu, 27 Oct 2016 21:45:46 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 327A5244E
	for <gentoo-commits@lists.gentoo.org>; Thu, 27 Oct 2016 21:45:44 +0000 (UTC)
From: "Patrice Clement" <monsieurp@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Patrice Clement" <monsieurp@gentoo.org>
Message-ID: <1477604721.f88a84ae31279839dd7aac43997ce142e65e7b2d.monsieurp@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/libmediaart/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild
X-VCS-Directories: media-libs/libmediaart/
X-VCS-Committer: monsieurp
X-VCS-Committer-Name: Patrice Clement
X-VCS-Revision: f88a84ae31279839dd7aac43997ce142e65e7b2d
X-VCS-Branch: master
Date: Thu, 27 Oct 2016 21:45:44 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 0958119e-0459-4517-ba70-b354982da169
X-Archives-Hash: d4ee29cb437340809b824c68f0334f4a

commit:     f88a84ae31279839dd7aac43997ce142e65e7b2d
Author:     Andreas Sturmlechner <andreas.sturmlechner <AT> gmail <DOT> com>
AuthorDate: Thu Oct 20 14:08:58 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Thu Oct 27 21:45:21 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f88a84ae

media-libs/libmediaart: Drop USE=qt4, fix build w/ Qt 5.7.0, EAPI 6.

Gentoo-Bug: https://bugs.gentoo.org/590402

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2605

Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild | 77 ++++++++++++++++++++++
 1 file changed, 77 insertions(+)

diff --git a/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild b/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild
new file mode 100644
index 00000000..2103149
--- /dev/null
+++ b/media-libs/libmediaart/libmediaart-1.9.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.16"
+
+inherit autotools flag-o-matic gnome2 vala virtualx
+
+DESCRIPTION="Manages, extracts and handles media art caches"
+HOMEPAGE="https://github.com/GNOME/libmediaart"
+
+LICENSE="LGPL-2.1+"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk +introspection qt5 vala"
+REQUIRED_USE="
+	?? ( gtk qt5 )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.38.0:2
+	gtk? ( >=x11-libs/gdk-pixbuf-2.12:2 )
+	introspection? ( >=dev-libs/gobject-introspection-1.30:= )
+	qt5? ( dev-qt/qtgui:5 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/gobject-introspection-common
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	# Fix QT automagic selection, bug #523122
+	eapply "${FILESDIR}"/${PN}-0.7.0-qt5.patch
+
+	# Make doc parallel installable
+	cd "${S}"/docs/reference/${PN} || die
+	sed -e "s/\(DOC_MODULE.*=\).*/\1${PN}-${SLOT}/" \
+		-e "s/\(DOC_MAIN_SGML_FILE.*=\).*/\1${PN}-docs-${SLOT}.sgml/" \
+		-i Makefile.am Makefile.in || die
+	sed -e "s/\(<book.*name=\"\)libmediaart/\1${PN}-${SLOT}/" \
+		-i html/libmediaart.devhelp2 || die
+	mv libmediaart-docs{,-${SLOT}}.sgml || die
+	mv libmediaart-overrides{,-${SLOT}}.txt || die
+	mv libmediaart-sections{,-${SLOT}}.txt || die
+	mv html/libmediaart{,-${SLOT}}.devhelp2 || die
+	cd "${S}" || die
+
+	eautoreconf
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	if use qt5 ; then
+		local myconf="--with-qt-version=5"
+		append-cxxflags -std=c++11
+	fi
+
+	gnome2_src_configure \
+		--enable-unit-tests \
+		$(use_enable gtk gdkpixbuf) \
+		$(use_enable introspection) \
+		$(use_enable qt5 qt) \
+		$(use_enable vala) \
+		${myconf}
+}
+
+src_test() {
+	dbus-launch virtx emake check #513502
+}