[gentoo-commits] repo/gentoo:master commit in: dev-libs/antlr-c/, dev-libs/antlr-c/files/

[gentoo-commits] repo/gentoo:master commit in: dev-libs/antlr-c/, dev-libs/antlr-c/files/

[James Le Cuirot]

commit:     7ca2e0ce77d6447536aa56d3bc047619c9d1abbc
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 12 23:22:20 2016 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Tue Jan 12 23:23:08 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ca2e0ce

dev-libs/antlr-c: Version bump to 3.5.2

Adds multilib support. This version also includes important fixes for
mysql-workbench. See bug #570600.

Package-Manager: portage-2.2.26

 dev-libs/antlr-c/Manifest                          |  2 +-
 dev-libs/antlr-c/antlr-c-3.5.2.ebuild              | 64 +++++++++++++++++++++
 dev-libs/antlr-c/antlr-c-3.5.ebuild                | 66 ----------------------
 .../{antlr-c-3.3-cflags.patch => 3.5-cflags.patch} |  0
 4 files changed, 65 insertions(+), 67 deletions(-)

diff --git a/dev-libs/antlr-c/Manifest b/dev-libs/antlr-c/Manifest
index 7218aff..ec4fb21 100644
--- a/dev-libs/antlr-c/Manifest
+++ b/dev-libs/antlr-c/Manifest
@@ -1 +1 @@
-DIST antlr-3.5.tar.gz 6791279 SHA256 6be17690f782c899cda68be812df5c40911aed057bf0192b0c37d2711cba8fc8 SHA512 a7014bc5d178add8a1f8e44a19ec60fed934f79f38fd702c7d7c3bb6a8c803492063911f86a445b696d10956f6f902144a5244046e83d70cffdc1717400c38a7 WHIRLPOOL c364d9ffac34de2e80a04233c73cab54b468eb958d924a305ccfc534587996edd4ee78a8fbb9416f2cad404dc43f44da9f9717e32e3f33da900c450c41a046ea
+DIST antlr-3.5.2.tar.gz 6927126 SHA256 529baf7d11f06b773543e25271c1a6e1735d2f8061f4866d1ea5c99a5d71ee1f SHA512 e2a0520093fb2a77dcd9d44f26a9fdd612dceaffb398c53b2b8cd29f4630830647ede29e8dd55b434cb2c165b0fd1d77968ec6e6de0798f14d9cdfd9e6fccd99 WHIRLPOOL a3a2bf81cc91a332725a4ce15dcccf10df5395b27a521656b1f3e80fed10197edc132fa2a8b9a259b2ee603320492b4b1f664692a967fdfdbb574d919b9aa20e

diff --git a/dev-libs/antlr-c/antlr-c-3.5.2.ebuild b/dev-libs/antlr-c/antlr-c-3.5.2.ebuild
new file mode 100644
index 0000000..3449cd4
--- /dev/null
+++ b/dev-libs/antlr-c/antlr-c-3.5.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils autotools multilib-minimal
+
+MY_PN="${PN%-c}"
+DESCRIPTION="The ANTLR3 C Runtime"
+HOMEPAGE="http://www.antlr3.org/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}3/archive/${PV}.tar.gz -> ${MY_PN}-${PV}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug debugger doc static-libs"
+
+DEPEND="doc? ( app-doc/doxygen[dot] )"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_PN}3-${PV}/runtime/C"
+PATCHES=( "${FILESDIR}/3.5-cflags.patch" )
+MULTILIB_WRAPPED_HEADERS=( /usr/include/antlr3config.h )
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	sed -i '/^QUIET/s/NO/YES/' doxyfile || die
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local econfargs=(
+		--enable-shared
+		$(use_enable debug debuginfo)
+		$(use_enable debugger antlrdebug)
+		$(use_enable static-libs static)
+	)
+
+	case "${ABI}" in
+		*64*) econfargs+=( --enable-64bit ) ;;
+		*) econfargs+=( --disable-64bit ) ;;
+	esac
+
+	econf "${econfargs[@]}"
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		einfo "Generating API documentation ..."
+		cd "${S}" || die
+		doxygen -u doxyfile || die
+		doxygen doxyfile || die
+	fi
+}
+
+src_install() {
+	multilib-minimal_src_install
+	prune_libtool_files
+	use doc && dohtml -r "${S}/api/"
+}

