[gentoo-commits] repo/gentoo:master commit in: dev-python/guessit/

["Ian Delaney" <idella4@gentoo.org>]

commit:     004274e77863f566f3f2b7030830f7737ea46aab
Author:     Ilya Tumaykin <itumaykin <AT> gmail <DOT> com>
AuthorDate: Wed May 11 04:57:16 2016 +0000
Commit:     Ian Delaney <idella4 <AT> gentoo <DOT> org>
CommitDate: Thu May 12 11:39:36 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=004274e7

dev-python/guessit: revbump to 1.0.3-r1

Bump EAPI to 6, add missing deps, update HOMEPAGE,
fetch tarball from PyPI, make testsuite functional.

Package-Manager: portage-2.2.28

Signed-off-by: Ian Delaney <idella4 <AT> gentoo.org>

 dev-python/guessit/guessit-1.0.3-r1.ebuild | 50 ++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-python/guessit/guessit-1.0.3-r1.ebuild b/dev-python/guessit/guessit-1.0.3-r1.ebuild
new file mode 100644
index 0000000..ef300a4
--- /dev/null
+++ b/dev-python/guessit/guessit-1.0.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for guessing information from video filenames"
+HOMEPAGE="https://github.com/guessit-io/guessit https://pypi.python.org/pypi/guessit"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/babelfish-0.5.5[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	<dev-python/python-dateutil-2.5.2[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/stevedore[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/pytest-2.7.3[${PYTHON_USEDEP}]
+		dev-python/pytest-capturelog[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Disable benchmarks as they require unavailable pytest-benchmark.
+	rm guessit/test/test_benchmark.py || die
+	sed -i -e "s|'pytest-benchmark',||g" setup.py || die
+
+	# Disable unconditional dependency on dev-python/pytest-runner.
+	sed -i -e "s|'pytest-runner'||g" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}