[gentoo-commits] repo/gentoo:master commit in: dev-libs/libcdio-paranoia/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     4c06ef8e54b850bac8b45ef64b140b0758136af4
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 26 17:00:32 2016 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Oct 26 17:02:34 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4c06ef8e

dev-libs/libcdio-paranoia: Revbump to make use of dev-libs/libcdio sub-slot.

Bumped ebuild to EAPI-6.

Package-Manager: portage-2.3.2
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 .../libcdio-paranoia-0.93_p1-r1.ebuild             | 64 ++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1-r1.ebuild b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1-r1.ebuild
new file mode 100644
index 00000000..202d22e
--- /dev/null
+++ b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.93_p1-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+MY_P=${PN}-10.2+${PV/_p/+}
+
+inherit eutils autotools multilib-minimal flag-o-matic
+
+DESCRIPTION="an advanced CDDA reader with error correction"
+HOMEPAGE="https://www.gnu.org/software/libcdio/"
+SRC_URI="mirror://gnu/${PN%-*}/${MY_P}.tar.gz"
+
+# COPYING-GPL from cdparanoia says "2 or later"
+# COPYING-LGPL from cdparanoia says "2.1 or later" but 2 files are without the
+# clause "or later" so we use LGPL-2.1 without +
+LICENSE="GPL-3+ GPL-2+ LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="+cxx static-libs test"
+
+RDEPEND="app-eselect/eselect-cdparanoia
+	>=dev-libs/libcdio-0.93:0=[${MULTILIB_USEDEP}]
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r10
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS )
+
+src_prepare() {
+	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466410
+	default
+	eautoreconf
+
+	[[ ${CC} == *clang* ]] && append-flags -std=gnu89
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-maintainer-mode
+		--disable-example-progs
+		$(use_enable cxx)
+		--disable-cpp-progs
+		--with-cd-paranoia-name=libcdio-paranoia
+	)
+	# Darwin linker doesn't get this
+	[[ ${CHOST} == *-darwin* ]] && myeconfargs+=( --without-versioned-libs )
+	ECONF_SOURCE="${S}" \
+	econf "${myeconfargs[@]}"
+}
+
+pkg_postinst() {
+	eselect cdparanoia update ifunset
+}
+
+pkg_postrm() {
+	eselect cdparanoia update ifunset
+}