[gentoo-commits] repo/gentoo:master commit in: games-strategy/s25rttr/

["Michael Sterrett" <mr_bones_@gentoo.org>]

commit:     baf6a7f2c6be28890e17269527505c8c19c9c764
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Tue May  3 19:27:39 2016 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Tue May  3 19:57:05 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=baf6a7f2

games-strategy/s25rttr: rev bump to remove glfw support since this is the last customer in the tree for glfw-2

Package-Manager: portage-2.2.26

 games-strategy/s25rttr/s25rttr-0.8.1-r2.ebuild | 110 +++++++++++++++++++++++++
 1 file changed, 110 insertions(+)

diff --git a/games-strategy/s25rttr/s25rttr-0.8.1-r2.ebuild b/games-strategy/s25rttr/s25rttr-0.8.1-r2.ebuild
new file mode 100644
index 0000000..b53858b
--- /dev/null
+++ b/games-strategy/s25rttr/s25rttr-0.8.1-r2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils cmake-utils gnome2-utils games
+
+DESCRIPTION="Open Source remake of The Settlers II game (needs original game files)"
+HOMEPAGE="http://www.siedler25.org/"
+# no upstream source tarball yet
+# https://bugs.launchpad.net/s25rttr/+bug/1069546
+SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug"
+
+RDEPEND="app-arch/bzip2
+	media-libs/libsamplerate
+	media-libs/libsdl[X,sound,opengl,video]
+	media-libs/libsndfile
+	media-libs/sdl-mixer[vorbis]
+	net-libs/miniupnpc
+	virtual/libiconv
+	virtual/opengl"
+DEPEND="${RDEPEND}
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-cmake.patch \
+		"${FILESDIR}"/${P}-soundconverter.patch \
+		"${FILESDIR}"/${P}-fpic.patch \
+		"${FILESDIR}"/${P}-format.patch \
+		"${FILESDIR}"/${P}-miniupnpc-api-14.patch \
+		"${FILESDIR}"/${P}-cmake-3.patch
+}
+
+src_configure() {
+	local arch
+	case ${ARCH} in
+		amd64)
+			arch="x86_64" ;;
+		x86)
+			arch="i386" ;;
+		*) die "Architecture ${ARCH} not yet supported" ;;
+	esac
+
+	local mycmakeargs=(
+		-DCOMPILEFOR="linux"
+		-DCOMPILEARCH="${arch}"
+		-DCMAKE_SKIP_RPATH=YES
+		-DPREFIX="${GAMES_PREFIX}"
+		-DBINDIR="${GAMES_BINDIR}"
+		-DDATADIR="${GAMES_DATADIR}"
+		-DLIBDIR="$(games_get_libdir)/${PN}"
+		-DDRIVERDIR="$(games_get_libdir)/${PN}"
+		-DGAMEDIR="~/.${PN}/S2"
+		-DBUILD_GLFW_DRIVER=OFF
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# work around some relative paths (CMAKE_IN_SOURCE_BUILD not supported)
+	ln -s "${CMAKE_USE_DIR}"/RTTR "${CMAKE_BUILD_DIR}"/RTTR || die
+
+	cmake-utils_src_compile
+
+	mv "${CMAKE_USE_DIR}"/RTTR/{sound-convert,s-c_resample} "${T}"/ || die
+}
+
+src_install() {
+	cd "${CMAKE_BUILD_DIR}" || die
+
+	exeinto "$(games_get_libdir)"/${PN}
+	doexe "${T}"/{sound-convert,s-c_resample}
+	exeinto "$(games_get_libdir)"/${PN}/video
+	doexe driver/video/SDL/src/libvideoSDL.so
+	exeinto "$(games_get_libdir)"/${PN}/audio
+	doexe driver/audio/SDL/src/libaudioSDL.so
+
+	insinto "${GAMES_DATADIR}"
+	doins -r "${CMAKE_USE_DIR}"/RTTR
+	dosym ./LSTS/splash.bmp "${GAMES_DATADIR}"/RTTR/splash.bmp
+
+	doicon -s 64 "${CMAKE_USE_DIR}"/debian/${PN}.png
+	dogamesbin src/s25client
+	make_desktop_entry "s25client" "Settlers RTTR" "${PN}"
+	dodoc RTTR/texte/{keyboardlayout.txt,readme.txt}
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	elog "Copy your Settlers2 game files into ~/.${PN}/S2"
+
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}