[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-color-manager/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     d3725e9a6e327e90f647e68ff54edb38d50110aa
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Jul  3 17:01:10 2016 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Jul  3 17:01:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3725e9a

gnome-extra/gnome-color-manager: Version bump

Package-Manager: portage-2.3.0_rc1

 gnome-extra/gnome-color-manager/Manifest           |  1 +
 .../gnome-color-manager-3.20.0.ebuild              | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/gnome-color-manager/Manifest b/gnome-extra/gnome-color-manager/Manifest
index 958b756..14acb4e 100644
--- a/gnome-extra/gnome-color-manager/Manifest
+++ b/gnome-extra/gnome-color-manager/Manifest
@@ -1 +1,2 @@
 DIST gnome-color-manager-3.18.0.tar.xz 2647648 SHA256 83d06f3b76b89b6c56bd6e4f792e15c67b561682fa9d59b60cbf716f6130a435 SHA512 4f1259681ee5f3762b1e4212e7b48c2caaa371d5cec00aa1ee4506f908310c8bbe4ff3e05e857707573475bfae0e61364d72c2d942d1d3fe5d978d2ca02c627c WHIRLPOOL 24e90187d17591450ac23da6afce3736e9380c2be75f0e3e7c470cebd5c849e8a40adf697cf42cc9269c419190379395d450fbe4a60eace40e16fe5ecf3ad8ae
+DIST gnome-color-manager-3.20.0.tar.xz 2661180 SHA256 fc4b8b075e79c1633ad935fb42e2aa06bf31a3e7e15360c705c771366e540793 SHA512 1c308fcf3f0d752f23fbbcd701272e05ede481260dffc77203d255b93da0278cd593558461309df0ea95d77b60c176c5ba2c695c27ec5042914a22272f033505 WHIRLPOOL 3ca5af3e491e7949f3af70611bcc304999d9afc4547442eb989d974aec4e95b993430eca9076f689e9239ee8bc88879c8773cb42574ed60c60913763e4f31158

diff --git a/gnome-extra/gnome-color-manager/gnome-color-manager-3.20.0.ebuild b/gnome-extra/gnome-color-manager/gnome-color-manager-3.20.0.ebuild
new file mode 100644
index 0000000..07dadcf
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/gnome-color-manager-3.20.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit gnome2 virtualx
+
+DESCRIPTION="Color profile manager for the GNOME desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-color-manager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="packagekit raw"
+
+# Need gtk+-3.3.8 for https://bugzilla.gnome.org/show_bug.cgi?id=673331
+RDEPEND="
+	>=dev-libs/glib-2.31.10:2
+	>=media-libs/lcms-2.2:2
+	>=media-libs/libcanberra-0.10[gtk3]
+	media-libs/libexif
+	media-libs/tiff:0=
+
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-libs/vte-0.25.1:2.91
+	>=x11-misc/colord-1.3.1:0=
+	>=x11-libs/colord-gtk-0.1.20
+
+	packagekit? ( app-admin/packagekit-base )
+	raw? ( media-gfx/exiv2 )
+"
+# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
+DEPEND="${RDEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	dev-libs/appstream-glib
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# Always enable tests since they are check_PROGRAMS anyway
+	# appstream does not want to be relax by default !
+	gnome2_src_configure \
+		--disable-static \
+		--enable-tests \
+		$(use_enable packagekit) \
+		$(use_enable raw exiv) \
+		APPSTREAM_UTIL=$(type -P true)
+}
+
+src_test() {
+	virtx emake check
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! has_version media-gfx/argyllcms ; then
+		elog "If you want to do display or scanner calibration, you will need to"
+		elog "install media-gfx/argyllcms"
+	fi
+}