[gentoo-commits] repo/gentoo:master commit in: x11-misc/xsnow/

["Jeroen Roovers" <jer@gentoo.org>]

commit:     f966d5739580b59fcc675a813ed5e2761886e8eb
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 24 11:53:58 2016 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Jul 24 11:53:58 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f966d573

x11-misc/xsnow: EAPI update.

Package-Manager: portage-2.3.0

 x11-misc/xsnow/xsnow-1.42-r2.ebuild | 46 +++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/x11-misc/xsnow/xsnow-1.42-r2.ebuild b/x11-misc/xsnow/xsnow-1.42-r2.ebuild
new file mode 100644
index 0000000..d337512
--- /dev/null
+++ b/x11-misc/xsnow/xsnow-1.42-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs
+
+DESCRIPTION="let it snow on your desktop and windows"
+HOMEPAGE="http://dropmix.xs4all.nl/rick/Xsnow/"
+SRC_URI="${HOMEPAGE}${P}.tar.gz"
+
+LICENSE="freedist"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXt
+	x11-libs/libXext
+	x11-libs/libXpm
+"
+DEPEND="
+	${RDEPEND}
+	app-text/rman
+	x11-misc/imake
+	x11-misc/gccmakedep
+	x11-proto/xextproto
+	x11-proto/xproto
+"
+
+src_compile() {
+	xmkmf || die
+	make depend || die
+	emake \
+		CC="$(tc-getCC)" \
+		CDEBUGFLAGS="${CFLAGS}" \
+		LOCAL_LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin xsnow
+	rman -f HTML < xsnow._man > xsnow.1-html || die
+	newman xsnow._man xsnow.1
+	newdoc xsnow.1-html xsnow.1.html
+	dodoc README
+}