[gentoo-commits] repo/gentoo:master commit in: dev-ml/reactiveData/

["Alexis Ballier" <aballier@gentoo.org>]

commit:     fcf8e12653cb8867d025eecb9993a12b442d238a
Author:     Alexis Ballier <aballier <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  7 10:23:03 2016 +0000
Commit:     Alexis Ballier <aballier <AT> gentoo <DOT> org>
CommitDate: Wed Sep  7 10:23:10 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fcf8e126

dev-ml/reactiveData: add live ebuild

Package-Manager: portage-2.3.0

 dev-ml/reactiveData/reactiveData-9999.ebuild | 46 ++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-ml/reactiveData/reactiveData-9999.ebuild b/dev-ml/reactiveData/reactiveData-9999.ebuild
new file mode 100644
index 00000000..59dac46
--- /dev/null
+++ b/dev-ml/reactiveData/reactiveData-9999.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+DESCRIPTION="Functional reactive programming with incremental changes in data structures"
+HOMEPAGE="https://github.com/ocsigen/reactiveData"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/ocsigen/reactiveData"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/ocsigen/reactiveData/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0/${PV}"
+IUSE="+ocamlopt"
+
+RDEPEND=">=dev-lang/ocaml-3.12:=[ocamlopt?]
+	dev-ml/react:="
+DEPEND="${RDEPEND}
+	dev-ml/findlib
+	dev-ml/opam
+	dev-ml/ocamlbuild
+"
+
+src_compile() {
+	ocaml pkg/build.ml \
+		native=$(usex ocamlopt true false) \
+		native-dynlink=$(usex ocamlopt true false) \
+		|| die
+}
+
+src_install() {
+	opam-installer \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		|| die
+	dodoc README.md
+}