[gentoo-commits] repo/gentoo:master commit in: dev-util/oprofile/

["Andrew Savchenko" <bircoph@gentoo.org>]

commit:     29d5953cd9ef8e3a7ff83005cfa6656f8e8455e0
Author:     Andrew Savchenko <bircoph <AT> gmail <DOT> com>
AuthorDate: Tue Sep 29 19:35:38 2015 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Tue Sep 29 19:48:43 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29d5953c

dev-util/oprofile: update dependencies

migrate from sys-devel/binutils to sys-libs/binutils-libs

Package-Manager: portage-2.2.22
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 dev-util/oprofile/oprofile-0.9.9-r2.ebuild | 81 ++++++++++++++++++++++++++++++
 dev-util/oprofile/oprofile-1.0.0-r2.ebuild | 72 ++++++++++++++++++++++++++
 dev-util/oprofile/oprofile-1.1.0-r1.ebuild | 67 ++++++++++++++++++++++++
 3 files changed, 220 insertions(+)

diff --git a/dev-util/oprofile/oprofile-0.9.9-r2.ebuild b/dev-util/oprofile/oprofile-0.9.9-r2.ebuild
new file mode 100644
index 0000000..bab174a
--- /dev/null
+++ b/dev-util/oprofile/oprofile-0.9.9-r2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit autotools eutils linux-info multilib user java-pkg-opt-2
+
+MY_P=${PN}-${PV/_/-}
+DESCRIPTION="A transparent low-overhead system-wide profiler"
+HOMEPAGE="http://${PN}.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="java pch qt4"
+
+DEPEND=">=dev-libs/popt-1.7-r1
+	sys-libs/binutils-libs
+	>=sys-libs/glibc-2.3.2-r1
+	qt4? ( dev-qt/qtgui:4[qt3support] )
+	java? ( >=virtual/jdk-1.5:= )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	if ! linux_config_exists || ! linux_chkconfig_present OPROFILE ; then
+		echo
+		elog "In order for ${PN} to work, you need to configure your kernel"
+		elog "with CONFIG_OPROFILE set to 'm' or 'y'."
+		echo
+	fi
+
+	if ! kernel_is -ge 2 6 ; then
+		echo
+		elog "Support for kernels before 2.6 has been dropped in ${PN}-0.9.8."
+		echo
+	fi
+
+	# Required for JIT support, see README_PACKAGERS
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+
+	use java && java-pkg_init
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-gcc-4.9-non-ppc.patch"
+	epatch "${FILESDIR}/${P}-gcc-4.9-unused.patch"
+	epatch "${FILESDIR}/${PN}-1.0.0-athlon.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with qt4 x) \
+		$(use_enable qt4 gui qt4) \
+		$(use_enable pch) \
+		$(use_with java java ${JAVA_HOME})
+}
+
+src_install() {
+	emake DESTDIR="${D}" htmldir="/usr/share/doc/${PF}" install
+
+	dodoc ChangeLog* README TODO
+
+	dodir /etc/env.d
+	echo "LDPATH=${PREFIX}/usr/$(get_libdir)/${PN}" > "${D}"/etc/env.d/10${PN} || die "env.d failed"
+}
+
+pkg_postinst() {
+	echo
+	elog "Now load the ${PN} module by running:"
+	elog "  # opcontrol --init"
+	elog "Then read manpages and this html doc:"
+	elog "  /usr/share/doc/${PF}/${PN}.html"
+	echo
+}

