[gentoo-commits] repo/gentoo:master commit in: net-libs/gtk-vnc/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     ed1b22fd71d7da9bf9028fcb438c237f0bc24a5d
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 11 18:35:33 2016 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Sep 11 19:00:02 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ed1b22fd

net-libs/gtk-vnc: cleanup old revision

Package-Manager: portage-2.3.0

 net-libs/gtk-vnc/Manifest             |   1 -
 net-libs/gtk-vnc/gtk-vnc-0.5.3.ebuild | 187 ----------------------------------
 2 files changed, 188 deletions(-)

diff --git a/net-libs/gtk-vnc/Manifest b/net-libs/gtk-vnc/Manifest
index d2cdcea..3dd3ee4 100644
--- a/net-libs/gtk-vnc/Manifest
+++ b/net-libs/gtk-vnc/Manifest
@@ -1,3 +1,2 @@
-DIST gtk-vnc-0.5.3.tar.xz 408336 SHA256 d490a6c8f40e550d43aef0043ce3bec498ec220d5eb3dc5cdcff8fd561149caf SHA512 a5d81fcb8ee04f033a3aec2eed334e4237c8f4d7334e4875a149b5b385b0f0f0948d2d5227fbbfdccec8d192ba8bbc5f93dd83bb0d6604da25675662a9858cf2 WHIRLPOOL c2b6dc272843e0fce795fb4e082330f252a6f8413806e77b4ace78d63fead48634e647df96e2d6436b3c7a16013f6c2d18d377c762607ed2fd4dbd21e3f62fe3
 DIST gtk-vnc-0.5.4.tar.xz 418104 SHA256 488aa97a76ce6868160699cd45d4a0ee0fe6f0ad4631737c6ddd84450f6c9ce7 SHA512 068f7e29d40c677c9453364e33ab3a57e155dd0715299c8dee3f9933ecdb2e3bc4aea6dd722f5bc846d9b883e4f5a6de7b46742f004b348a551100ea7720da61 WHIRLPOOL 4d29f394a3ac5ea10584369f4a2290274a4be95c5d68c13e84e7ce990bf907243f16afc9b610ba973eebb3d137ca0fc4dce04df5f79afa1327a1c7aadcafaf5b
 DIST gtk-vnc-0.6.0.tar.xz 439104 SHA256 9559348805e64d130dae569fee466930175dbe150d2649bb868b5c095f130433 SHA512 38d37753bd8c88d112c046eb8430383b073b6516c72660b3e53612986a6772b72e3e6037f61e7a3700980ab1509c1f44fbfe0b80594c8a5e5520df166212f158 WHIRLPOOL e156f368a9d70e90077253b031db49f5f58e2f248b3e15bc11340f01f6bcbd342cf08dd9810c8ee447ab372159d09c3353aa5ce6195f67c677e7c43a563a75c0

