[gentoo-commits] repo/gentoo:master commit in: sci-libs/netcdf/

["David Seifert" <soap@gentoo.org>]

commit:     1fb79e2536fc00ccb8f7b40429d57c9ca6d693af
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 23 19:40:26 2016 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Jan 23 20:05:10 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1fb79e25

sci-libs/netcdf: port to EAPI=6, remove 'autotools-utils' usage

Package-Manager: portage-2.2.27

 sci-libs/netcdf/netcdf-4.4.0-r1.ebuild | 54 ++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/sci-libs/netcdf/netcdf-4.4.0-r1.ebuild b/sci-libs/netcdf/netcdf-4.4.0-r1.ebuild
new file mode 100644
index 0000000..d82570b
--- /dev/null
+++ b/sci-libs/netcdf/netcdf-4.4.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils
+
+DESCRIPTION="Scientific library and interface for array oriented data access"
+HOMEPAGE="http://www.unidata.ucar.edu/software/netcdf/"
+SRC_URI="https://github.com/Unidata/netcdf-c/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="UCAR-Unidata"
+SLOT="0/11"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+dap examples hdf +hdf5 mpi static-libs szip test tools"
+
+RDEPEND="
+	dap? ( net-misc/curl:0= )
+	hdf? ( sci-libs/hdf:0= sci-libs/hdf5:0= )
+	hdf5? ( sci-libs/hdf5:0=[mpi=,szip=,zlib] )"
+DEPEND="${RDEPEND}"
+# doc generation is missing many doxygen files in tar ball
+#	doc? ( app-doc/doxygen[dot] )"
+
+REQUIRED_USE="test? ( tools ) szip? ( hdf5 ) mpi? ( hdf5 )"
+
+S="${WORKDIR}/${PN}-c-${PV}"
+
+src_configure() {
+	local myconf
+	if use mpi; then
+		export CC=mpicc
+		myconf="--enable-parallel"
+		use test && myconf+=" --enable-parallel-tests"
+	fi
+	econf "${myconf}" \
+		--disable-examples \
+		--disable-dap-remote-tests \
+		$(use_enable dap) \
+		$(use_enable hdf hdf4) \
+		$(use_enable hdf5 netcdf-4) \
+		$(use_enable static-libs static) \
+		$(use_enable tools utilities)
+}
+
+src_install() {
+	default
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+	prune_libtool_files
+}