diff --git a/dev-util/oprofile/oprofile-1.0.0-r2.ebuild b/dev-util/oprofile/oprofile-1.0.0-r2.ebuild
new file mode 100644
index 0000000..2fda6ad
--- /dev/null
+++ b/dev-util/oprofile/oprofile-1.0.0-r2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit eutils java-pkg-opt-2 linux-info multilib user
+
+MY_P=${PN}-${PV/_/-}
+DESCRIPTION="A transparent low-overhead system-wide profiler"
+HOMEPAGE="http://${PN}.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="java pch"
+
+RDEPEND=">=dev-libs/popt-1.7-r1
+	sys-libs/binutils-libs
+	>=sys-libs/glibc-2.3.2-r1
+	java? ( >=virtual/jdk-1.5:= )"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.31"
+
+S="${WORKDIR}/${MY_P}"
+
+CONFIG_CHECK="PERF_EVENTS"
+ERROR_PERF_EVENTS="CONFIG_PERF_EVENTS is mandatory for ${PN} to work."
+
+pkg_setup() {
+	linux-info_pkg_setup
+	if ! kernel_is -ge 2 6 31; then
+		echo
+		ewarn "Support for kernels before 2.6.31 has been dropped in ${PN}-1.0.0."
+		echo
+	fi
+
+	# Required for JIT support, see README_PACKAGERS
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+
+	use java && java-pkg_init
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-athlon.patch"
+	epatch "${FILESDIR}/${P}-opjitconv-open.patch"
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_enable pch) \
+		$(use_with java java ${JAVA_HOME})
+}
+
+src_install() {
+	emake DESTDIR="${D}" htmldir="/usr/share/doc/${PF}" install
+
+	dodoc ChangeLog* README TODO
+	echo "LDPATH=${PREFIX}/usr/$(get_libdir)/${PN}" > "${T}/10${PN}"
+	doenvd "${T}/10${PN}"
+}
+
+pkg_postinst() {
+	echo
+	elog "Starting from ${PN}-1.0.0 opcontrol was removed, use operf instead."
+	elog "CONFIG_OPROFILE is no longer used, you may remove it from your kernels."
+	elog "Please read manpages and this html doc:"
+	elog "  /usr/share/doc/${PF}/${PN}.html"
+	echo
+}

diff --git a/dev-util/oprofile/oprofile-1.1.0-r1.ebuild b/dev-util/oprofile/oprofile-1.1.0-r1.ebuild
new file mode 100644
index 0000000..f4aae03
--- /dev/null
+++ b/dev-util/oprofile/oprofile-1.1.0-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+inherit java-pkg-opt-2 linux-info multilib user
+
+MY_P=${PN}-${PV/_/-}
+DESCRIPTION="A transparent low-overhead system-wide profiler"
+HOMEPAGE="http://${PN}.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="java pch"
+
+RDEPEND=">=dev-libs/popt-1.7-r1
+	sys-libs/binutils-libs
+	>=sys-libs/glibc-2.3.2-r1
+	java? ( >=virtual/jdk-1.5:= )"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.31"
+
+S="${WORKDIR}/${MY_P}"
+
+CONFIG_CHECK="PERF_EVENTS"
+ERROR_PERF_EVENTS="CONFIG_PERF_EVENTS is mandatory for ${PN} to work."
+
+pkg_setup() {
+	linux-info_pkg_setup
+	if ! kernel_is -ge 2 6 31; then
+		echo
+		ewarn "Support for kernels before 2.6.31 has been dropped in ${PN}-1.0.0."
+		echo
+	fi
+
+	# Required for JIT support, see README_PACKAGERS
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+
+	use java && java-pkg_init
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_enable pch) \
+		$(use_with java java ${JAVA_HOME})
+}
+
+src_install() {
+	emake DESTDIR="${D}" htmldir="/usr/share/doc/${PF}" install
+
+	dodoc ChangeLog* README TODO
+	echo "LDPATH=${PREFIX}/usr/$(get_libdir)/${PN}" > "${T}/10${PN}"
+	doenvd "${T}/10${PN}"
+}
+
+pkg_postinst() {
+	echo
+	elog "Starting from ${PN}-1.0.0 opcontrol was removed, use operf instead."
+	elog "CONFIG_OPROFILE is no longer used, you may remove it from your kernels."
+	elog "Please read manpages and this html doc:"
+	elog "  /usr/share/doc/${PF}/${PN}.html"
+	echo
+}