diff --git a/dev-libs/antlr-c/antlr-c-3.5.ebuild b/dev-libs/antlr-c/antlr-c-3.5.ebuild
deleted file mode 100644
index 3ac3af3..0000000
--- a/dev-libs/antlr-c/antlr-c-3.5.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="5"
-
-AUTOTOOLS_AUTORECONF=1
-AUTOTOOLS_IN_SOURCE_BUILD=1
-inherit autotools-utils eutils
-
-MY_P="antlr-${PV}"
-DESCRIPTION="The ANTLR3 C Runtime"
-HOMEPAGE="https://github.com/antlr/antlr3/tree/master/runtime/C"
-SRC_URI="https://github.com/antlr/antlr3/archive/${MY_P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86"
-IUSE="debug debugger doc static-libs"
-
-DEPEND="doc? ( app-doc/doxygen )"
-RDEPEND=""
-
-S="${WORKDIR}/antlr3-${MY_P}/runtime/C"
-
-DOCS=( AUTHORS ChangeLog NEWS README )
-PATCHES=( "${FILESDIR}/${PN}-3.3-cflags.patch" )
-
-src_prepare() {
-	sed -i -e '/^QUIET/s/NO/YES/' doxyfile || die 'sed on doxyfile failed'
-
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		$(use_enable static-libs static)
-		$(use_enable debug debuginfo)
-		$(use_enable debugger antlrdebug)
-	)
-	if use amd64 || use ia64; then
-		myeconfargs+=( --enable-64bit )
-	else
-		myeconfargs+=( --disable-64bit )
-	fi
-
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	autotools-utils_src_compile
-
-	if use doc; then
-		einfo "Generating documentation API ..."
-		doxygen -u doxyfile
-		doxygen doxyfile || die "doxygen failed"
-	fi
-}
-
-src_install() {
-	autotools-utils_src_install
-
-	if use doc; then
-		dohtml api/*
-	fi
-}

diff --git a/dev-libs/antlr-c/files/antlr-c-3.3-cflags.patch b/dev-libs/antlr-c/files/3.5-cflags.patch
similarity index 100%
rename from dev-libs/antlr-c/files/antlr-c-3.3-cflags.patch
rename to dev-libs/antlr-c/files/3.5-cflags.patch

[gentoo-commits] repo/gentoo:master commit in: dev-libs/antlr-c/, dev-libs/antlr-c/files/

[Sam James]

commit:     26b189e6ee6589afda4fa10507aef5e7907d2f13
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Jan  5 04:36:19 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan  5 04:37:40 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=26b189e6

dev-libs/antlr-c: fix autoconf macro; drop (repurpose) invalid USE=debug

* Fix unnecessary use of AC_INCLUDES_DEFAULT (configure script + image is the same
  without it) which causes noise in ./configure
* Drop USE=debug for debug symbols (invalid)
* Rename USE=debugger -> USE=debug to match what USE=debug is really for
* Cleanup 64-bit test

Closes: https://bugs.gentoo.org/921345
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/antlr-c/antlr-c-3.5.2-r3.ebuild  | 62 +++++++++++++++++++++++++++++++
 dev-libs/antlr-c/files/3.5-autoconf.patch | 11 ++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-libs/antlr-c/antlr-c-3.5.2-r3.ebuild b/dev-libs/antlr-c/antlr-c-3.5.2-r3.ebuild
new file mode 100644
index 000000000000..efabf84d7edc
--- /dev/null
+++ b/dev-libs/antlr-c/antlr-c-3.5.2-r3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_PN="${PN%-c}"
+DESCRIPTION="The ANTLR3 C Runtime"
+HOMEPAGE="https://www.antlr3.org/"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}3/archive/${PV}.tar.gz -> ${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}3-${PV}/runtime/C"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc"
+
+BDEPEND="doc? ( app-doc/doxygen[dot] )"
+
+PATCHES=(
+	"${FILESDIR}/3.5-cflags.patch"
+	"${FILESDIR}/3.5-autoconf.patch"
+)
+
+src_prepare() {
+	default
+
+	sed -i '/^QUIET/s/NO/YES/' doxyfile || die
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable debug antlrdebug)
+	)
+
+	case "$(tc-get-ptr-size)" in
+		8) econfargs+=( --enable-64bit ) ;;
+		4) econfargs+=( --disable-64bit ) ;;
+	esac
+
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${econfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		einfo "Generating API documentation ..."
+		doxygen -u doxyfile || die
+		doxygen doxyfile || die
+
+		HTML_DOCS=( "${S}"/api/ )
+	fi
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}

diff --git a/dev-libs/antlr-c/files/3.5-autoconf.patch b/dev-libs/antlr-c/files/3.5-autoconf.patch
new file mode 100644
index 000000000000..5077652d2b5c
--- /dev/null
+++ b/dev-libs/antlr-c/files/3.5-autoconf.patch
@@ -0,0 +1,11 @@
+https://bugs.gentoo.org/921345
+--- a/configure.ac
++++ b/configure.ac
+@@ -148,7 +148,6 @@ AC_PROG_MAKE_SET
+ # Checks for libraries.
+ 
+ # Checks for header files.
+-AC_INCLUDES_DEFAULT()
+ AC_HEADER_RESOLV
+ AC_CHECK_HEADERS([sys/malloc.h malloc.h], [], [],
+ [[#ifdef HAVE_SYS_MALLOC_H