* [gentoo-commits] proj/kde:master commit in: kde-plasma/libkscreen/, kde-plasma/plasma-desktop/, kde-plasma/kde-gtk-config/, ...
@ 2016-01-27 8:44 Manuel Rüger
0 siblings, 0 replies; only message in thread
From: Manuel Rüger @ 2016-01-27 8:44 UTC (permalink / raw
To: gentoo-commits
commit: 9e0d6f69330957a271532d13d3ebb521cb1046b1
Author: Andreas Sturmlechner <andreas.sturmlechner <AT> gmail <DOT> com>
AuthorDate: Tue Jan 26 22:07:29 2016 +0000
Commit: Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Wed Jan 27 08:44:02 2016 +0000
URL: https://gitweb.gentoo.org/proj/kde.git/commit/?id=9e0d6f69
kde-plasma: 5.5.4 version bump
Package-Manager: portage-2.2.27
kde-plasma/bluedevil/bluedevil-5.5.4.ebuild | 52 +++++++
kde-plasma/breeze-gtk/breeze-gtk-5.5.4.ebuild | 13 ++
kde-plasma/breeze/breeze-5.5.4.ebuild | 66 ++++++++
.../kde-cli-tools/kde-cli-tools-5.5.4.ebuild | 60 +++++++
.../kde-gtk-config/kde-gtk-config-5.5.4.ebuild | 57 +++++++
kde-plasma/kdecoration/kdecoration-5.5.4.ebuild | 17 ++
.../kdeplasma-addons/kdeplasma-addons-5.5.4.ebuild | 64 ++++++++
kde-plasma/kgamma/kgamma-5.5.4.ebuild | 31 ++++
kde-plasma/khelpcenter/khelpcenter-5.5.4.ebuild | 42 +++++
kde-plasma/khotkeys/khotkeys-5.5.4.ebuild | 46 ++++++
kde-plasma/kinfocenter/kinfocenter-5.5.4.ebuild | 89 +++++++++++
| 45 ++++++
kde-plasma/kscreen/kscreen-5.5.4.ebuild | 34 ++++
.../kscreenlocker/kscreenlocker-5.5.4.ebuild | 90 +++++++++++
kde-plasma/ksshaskpass/ksshaskpass-5.5.4.ebuild | 50 ++++++
kde-plasma/ksysguard/ksysguard-5.5.4.ebuild | 48 ++++++
kde-plasma/kwallet-pam/kwallet-pam-5.5.4.ebuild | 29 ++++
.../kwayland-integration-5.5.4.ebuild | 23 +++
kde-plasma/kwayland/kwayland-5.5.4.ebuild | 25 +++
kde-plasma/kwin/kwin-5.5.4.ebuild | 88 +++++++++++
kde-plasma/kwrited/kwrited-5.5.4.ebuild | 24 +++
kde-plasma/libkscreen/libkscreen-5.5.4.ebuild | 26 ++++
kde-plasma/libksysguard/libksysguard-5.5.4.ebuild | 54 +++++++
kde-plasma/milou/milou-5.5.4.ebuild | 30 ++++
kde-plasma/oxygen/oxygen-5.5.4.ebuild | 36 +++++
.../plasma-desktop/plasma-desktop-5.5.4.ebuild | 139 +++++++++++++++++
.../plasma-mediacenter-5.5.4.ebuild | 48 ++++++
kde-plasma/plasma-meta/plasma-meta-5.5.4.ebuild | 63 ++++++++
kde-plasma/plasma-nm/plasma-nm-5.5.4.ebuild | 66 ++++++++
kde-plasma/plasma-pa/plasma-pa-5.5.4.ebuild | 27 ++++
kde-plasma/plasma-sdk/plasma-sdk-5.5.4.ebuild | 40 +++++
.../plasma-workspace-wallpapers-5.5.4.ebuild | 16 ++
.../plasma-workspace/plasma-workspace-5.5.4.ebuild | 172 +++++++++++++++++++++
.../polkit-kde-agent/polkit-kde-agent-5.5.4.ebuild | 32 ++++
kde-plasma/powerdevil/powerdevil-5.5.4.ebuild | 81 ++++++++++
kde-plasma/sddm-kcm/sddm-kcm-5.5.4.ebuild | 39 +++++
.../systemsettings/systemsettings-5.5.4.ebuild | 46 ++++++
kde-plasma/user-manager/user-manager-5.5.4.ebuild | 26 ++++
38 files changed, 1934 insertions(+)
diff --git a/kde-plasma/bluedevil/bluedevil-5.5.4.ebuild b/kde-plasma/bluedevil/bluedevil-5.5.4.ebuild
new file mode 100644
index 0000000..1b789d2
--- /dev/null
+++ b/kde-plasma/bluedevil/bluedevil-5.5.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit fdo-mime kde5
+
+DESCRIPTION="Bluetooth stack for KDE"
+HOMEPAGE="https://projects.kde.org/projects/extragear/base/bluedevil"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+ $(add_frameworks_dep bluez-qt)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kded)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep plasma)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+DEPEND="${COMMON_DEPEND}
+ x11-misc/shared-mime-info
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ !app-mobilephone/obexd
+ !app-mobilephone/obex-data-server
+ !net-wireless/bluedevil
+ !net-wireless/kbluetooth
+"
+
+pkg_postinst() {
+ kde5_pkg_postinst
+ fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+ kde5_pkg_postinst
+ fdo-mime_mime_database_update
+}
diff --git a/kde-plasma/breeze-gtk/breeze-gtk-5.5.4.ebuild b/kde-plasma/breeze-gtk/breeze-gtk-5.5.4.ebuild
new file mode 100644
index 0000000..8596e57
--- /dev/null
+++ b/kde-plasma/breeze-gtk/breeze-gtk-5.5.4.ebuild
@@ -0,0 +1,13 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Official GTK+ port of KDE's Breeze widget style"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze-gtk"
+LICENSE="LGPL-2.1+"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
diff --git a/kde-plasma/breeze/breeze-5.5.4.ebuild b/kde-plasma/breeze/breeze-5.5.4.ebuild
new file mode 100644
index 0000000..d963c64
--- /dev/null
+++ b/kde-plasma/breeze/breeze-5.5.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5 multibuild
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="qt4"
+
+DEPEND="
+ $(add_frameworks_dep frameworkintegration)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep plasma)
+ $(add_plasma_dep kdecoration)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libxcb
+ qt4? (
+ kde-base/kdelibs:4
+ x11-libs/libX11
+ )
+"
+RDEPEND="${DEPEND}
+ $(add_frameworks_dep breeze-icons)
+ $(add_plasma_dep kde-cli-tools)
+"
+
+pkg_setup() {
+ kde5_pkg_setup
+ MULTIBUILD_VARIANTS=( kf5 $(usev qt4) )
+}
+
+src_configure() {
+ myconfigure() {
+ local mycmakeargs=()
+
+ if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+ mycmakeargs+=( -DUSE_KDE4=true )
+ fi
+
+ kde5_src_configure
+ }
+
+ multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+ multibuild_foreach_variant kde5_src_compile
+}
+
+src_install() {
+ multibuild_foreach_variant kde5_src_install
+}
diff --git a/kde-plasma/kde-cli-tools/kde-cli-tools-5.5.4.ebuild b/kde-plasma/kde-cli-tools/kde-cli-tools-5.5.4.ebuild
new file mode 100644
index 0000000..8c2dd2b
--- /dev/null
+++ b/kde-plasma/kde-cli-tools/kde-cli-tools-5.5.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kde-cli-tools"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="+kdesu X"
+
+DEPEND="
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ kdesu? ( $(add_frameworks_dep kdesu) )
+ X? (
+ $(add_frameworks_dep kdelibs4support)
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+ )
+"
+RDEPEND="${DEPEND}
+ handbook? ( !kde-apps/kdesu[handbook] )
+"
+
+# requires running kde environment
+RESTRICT="test"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package kdesu KF5Su)
+ $(cmake-utils_use_find_package X KF5KDELibs4Support)
+ $(cmake-utils_use_find_package X Qt5X11Extras)
+ )
+
+ kde5_src_configure
+}
+
+src_install() {
+ kde5_src_install
+ use kdesu && dosym /usr/$(get_libdir)/libexec/kf5/kdesu /usr/bin/kdesu5
+}
diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.5.4.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.5.4.ebuild
new file mode 100644
index 0000000..d10312c
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.5.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE systemsettings kcm to set GTK application look&feel"
+HOMEPAGE="https://projects.kde.org/kde-gtk-config"
+LICENSE="GPL-3"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="+gtk3"
+
+DEPEND="
+ $(add_frameworks_dep karchive)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep kwidgetsaddons)
+ dev-libs/glib:2
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ x11-libs/gtk+:2
+ gtk3? ( x11-libs/gtk+:3 )
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ !kde-base/kde-gtk-config:4
+ !kde-misc/kde-gtk-config
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.4.2-gtk3-optional.patch" )
+
+src_configure() {
+ local mycmakeargs=(
+ -DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+ -DBUILD_gtk3proxies=$(usex gtk3)
+ )
+
+ kde5_src_configure
+}
+
+pkg_postinst() {
+ kde5_pkg_postinst
+ einfo
+ elog "If you notice missing icons in your GTK applications, you may have to install"
+ elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+ elog "for example."
+ einfo
+}
diff --git a/kde-plasma/kdecoration/kdecoration-5.5.4.ebuild b/kde-plasma/kdecoration/kdecoration-5.5.4.ebuild
new file mode 100644
index 0000000..f9da080
--- /dev/null
+++ b/kde-plasma/kdecoration/kdecoration-5.5.4.ebuild
@@ -0,0 +1,17 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Plugin based library to create window decorations"
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-qt/qtgui:5"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.5.4.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.5.4.ebuild
new file mode 100644
index 0000000..11ed696
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.5.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Extra Plasma applets and engines"
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="ibus scim"
+
+DEPEND="
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep karchive)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep kross)
+ $(add_frameworks_dep krunner)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kunitconversion)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep plasma)
+ $(add_frameworks_dep sonnet)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ ibus? (
+ app-i18n/ibus
+ dev-libs/glib:2
+ dev-qt/qtx11extras:5
+ x11-libs/libxcb
+ x11-libs/xcb-util-keysyms
+ )
+ scim? ( app-i18n/scim )
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep plasma-workspace)
+ !kde-base/kdeplasma-addons:4
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package ibus IBus)
+ $(cmake-utils_use_find_package scim)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/kgamma/kgamma-5.5.4.ebuild b/kde-plasma/kgamma/kgamma-5.5.4.ebuild
new file mode 100644
index 0000000..2d7ca13
--- /dev/null
+++ b/kde-plasma/kgamma/kgamma-5.5.4.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="forceoptional"
+KMNAME="${PN}5"
+inherit kde5
+
+DESCRIPTION="Screen gamma values kcontrol module"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+ x11-libs/libXxf86vm
+"
+DEPEND="${RDEPEND}
+ x11-proto/xf86vidmodeproto
+ !<kde-apps/kde4-l10n-15.08.0
+ !kde-apps/kgamma:5
+"
diff --git a/kde-plasma/khelpcenter/khelpcenter-5.5.4.ebuild b/kde-plasma/khelpcenter/khelpcenter-5.5.4.ebuild
new file mode 100644
index 0000000..f621910
--- /dev/null
+++ b/kde-plasma/khelpcenter/khelpcenter-5.5.4.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="The KDE Help Center"
+HOMEPAGE+=" https://userbase.kde.org/KHelpCenter"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcodecs)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep khtml)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kinit)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kparts)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ !kde-base/khelpcenter:4
+"
diff --git a/kde-plasma/khotkeys/khotkeys-5.5.4.ebuild b/kde-plasma/khotkeys/khotkeys-5.5.4.ebuild
new file mode 100644
index 0000000..f4484fa
--- /dev/null
+++ b/kde-plasma/khotkeys/khotkeys-5.5.4.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="KDE workspace hotkey module"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdelibs4support X)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep ktextwidgets)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_plasma_dep plasma-workspace)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep kded)
+ $(add_plasma_dep kde-cli-tools)
+ !kde-base/khotkeys:4
+ !kde-base/systemsettings:4
+"
+DEPEND="${COMMON_DEPEND}
+ x11-libs/libxcb
+ x11-libs/libXtst
+ x11-proto/xproto
+"
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.5.4.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.5.4.ebuild
new file mode 100644
index 0000000..15ec75c
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.5.4.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="A utility that provides information about a computer system"
+HOMEPAGE="https://www.kde.org/applications/system/kinfocenter/"
+SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="egl gles ieee1394 +opengl +pci samba nfs wayland X"
+
+REQUIRED_USE="egl? ( || ( gles opengl ) )"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep solid)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5[opengl(+)]
+ dev-qt/qtwidgets:5
+ gles? (
+ dev-qt/qtgui:5[gles2]
+ || (
+ media-libs/mesa[egl,gles1]
+ media-libs/mesa[egl,gles2]
+ )
+ )
+ ieee1394? ( sys-libs/libraw1394 )
+ nfs? ( net-fs/nfs-utils )
+ opengl? (
+ virtual/glu
+ virtual/opengl
+ )
+ pci? ( sys-apps/pciutils )
+ samba? ( net-fs/samba[server(+)] )
+ wayland? ( $(add_plasma_dep kwayland) )
+ X? ( x11-libs/libX11 )
+"
+DEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep plasma)
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ !kde-base/kcontrol:4
+ !kde-base/kinfocenter:4
+ !kde-misc/about-distro
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package egl EGL)
+ $(cmake-utils_use_find_package gles OpenGLES)
+ $(cmake-utils_use_find_package ieee1394 RAW1394)
+ $(cmake-utils_use_find_package opengl OpenGL)
+ $(cmake-utils_use_find_package pci PCIUTILS)
+ $(cmake-utils_use_find_package wayland KF5Wayland)
+ $(cmake-utils_use_find_package X X11)
+ )
+
+ kde5_src_configure
+}
+
+src_install() {
+ kde5_src_install
+
+ insinto /etc/xdg
+ doins "${FILESDIR}"/kcm-about-distrorc
+
+ insinto /usr/share/${PN}
+ doins "${DISTDIR}"/glogo-small.png
+}
--git a/kde-plasma/kmenuedit/kmenuedit-5.5.4.ebuild b/kde-plasma/kmenuedit/kmenuedit-5.5.4.ebuild
new file mode 100644
index 0000000..e1c4776
--- /dev/null
+++ b/kde-plasma/kmenuedit/kmenuedit-5.5.4.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="KDE menu editor"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kmenuedit"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="+hotkeys"
+
+DEPEND="
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep sonnet)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ hotkeys? ( $(add_plasma_dep khotkeys) )
+"
+RDEPEND="${DEPEND}
+ !kde-base/kmenuedit:4
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package hotkeys KHotKeysDBusInterface)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/kscreen/kscreen-5.5.4.ebuild b/kde-plasma/kscreen/kscreen-5.5.4.ebuild
new file mode 100644
index 0000000..8ac46eb
--- /dev/null
+++ b/kde-plasma/kscreen/kscreen-5.5.4.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_PUNT_BOGUS_DEPS="true"
+inherit kde5
+
+DESCRIPTION="KDE screen management"
+HOMEPAGE="https://projects.kde.org/projects/extragear/base/kscreen"
+
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_plasma_dep libkscreen)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kxmlgui)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5[widgets]
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ dev-qt/qtgraphicaleffects:5
+ !kde-misc/kscreen
+"
diff --git a/kde-plasma/kscreenlocker/kscreenlocker-5.5.4.ebuild b/kde-plasma/kscreenlocker/kscreenlocker-5.5.4.ebuild
new file mode 100644
index 0000000..d2a0411
--- /dev/null
+++ b/kde-plasma/kscreenlocker/kscreenlocker-5.5.4.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="forceoptional"
+QT_MINIMAL="5.5.0"
+VIRTUALX_REQUIRED="test"
+inherit kde5 pam
+
+DESCRIPTION="Library and components for secure lock screen architecture"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="pam"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kcrash)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kidletime)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep plasma)
+ $(add_plasma_dep kwayland)
+ dev-libs/wayland
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5[widgets]
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+ x11-libs/libXi
+ x11-libs/libxcb
+ x11-libs/xcb-util-keysyms
+ pam? ( virtual/pam )
+"
+DEPEND="${COMMON_DEPEND}
+ x11-proto/xproto
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ !<kde-base/kcheckpass-4.11.22-r1:4
+ !kde-base/kdebase-pam:4
+ !<kde-plasma/plasma-workspace-5.4.50
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.4.90-no-SUID-no-GUID.patch" )
+
+src_prepare() {
+ kde5_src_prepare
+
+ use test || sed -i \
+ -e "/add_subdirectory(autotests)/ s/^/#/" greeter/CMakeLists.txt || die
+}
+
+src_test() {
+ # requires running environment
+ local myctestargs=(
+ -E x11LockerTest
+ )
+ kde5_src_test
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package pam)
+ )
+ kde5_src_configure
+}
+
+src_install() {
+ kde5_src_install
+
+ newpamd "${FILESDIR}/kde.pam" kde
+ newpamd "${FILESDIR}/kde-np.pam" kde-np
+
+ if ! use pam; then
+ chown root "${ED}"usr/$(get_libdir)/libexec/kcheckpass || die
+ chmod +s "${ED}"usr/$(get_libdir)/libexec/kcheckpass || die
+ fi
+}
diff --git a/kde-plasma/ksshaskpass/ksshaskpass-5.5.4.ebuild b/kde-plasma/ksshaskpass/ksshaskpass-5.5.4.ebuild
new file mode 100644
index 0000000..0e18e8b
--- /dev/null
+++ b/kde-plasma/ksshaskpass/ksshaskpass-5.5.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE implementation of ssh-askpass with Kwallet integration"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/ksshaskpass"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwallet)
+ $(add_frameworks_dep kwidgetsaddons)
+ dev-qt/qtwidgets:5
+"
+RDEPEND="
+ ${DEPEND}
+ !net-misc/ksshaskpass
+"
+
+src_install() {
+ kde5_src_install
+
+ insinto /etc/plasma/startup
+ doins "${FILESDIR}/05-ksshaskpass.sh"
+}
+
+pkg_postinst() {
+ kde5_pkg_postinst
+
+ elog ""
+ elog "In order to have ssh-agent start at kde startup,"
+ elog "edit /etc/plasma/startup/10-agent-startup.sh and uncomment"
+ elog "the lines enabling ssh-agent."
+ elog
+ elog "If you do so, do not forget to uncomment the respective"
+ elog "lines in /etc/plasma/shutdown/10-agent-shutdown.sh to"
+ elog "properly kill the agent when the session ends."
+ elog
+ elog "${PN} has been installed as your default askpass application"
+ elog "for Plasma 5 sessions."
+ elog "If that's not desired, select the one you want to use in"
+ elog "/etc/plasma/startup/05-ksshaskpass.sh"
+ elog ""
+}
diff --git a/kde-plasma/ksysguard/ksysguard-5.5.4.ebuild b/kde-plasma/ksysguard/ksysguard-5.5.4.ebuild
new file mode 100644
index 0000000..b3a0052
--- /dev/null
+++ b/kde-plasma/ksysguard/ksysguard-5.5.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="Network-enabled task manager and system monitor"
+LICENSE="GPL-2+"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="lm_sensors"
+
+DEPEND="
+ $(add_plasma_dep libksysguard)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kitemviews)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ lm_sensors? ( sys-apps/lm_sensors )
+"
+RDEPEND="${DEPEND}
+ !kde-base/ksysguard:4
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package lm_sensors Sensors)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/kwallet-pam/kwallet-pam-5.5.4.ebuild b/kde-plasma/kwallet-pam/kwallet-pam-5.5.4.ebuild
new file mode 100644
index 0000000..4849c04
--- /dev/null
+++ b/kde-plasma/kwallet-pam/kwallet-pam-5.5.4.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_AUTODEPS="false"
+inherit kde5 multilib
+
+DESCRIPTION="KWallet PAM module to not enter password again"
+LICENSE="LGPL-2.1"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ dev-libs/libgcrypt:0=
+ virtual/pam
+"
+RDEPEND="${DEPEND}
+ net-misc/socat
+"
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_INSTALL_LIBDIR="/$(get_libdir)"
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/kwayland-integration/kwayland-integration-5.5.4.ebuild b/kde-plasma/kwayland-integration/kwayland-integration-5.5.4.ebuild
new file mode 100644
index 0000000..a05cbd7
--- /dev/null
+++ b/kde-plasma/kwayland-integration/kwayland-integration-5.5.4.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Provides integration plugins for various KDE frameworks for Wayland"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kwayland-integration"
+
+LICENSE="LGPL-2.1"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kidletime)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_plasma_dep kwayland)
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/kwayland/kwayland-5.5.4.ebuild b/kde-plasma/kwayland/kwayland-5.5.4.ebuild
new file mode 100644
index 0000000..0623300
--- /dev/null
+++ b/kde-plasma/kwayland/kwayland-5.5.4.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Qt-style client and server library wrapper for Wayland libraries"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kwayland"
+
+LICENSE="LGPL-2.1"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ >=dev-libs/wayland-1.7.0
+ dev-qt/qtgui:5
+ media-libs/mesa[egl]
+"
+RDEPEND="${DEPEND}"
+
+# All failing, i guess we need a virtual wayland server
+RESTRICT="test"
diff --git a/kde-plasma/kwin/kwin-5.5.4.ebuild b/kde-plasma/kwin/kwin-5.5.4.ebuild
new file mode 100644
index 0000000..aa46cbf
--- /dev/null
+++ b/kde-plasma/kwin/kwin-5.5.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE window manager"
+LICENSE="GPL-2+"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="gles2 multimedia"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kcrash)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kidletime)
+ $(add_frameworks_dep kinit)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem X)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep plasma)
+ $(add_plasma_dep kdecoration)
+ $(add_plasma_dep kscreenlocker)
+ $(add_plasma_dep kwayland)
+ >=dev-libs/libinput-0.10
+ >=dev-libs/wayland-1.2
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5[gles2=,opengl(+)]
+ dev-qt/qtscript:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ media-libs/fontconfig
+ media-libs/freetype
+ media-libs/libepoxy
+ media-libs/mesa[egl,gbm,gles2?,wayland]
+ virtual/libudev:=
+ x11-libs/libICE
+ x11-libs/libSM
+ x11-libs/libX11
+ x11-libs/libdrm
+ >=x11-libs/libxcb-1.10
+ >=x11-libs/libxkbcommon-0.4.1
+ x11-libs/xcb-util-cursor
+ x11-libs/xcb-util-image
+ x11-libs/xcb-util-keysyms
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ multimedia? (
+ || (
+ dev-qt/qtmultimedia:5[gstreamer,qml]
+ dev-qt/qtmultimedia:5[gstreamer010,qml]
+ )
+ )
+ !kde-base/kwin:4
+ !kde-base/systemsettings:4
+"
+DEPEND="${COMMON_DEPEND}
+ dev-qt/designer:5
+ dev-qt/qtconcurrent:5
+ x11-proto/xproto
+ test? ( x11-libs/xcb-util-wm )
+"
+
+src_prepare() {
+ kde5_src_prepare
+ use multimedia || epatch "${FILESDIR}/${PN}-gstreamer-optional.patch"
+}
diff --git a/kde-plasma/kwrited/kwrited-5.5.4.ebuild b/kde-plasma/kwrited/kwrited-5.5.4.ebuild
new file mode 100644
index 0000000..882d3b7
--- /dev/null
+++ b/kde-plasma/kwrited/kwrited-5.5.4.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE daemon listening for wall and write messages"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kpty)
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+ !kde-base/kwrited:4
+"
diff --git a/kde-plasma/libkscreen/libkscreen-5.5.4.ebuild b/kde-plasma/libkscreen/libkscreen-5.5.4.ebuild
new file mode 100644
index 0000000..101e06d
--- /dev/null
+++ b/kde-plasma/libkscreen/libkscreen-5.5.4.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="forceoptional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE screen management library"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtx11extras:5
+ x11-libs/libxcb
+"
+RDEPEND="${DEPEND}
+ !x11-libs/libkscreen:5
+"
+
+# requires running session
+RESTRICT="test"
diff --git a/kde-plasma/libksysguard/libksysguard-5.5.4.ebuild b/kde-plasma/libksysguard/libksysguard-5.5.4.ebuild
new file mode 100644
index 0000000..02051d7
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-5.5.4.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Task management and system monitoring library"
+LICENSE="LGPL-2+"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="+detailedmemory X"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ sys-libs/zlib
+ detailedmemory? ( dev-qt/qtwebkit:5 )
+ X? (
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+ x11-libs/libXres
+ )
+"
+RDEPEND="${COMMON_DEPEND}
+ !kde-base/ksysguard:4
+ !kde-base/libksysguard:4
+"
+DEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep plasma)
+ X? ( x11-proto/xproto )
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package detailedmemory Qt5WebKitWidgets)
+ $(cmake-utils_use_find_package X X11)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/milou/milou-5.5.4.ebuild b/kde-plasma/milou/milou-5.5.4.ebuild
new file mode 100644
index 0000000..0ca4d04
--- /dev/null
+++ b/kde-plasma/milou/milou-5.5.4.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Dedicated search application built on top of Baloo"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/milou"
+
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep krunner)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep plasma)
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+ !kde-misc/milou:4
+"
diff --git a/kde-plasma/oxygen/oxygen-5.5.4.ebuild b/kde-plasma/oxygen/oxygen-5.5.4.ebuild
new file mode 100644
index 0000000..87630aa
--- /dev/null
+++ b/kde-plasma/oxygen/oxygen-5.5.4.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE window manager theme"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/oxygen"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+ $(add_frameworks_dep frameworkintegration)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_plasma_dep kdecoration)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libxcb
+ !kde-base/kdebase-cursors:4
+ !kde-base/oxygen:4
+"
+DEPEND="${RDEPEND}
+ $(add_frameworks_dep kservice)
+"
diff --git a/kde-plasma/plasma-desktop/plasma-desktop-5.5.4.ebuild b/kde-plasma/plasma-desktop/plasma-desktop-5.5.4.ebuild
new file mode 100644
index 0000000..5b8fa4b
--- /dev/null
+++ b/kde-plasma/plasma-desktop/plasma-desktop-5.5.4.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="KDE Plasma desktop"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="+evdev +fontconfig gtk2 gtk3 legacy-systray pulseaudio +qt4 touchpad"
+
+COMMON_DEPEND="
+ $(add_plasma_dep kwin)
+ $(add_plasma_dep plasma-workspace)
+ $(add_frameworks_dep attica)
+ $(add_frameworks_dep baloo)
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep karchive)
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kbookmarks)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcodecs)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kded)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep kemoticons)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kitemmodels)
+ $(add_frameworks_dep kitemviews)
+ $(add_frameworks_dep kjobwidgets)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep knotifyconfig)
+ $(add_frameworks_dep kparts)
+ $(add_frameworks_dep kpeople)
+ $(add_frameworks_dep krunner)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwallet)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep plasma)
+ $(add_frameworks_dep solid)
+ $(add_frameworks_dep sonnet)
+ dev-qt/qtconcurrent:5
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtprintsupport:5
+ dev-qt/qtsql:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ dev-qt/qtxml:5
+ media-libs/phonon[qt5]
+ x11-libs/libX11
+ x11-libs/libXcursor
+ x11-libs/libXfixes
+ x11-libs/libXi
+ x11-libs/libxcb
+ x11-libs/libxkbfile
+ fontconfig? (
+ media-libs/fontconfig
+ media-libs/freetype
+ x11-libs/libXft
+ x11-libs/xcb-util-image
+ )
+ pulseaudio? (
+ dev-libs/glib:2
+ media-libs/libcanberra
+ media-sound/pulseaudio
+ )
+ touchpad? ( x11-drivers/xf86-input-synaptics )
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep breeze)
+ $(add_plasma_dep kde-cli-tools)
+ $(add_plasma_dep oxygen)
+ dev-qt/qtgraphicaleffects:5
+ sys-apps/accountsservice
+ x11-apps/setxkbmap
+ legacy-systray? (
+ gtk2? ( dev-libs/libappindicator:2 )
+ gtk3? ( dev-libs/libappindicator:3 )
+ qt4? ( dev-libs/sni-qt )
+ )
+ pulseaudio? ( $(add_plasma_dep plasma-pa ) )
+ qt4? ( kde-base/qguiplatformplugin_kde )
+ !kde-apps/kcontrol
+ !kde-apps/kdepasswd
+ !kde-apps/knetattach[handbook]
+ !kde-base/plasma-desktop:4
+ !kde-base/plasma-workspace:4
+ !kde-base/solid-actions-kcm:4
+ !kde-base/systemsettings:4
+ !kde-misc/kcm_touchpad
+ !kde-misc/kcm-touchpad
+ !kde-plasma/kcm-touchpad
+"
+DEPEND="${COMMON_DEPEND}
+ dev-libs/boost
+ x11-proto/xproto
+ evdev? ( x11-drivers/xf86-input-evdev )
+ fontconfig? ( x11-libs/libXrender )
+"
+
+REQUIRED_USE="legacy-systray? ( || ( gtk2 gtk3 qt4 ) ) gtk2? ( legacy-systray ) gtk3? ( legacy-systray )"
+
+pkg_setup() {
+ if has_version net-im/skype && use legacy-systray && use amd64; then
+ einfo
+ elog "You need to install dev-libs/sni-qt[abi_x86_32] as skype is a 32-bit binary."
+ einfo
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package evdev)
+ $(cmake-utils_use_find_package fontconfig Fontconfig)
+ $(cmake-utils_use_find_package pulseaudio PulseAudio)
+ $(cmake-utils_use_find_package touchpad Synaptics)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/plasma-mediacenter/plasma-mediacenter-5.5.4.ebuild b/kde-plasma/plasma-mediacenter/plasma-mediacenter-5.5.4.ebuild
new file mode 100644
index 0000000..4383d3e
--- /dev/null
+++ b/kde-plasma/plasma-mediacenter/plasma-mediacenter-5.5.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_PUNT_BOGUS_DEPS="true"
+inherit kde5
+
+DESCRIPTION="Unified media experience for any device capable of running KDE"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="semantic-desktop"
+
+DEPEND="
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep plasma)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtxml:5
+ media-libs/taglib
+ semantic-desktop? (
+ $(add_frameworks_dep baloo)
+ $(add_frameworks_dep kfilemetadata)
+ )
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep plasma-workspace)
+ dev-qt/qtmultimedia:5[qml]
+ !media-video/plasma-mediacenter
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package semantic-desktop KF5Baloo)
+ $(cmake-utils_use_find_package semantic-desktop KF5FileMetadata)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/plasma-meta/plasma-meta-5.5.4.ebuild b/kde-plasma/plasma-meta/plasma-meta-5.5.4.ebuild
new file mode 100644
index 0000000..05ec230
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-5.5.4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5-functions
+
+DESCRIPTION="Merge this to pull in all Plasma 5 packages"
+HOMEPAGE="https://www.kde.org/workspaces/plasmadesktop/"
+
+LICENSE="metapackage"
+SLOT="5"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="bluetooth +display-manager gtk mediacenter networkmanager pulseaudio +sddm sdk +wallpapers"
+
+RDEPEND="
+ $(add_plasma_dep breeze)
+ $(add_plasma_dep kde-cli-tools)
+ $(add_plasma_dep kdecoration)
+ $(add_plasma_dep kdeplasma-addons)
+ $(add_plasma_dep kgamma)
+ $(add_plasma_dep khelpcenter)
+ $(add_plasma_dep khotkeys)
+ $(add_plasma_dep kinfocenter)
+ $(add_plasma_dep kmenuedit)
+ $(add_plasma_dep kscreen)
+ $(add_plasma_dep kscreenlocker)
+ $(add_plasma_dep ksshaskpass)
+ $(add_plasma_dep ksysguard)
+ $(add_plasma_dep kwallet-pam)
+ $(add_plasma_dep kwayland)
+ $(add_plasma_dep kwayland-integration)
+ $(add_plasma_dep kwin)
+ $(add_plasma_dep kwrited)
+ $(add_plasma_dep libkscreen)
+ $(add_plasma_dep libksysguard)
+ $(add_plasma_dep milou)
+ $(add_plasma_dep oxygen)
+ $(add_plasma_dep plasma-desktop)
+ $(add_plasma_dep plasma-workspace)
+ $(add_plasma_dep polkit-kde-agent)
+ $(add_plasma_dep powerdevil)
+ $(add_plasma_dep systemsettings)
+ $(add_plasma_dep user-manager)
+ bluetooth? (
+ $(add_plasma_dep bluedevil)
+ )
+ display-manager? (
+ sddm? ( x11-misc/sddm )
+ !sddm? ( x11-misc/lightdm )
+ )
+ gtk? (
+ $(add_plasma_dep breeze-gtk)
+ $(add_plasma_dep kde-gtk-config)
+ )
+ mediacenter? ( $(add_plasma_dep plasma-mediacenter) )
+ networkmanager? ( $(add_plasma_dep plasma-nm) )
+ pulseaudio? ( $(add_plasma_dep plasma-pa) )
+ sddm? ( $(add_plasma_dep sddm-kcm) )
+ sdk? ( $(add_plasma_dep plasma-sdk) )
+ wallpapers? ( $(add_plasma_dep plasma-workspace-wallpapers) )
+"
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.5.4.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.5.4.ebuild
new file mode 100644
index 0000000..6dde69e
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.5.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kitemviews)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwallet)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep networkmanager-qt 'teamd=')
+ $(add_frameworks_dep plasma)
+ $(add_frameworks_dep solid)
+ >=app-crypt/qca-2.1.0.3-r1:2[qt5]
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ >=net-misc/networkmanager-0.9.10.0[teamd=]
+ modemmanager? (
+ $(add_frameworks_dep modemmanager-qt)
+ dev-qt/qtxml:5
+ net-misc/mobile-broadband-provider-info
+ )
+ openconnect? (
+ dev-qt/qtxml:5
+ net-misc/networkmanager-openconnect
+ net-misc/openconnect:=
+ )
+"
+RDEPEND="${DEPEND}
+ $(add_plasma_dep plasma-workspace)
+ !kde-misc/plasma-nm
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package modemmanager ModemManager)
+ $(cmake-utils_use_find_package modemmanager KF5ModemManagerQt)
+ $(cmake-utils_use_find_package openconnect OpenConnect)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/plasma-pa/plasma-pa-5.5.4.ebuild b/kde-plasma/plasma-pa/plasma-pa-5.5.4.ebuild
new file mode 100644
index 0000000..2d69bc7
--- /dev/null
+++ b/kde-plasma/plasma-pa/plasma-pa-5.5.4.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_PUNT_BOGUS_DEPS="true"
+inherit kde5
+
+DESCRIPTION="Plasma applet for audio volume management using PulseAudio"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep plasma)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ media-sound/pulseaudio
+"
+
+RDEPEND="${DEPEND}"
diff --git a/kde-plasma/plasma-sdk/plasma-sdk-5.5.4.ebuild b/kde-plasma/plasma-sdk/plasma-sdk-5.5.4.ebuild
new file mode 100644
index 0000000..c8da2c6
--- /dev/null
+++ b/kde-plasma/plasma-sdk/plasma-sdk-5.5.4.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Useful applications for Plasma development"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep karchive)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep ktexteditor)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep plasma)
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+"
+RDEPEND="${DEPEND}
+ !dev-util/plasmate
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.3.2-remove-qtwebkit.patch" )
diff --git a/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.5.4.ebuild b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.5.4.ebuild
new file mode 100644
index 0000000..e3b472d
--- /dev/null
+++ b/kde-plasma/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.5.4.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_AUTODEPS="false"
+KDE_DEBUG="false"
+inherit kde5
+
+DESCRIPTION="Additional wallpapers for the Plasma workspace"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="$(add_frameworks_dep extra-cmake-modules)"
+RDEPEND="!<kde-apps/kde-wallpapers-15.08.3[-minimal(-)]"
diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.5.4.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.5.4.ebuild
new file mode 100644
index 0000000..f672e89
--- /dev/null
+++ b/kde-plasma/plasma-workspace/plasma-workspace-5.5.4.ebuild
@@ -0,0 +1,172 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_PUNT_BOGUS_DEPS="true"
+KDE_TEST="true"
+QT_MINIMAL="5.5.0"
+VIRTUALX_REQUIRED="test"
+inherit kde5 multilib qmake-utils
+
+DESCRIPTION="KDE Plasma workspace"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="dbus +geolocation gps prison qalculate"
+
+COMMON_DEPEND="
+ $(add_frameworks_dep baloo)
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kbookmarks)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kcrash)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdeclarative)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep kdesu)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep kguiaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kidletime)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kitemviews)
+ $(add_frameworks_dep kjobwidgets)
+ $(add_frameworks_dep kjs)
+ $(add_frameworks_dep kjsembed)
+ $(add_frameworks_dep knewstuff)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep knotifyconfig)
+ $(add_frameworks_dep kpackage)
+ $(add_frameworks_dep krunner)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep ktexteditor)
+ $(add_frameworks_dep ktextwidgets)
+ $(add_frameworks_dep kwallet)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep kxmlrpcclient)
+ $(add_frameworks_dep plasma)
+ $(add_frameworks_dep solid)
+ $(add_plasma_dep kscreenlocker)
+ $(add_plasma_dep kwayland)
+ $(add_plasma_dep kwin)
+ $(add_plasma_dep libkscreen)
+ $(add_plasma_dep libksysguard)
+ dev-qt/qtconcurrent:5
+ dev-qt/qtdbus:5
+ dev-qt/qtdeclarative:5[widgets]
+ dev-qt/qtgui:5[jpeg]
+ dev-qt/qtnetwork:5
+ dev-qt/qtscript:5
+ dev-qt/qtsql:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ dev-qt/qtxml:5
+ media-libs/phonon[qt5]
+ sys-libs/zlib
+ x11-libs/libICE
+ x11-libs/libSM
+ x11-libs/libX11
+ x11-libs/libXau
+ x11-libs/libxcb
+ x11-libs/libXfixes
+ x11-libs/libXrender
+ x11-libs/xcb-util
+ x11-libs/xcb-util-image
+ dbus? ( dev-libs/libdbusmenu-qt[qt5] )
+ geolocation? ( $(add_frameworks_dep networkmanager-qt) )
+ gps? ( sci-geosciences/gpsd )
+ prison? ( media-libs/prison:5 )
+ qalculate? ( sci-libs/libqalculate )
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_frameworks_dep kded)
+ $(add_kdeapps_dep kio-extras)
+ $(add_plasma_dep kde-cli-tools)
+ $(add_plasma_dep ksysguard)
+ $(add_plasma_dep milou)
+ dev-qt/qdbus:5
+ dev-qt/qtgraphicaleffects:5
+ dev-qt/qtpaths:5
+ dev-qt/qtquickcontrols:5[widgets]
+ x11-apps/mkfontdir
+ x11-apps/xmessage
+ x11-apps/xprop
+ x11-apps/xrdb
+ x11-apps/xset
+ x11-apps/xsetroot
+ !dev-libs/xembed-sni-proxy
+ !kde-base/freespacenotifier:4
+ !kde-base/libtaskmanager:4
+ !kde-base/kcminit:4
+ !kde-base/kdebase-startkde:4
+ !kde-base/klipper:4
+ !kde-base/krunner:4
+ !kde-base/ksmserver:4
+ !kde-base/ksplash:4
+ !kde-base/plasma-workspace:4
+"
+DEPEND="${COMMON_DEPEND}
+ x11-proto/xproto
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-5.4-startkde-script.patch"
+ "${FILESDIR}/${PN}-tests-optional.patch"
+)
+
+RESTRICT="test"
+
+src_prepare() {
+ kde5_src_prepare
+
+ sed -e "s|\`qtpaths|\`$(qt5_get_bindir)/qtpaths|" \
+ -i startkde/startkde.cmake startkde/startplasmacompositor.cmake || die
+
+ if ! use geolocation; then
+ punt_bogus_dep KF5 NetworkManagerQt
+ pushd dataengines > /dev/null || die
+ comment_add_subdirectory geolocation
+ popd > /dev/null || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package dbus dbusmenu-qt5)
+ $(cmake-utils_use_find_package gps libgps)
+ $(cmake-utils_use_find_package prison)
+ $(cmake-utils_use_find_package qalculate Qalculate)
+ )
+
+ kde5_src_configure
+}
+
+src_install() {
+ kde5_src_install
+
+ # startup and shutdown scripts
+ insinto /etc/plasma/startup
+ doins "${FILESDIR}/10-agent-startup.sh"
+
+ insinto /etc/plasma/shutdown
+ doins "${FILESDIR}/10-agent-shutdown.sh"
+}
+
+pkg_postinst () {
+ kde5_pkg_postinst
+
+ echo
+ elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+ elog "edit ${EPREFIX}/etc/plasma/startup/10-agent-startup.sh and"
+ elog "${EPREFIX}/etc/plasma/shutdown/10-agent-shutdown.sh"
+ echo
+}
diff --git a/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.5.4.ebuild b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.5.4.ebuild
new file mode 100644
index 0000000..acfd101
--- /dev/null
+++ b/kde-plasma/polkit-kde-agent/polkit-kde-agent-5.5.4.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KMNAME="${PN}-1"
+inherit kde5
+
+DESCRIPTION="PolKit agent module for KDE"
+HOMEPAGE="https://www.kde.org"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kcrash)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ || ( $(add_frameworks_dep polkit-qt) >=sys-auth/polkit-qt-0.112.0[qt5] )
+"
+RDEPEND="${DEPEND}
+ !sys-auth/polkit-kde-agent:4[-minimal(-)]
+ !sys-auth/polkit-kde-agent:5
+"
diff --git a/kde-plasma/powerdevil/powerdevil-5.5.4.ebuild b/kde-plasma/powerdevil/powerdevil-5.5.4.ebuild
new file mode 100644
index 0000000..7e2b2b2
--- /dev/null
+++ b/kde-plasma/powerdevil/powerdevil-5.5.4.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/powerdevil"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="systemd"
+
+DEPEND="
+ $(add_frameworks_dep kactivities)
+ $(add_frameworks_dep kauth policykit)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep kglobalaccel)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kidletime)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep knotifications)
+ $(add_frameworks_dep knotifyconfig)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kxmlgui)
+ $(add_frameworks_dep solid)
+ $(add_plasma_dep kwayland)
+ $(add_plasma_dep libkscreen)
+ $(add_plasma_dep plasma-workspace)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ virtual/libudev:=
+ x11-libs/libxcb
+"
+
+RDEPEND="${DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ systemd? ( >=sys-power/upower-0.9.23 )
+ !systemd? (
+ sys-auth/polkit-pkla-compat
+ || (
+ ( >=sys-auth/consolekit-1.0.1 >=sys-power/upower-0.9.23 )
+ sys-power/upower-pm-utils
+ )
+ )
+ !kde-base/powerdevil:4
+ !kde-base/systemsettings:4[handbook]
+"
+
+src_install() {
+ kde5_src_install
+
+ if ! use systemd ; then
+ insinto /etc/polkit-1/localauthority/10-vendor.d/
+ doins "${FILESDIR}"/10-org.freedesktop.upower.pkla
+ doins "${FILESDIR}"/20-org.freedesktop.consolekit.system.stop-multiple-users.pkla
+ doins "${FILESDIR}"/30-org.freedesktop.consolekit.system.restart-multiple-users.pkla
+ doins "${FILESDIR}"/40-org.freedesktop.consolekit.system.suspend-multiple-users.pkla
+ fi
+}
+
+pkg_postinst() {
+ kde5_pkg_postinst
+
+ if has_version sys-power/upower-pm-utils && ! use systemd ; then
+ ewarn "You have sys-power/upower-pm-utils installed, which was recommended in the past to"
+ ewarn "enable suspend and hibernate support. This workaround is no longer required, and it"
+ ewarn "is now recommended to use a recent version of upower and consolekit instead:"
+ ewarn
+ ewarn "emerge --ask --update \">=sys-auth/consolekit-1.0.0\" sys-power/upower"
+ fi
+}
diff --git a/kde-plasma/sddm-kcm/sddm-kcm-5.5.4.ebuild b/kde-plasma/sddm-kcm/sddm-kcm-5.5.4.ebuild
new file mode 100644
index 0000000..4883b49
--- /dev/null
+++ b/kde-plasma/sddm-kcm/sddm-kcm-5.5.4.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE control module for SDDM"
+HOMEPAGE="https://projects.kde.org/projects/kdereview/sddm-kcm"
+
+LICENSE="GPL-2+"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+COMMON_DEPEND="
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kio)
+ dev-qt/qtdeclarative:5[widgets]
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtx11extras:5
+ x11-libs/libX11
+ x11-libs/libXcursor
+"
+DEPEND="${COMMON_DEPEND}
+ x11-libs/libXfixes
+"
+RDEPEND="${COMMON_DEPEND}
+ $(add_plasma_dep kde-cli-tools)
+ x11-misc/sddm
+ !kde-misc/sddm-kcm
+"
+
+DOCS=( CONTRIBUTORS )
diff --git a/kde-plasma/systemsettings/systemsettings-5.5.4.ebuild b/kde-plasma/systemsettings/systemsettings-5.5.4.ebuild
new file mode 100644
index 0000000..8d8be86
--- /dev/null
+++ b/kde-plasma/systemsettings/systemsettings-5.5.4.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_HANDBOOK="forceoptional"
+inherit kde5
+
+DESCRIPTION="System settings utility"
+KEYWORDS=" ~amd64 ~x86"
+IUSE="classic gtk"
+
+DEPEND="
+ $(add_frameworks_dep kauth)
+ $(add_frameworks_dep kcmutils)
+ $(add_frameworks_dep kcompletion)
+ $(add_frameworks_dep kconfig)
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdbusaddons)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kitemviews)
+ $(add_frameworks_dep kservice)
+ $(add_frameworks_dep kwidgetsaddons)
+ $(add_frameworks_dep kwindowsystem)
+ $(add_frameworks_dep kxmlgui)
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+ classic? ( $(add_frameworks_dep khtml) )
+"
+RDEPEND="${DEPEND}
+ gtk? ( $(add_plasma_dep kde-gtk-config) )
+ !kde-base/systemsettings:4
+"
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake-utils_use_find_package classic KF5KHtml)
+ )
+
+ kde5_src_configure
+}
diff --git a/kde-plasma/user-manager/user-manager-5.5.4.ebuild b/kde-plasma/user-manager/user-manager-5.5.4.ebuild
new file mode 100644
index 0000000..5232794
--- /dev/null
+++ b/kde-plasma/user-manager/user-manager-5.5.4.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Simple system settings module to manage the users of your system"
+KEYWORDS=" ~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+ $(add_frameworks_dep kconfigwidgets)
+ $(add_frameworks_dep kcoreaddons)
+ $(add_frameworks_dep kdelibs4support)
+ $(add_frameworks_dep ki18n)
+ $(add_frameworks_dep kiconthemes)
+ $(add_frameworks_dep kio)
+ $(add_frameworks_dep kwidgetsaddons)
+ dev-libs/libpwquality
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}"
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2016-01-27 8:44 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2016-01-27 8:44 [gentoo-commits] proj/kde:master commit in: kde-plasma/libkscreen/, kde-plasma/plasma-desktop/, kde-plasma/kde-gtk-config/, Manuel Rüger
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox