[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-cors/

["Zac Medico" <zmedico@gentoo.org>]

commit:     c8c43ed43099093c7663b1705c2a38c2a97a3896
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Wed Sep  9 23:37:34 2015 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Wed Sep  9 23:37:34 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8c43ed4

dev-python/flask-cors: version bump to 2.1.0

Package-Manager: portage-2.2.20.1

 dev-python/flask-cors/Manifest                |  1 +
 dev-python/flask-cors/flask-cors-2.1.0.ebuild | 69 +++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/flask-cors/Manifest b/dev-python/flask-cors/Manifest
index f291c52..493ef34 100644
--- a/dev-python/flask-cors/Manifest
+++ b/dev-python/flask-cors/Manifest
@@ -1,2 +1,3 @@
 DIST flask-cors-1.8.0.tar.gz 17368 SHA256 da01f3ecf6d3d5c9c45ccdd95e6f93bc04a31f403ff5e4ad2e6c0fca99eb2cf1 SHA512 185a4e5785223d547373ff40d18dee2112a8da2dec2ecb39cb7b7c394e9220551e46302590870393c35902dd12e58d3d7cd4fb8fa052828b21d4107457a080fa WHIRLPOOL 1631d5c8e4521a31adcf061a6fbb21b9019835d3718ff02d16d2fe48af57d23d6cef01d740887d6b592ee420ba0c74ccb27a3a402547257823bc7a894793373a
 DIST flask-cors-1.9.0.tar.gz 22846 SHA256 d1237b21c3f98ea8bed387efdf1db1d1078df9c480f8fe06db21ff130420200b SHA512 0ed2d4fdd80b43bbbcab4257c3917ea12b39a9da89989e3cad5575d1ebca1523f9cefaca6c36b4dae81629f65936b2cdf3af04c789b28cc03d5660062c2a0e56 WHIRLPOOL 8356937c86d67da4084405d2a1565165da07a467f979c324d72dc4630f3abb7b1f2f906d700592a730a94a19fa12346014788863fa2f7041b5a015300349e16d
+DIST flask-cors-2.1.0.tar.gz 28038 SHA256 749fc78f18f677317cb44d8ee3fdd3a5914ec1c5f5340d10e2ac020d405c7ed1 SHA512 235162749485588e9112a52a833a43e68ad1737997628dc51cc30358d01837f427ba33872ecb1fff8e821b84c3de0a15a1c89c57f2407ef0cacafae9ca354640 WHIRLPOOL d71d1ea44954a6a691b1442a176d58413c4b99674e0e055af991b370fd39c0f5cb9ddffec7add635db8fcdbc93b6b0b7395e861b487863f458c7741d52215d0f

diff --git a/dev-python/flask-cors/flask-cors-2.1.0.ebuild b/dev-python/flask-cors/flask-cors-2.1.0.ebuild
new file mode 100644
index 0000000..23f893b
--- /dev/null
+++ b/dev-python/flask-cors/flask-cors-2.1.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Cors"
+MY_P="${MY_PN}-${PV}"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
+HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		${RDEPEND}
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/python-docs-2.7.6-r1:2.7
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	if use doc; then
+		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
+		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
+		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
+		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
+		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}