[gentoo-commits] proj/sci:master commit in: dev-python/nbconvert/

["Justin Lecher" <jlec@gentoo.org>]

commit:     e1d259fa37e81fbff05fdd0e19dafe76f30d5a11
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 30 13:39:28 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Fri Oct 30 13:39:28 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=e1d259fa

dev-python/nbconvert: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 dev-python/nbconvert/nbconvert-4.1.0.ebuild | 78 +++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/dev-python/nbconvert/nbconvert-4.1.0.ebuild b/dev-python/nbconvert/nbconvert-4.1.0.ebuild
new file mode 100644
index 0000000..0eab8bc
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-4.1.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+MY_PN="nbconvert"
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0.0-docs-Makefile.patch
+)
+
+RDEPEND="
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/mistune[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		app-text/pandoc
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	nosetests --with-coverage --cover-package=nbconvert nbconvert || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}