diff --git a/net-libs/gtk-vnc/gtk-vnc-0.5.3.ebuild b/net-libs/gtk-vnc/gtk-vnc-0.5.3.ebuild
deleted file mode 100644
index 8427711..00000000
--- a/net-libs/gtk-vnc/gtk-vnc-0.5.3.ebuild
+++ /dev/null
@@ -1,187 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="5"
-PYTHON_COMPAT=( python2_7 )
-VALA_MIN_API_VERSION="0.16"
-VALA_USE_DEPEND="vapigen"
-
-inherit eutils gnome.org python-r1 vala
-
-DESCRIPTION="VNC viewer widget for GTK"
-HOMEPAGE="https://live.gnome.org/gtk-vnc"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd"
-IUSE="examples +gtk3 +introspection pulseaudio python sasl vala"
-REQUIRED_USE="
-	python? ( ${PYTHON_REQUIRED_USE} )
-	vala? ( gtk3 introspection )
-"
-
-# libview is used in examples/gvncviewer -- no need
-# glib-2.30.1 needed to avoid linking failure due to .la files (bug #399129)
-COMMON_DEPEND="
-	>=dev-libs/glib-2.30.1:2
-	>=dev-libs/libgcrypt-1.4.2:0
-	dev-libs/libgpg-error
-	>=net-libs/gnutls-1.4
-	>=x11-libs/cairo-1.2
-	>=x11-libs/gtk+-2.18:2
-	x11-libs/libX11
-	gtk3? ( >=x11-libs/gtk+-2.91.3:3 )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.4 )
-	pulseaudio? ( media-sound/pulseaudio )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-python/pygtk-2:2[${PYTHON_USEDEP}] )
-	sasl? ( dev-libs/cyrus-sasl )
-"
-RDEPEND="${COMMON_DEPEND}"
-
-DEPEND="${COMMON_DEPEND}
-	>=dev-lang/perl-5
-	>=dev-util/intltool-0.40
-	sys-devel/gettext
-	virtual/pkgconfig
-	vala? (
-		$(vala_depend)
-		>=dev-libs/gobject-introspection-0.9.4 )
-"
-# eautoreconf requires gnome-common
-
-GTK2_BUILDDIR="${WORKDIR}/${P}_gtk2"
-GTK3_BUILDDIR="${WORKDIR}/${P}_gtk3"
-
-src_prepare() {
-	mkdir -p "${GTK2_BUILDDIR}" || die
-	mkdir -p "${GTK3_BUILDDIR}" || die
-	prepare_python() {
-		mkdir -p "${BUILD_DIR}" || die
-	}
-	if use python; then
-		python_foreach_impl prepare_python
-	fi
-
-	# Remove a few files that were autogenerated during distcheck.
-	# Having these around in srcdir breaks out of tree build since they're
-	# expected to be in builddir, which is correct for trunk builds since
-	# they're generated files, not source files. Funny false dichotomy.
-	rm -vf "${S}"/src/{vncconnectionenums.[ch],vncdisplayenums.[ch]}
-
-	# Fix incorrect codegendir check: h2def.py is in pygobject, not pygtk, upstream bug#????
-	sed -e 's/codegendir pygtk-2.0/codegendir pygobject-2.0/g' \
-		-i src/Makefile.* || die
-
-	# libtool seems unable to find this via VPATH so help it
-	sed -r "s:(gtkvnc_la_LIBADD =) libgtk-vnc-.*\.la:\1 ${GTK2_BUILDDIR}/src/libgtk-vnc-1.0.la:" \
-		-i src/Makefile.{am,in} || die
-
-	vala_src_prepare
-}
-
-src_configure() {
-	local myconf
-	myconf="
-		$(use_with examples) \
-		$(use_enable introspection) \
-		$(use_with pulseaudio) \
-		$(use_with sasl) \
-		--with-coroutine=gthread \
-		--without-libview \
-		--disable-static \
-		--disable-vala"
-
-	cd "${GTK2_BUILDDIR}" || die
-	einfo "Running configure in ${GTK2_BUILDDIR}"
-	ECONF_SOURCE="${S}" econf ${myconf} \
-		--with-python=no \
-		--with-gtk=2.0
-
-	configure_python() {
-		ECONF_SOURCE="${S}" econf ${myconf} \
-			$(use_with python) \
-			--with-gtk=2.0
-	}
-	if use python; then
-		python_foreach_impl run_in_build_dir configure_python
-	fi
-
-	if use gtk3; then
-		cd "${GTK3_BUILDDIR}" || die
-		einfo "Running configure in ${GTK3_BUILDDIR}"
-		# Python support is via gobject-introspection
-		# Ex: from gi.repository import GtkVnc
-		ECONF_SOURCE="${S}" econf ${myconf} \
-			$(use_enable vala) \
-			--with-python=no \
-			--with-gtk=3.0
-	fi
-}
-
-src_compile() {
-	cd "${GTK2_BUILDDIR}" || die
-	einfo "Running make in ${GTK2_BUILDDIR}"
-	emake
-
-	compile_python() {
-		cd "${BUILD_DIR}"/src || die
-		# CPPFLAGS set to help find includes for gvnc.override
-		emake gtkvnc.la \
-			VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
-			CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
-	}
-	if use python; then
-		python_foreach_impl run_in_build_dir compile_python
-	fi
-
-	if use gtk3; then
-		cd "${GTK3_BUILDDIR}" || die
-		einfo "Running make in ${GTK3_BUILDDIR}"
-		emake
-	fi
-}
-
-src_test() {
-	cd "${GTK2_BUILDDIR}" || die
-	einfo "Running make check in ${GTK2_BUILDDIR}"
-	default
-
-	if use gtk3; then
-		cd "${GTK3_BUILDDIR}" || die
-		einfo "Running make check in ${GTK3_BUILDDIR}"
-		default
-	fi
-}
-
-src_install() {
-	# Parallel installation fails sometimes, bug #328273, upstream bug #651923
-	# Upstream is still unable to reproduce, try again to use parallel with this new version
-	dodoc AUTHORS ChangeLog NEWS README
-
-	cd "${GTK2_BUILDDIR}" || die
-	einfo "Running make install in ${GTK2_BUILDDIR}"
-#	MAKEOPTS="${MAKEOPTS} -j1" default
-	default
-
-	install_python() {
-		cd "${BUILD_DIR}"/src || die
-		emake install-pyexecLTLIBRARIES DESTDIR="${D}" \
-			VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
-			CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
-	}
-	if use python; then
-		python_foreach_impl run_in_build_dir install_python
-	fi
-
-	if use gtk3; then
-		cd "${GTK3_BUILDDIR}" || die
-		einfo "Running make install in ${GTK3_BUILDDIR}"
-		#MAKEOPTS="${MAKEOPTS} -j1" default
-		default
-	fi
-
-	prune_libtool_files
-}