From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-831468-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
by finch.gentoo.org (Postfix) with ESMTP id A2DDC1384C0
for <garchives@archives.gentoo.org>; Mon, 31 Aug 2015 07:46:32 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B549F141FC;
Mon, 31 Aug 2015 07:46:30 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 222C7141FC
for <gentoo-commits@lists.gentoo.org>; Mon, 31 Aug 2015 07:46:30 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 22AE5340634
for <gentoo-commits@lists.gentoo.org>; Mon, 31 Aug 2015 07:46:29 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id A3BF7156
for <gentoo-commits@lists.gentoo.org>; Mon, 31 Aug 2015 07:46:26 +0000 (UTC)
From: "Yixun Lan" <dlan@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Yixun Lan" <dlan@gentoo.org>
Message-ID: <1441035357.d9f0d11f796cb6187bb3950d9127173ec99d4264.dlan@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-i18n/ibus/Manifest app-i18n/ibus/ibus-1.5.11.ebuild
X-VCS-Directories: app-i18n/ibus/
X-VCS-Committer: dlan
X-VCS-Committer-Name: Yixun Lan
X-VCS-Revision: d9f0d11f796cb6187bb3950d9127173ec99d4264
X-VCS-Branch: master
Date: Mon, 31 Aug 2015 07:46:26 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 1126ec7e-3b8b-44e1-82e3-4ee919b150e9
X-Archives-Hash: 7f3e314508892bd749dedd8b06c31f79
commit: d9f0d11f796cb6187bb3950d9127173ec99d4264
Author: Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 31 15:31:16 2015 +0000
Commit: Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Mon Aug 31 15:35:57 2015 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9f0d11f
app-i18n/ibus: version bump 1.5.11
Package-Manager: portage-2.2.20.1
app-i18n/ibus/Manifest | 1 +
app-i18n/ibus/ibus-1.5.11.ebuild | 191 +++++++++++++++++++++++++++++++++++++++
2 files changed, 192 insertions(+)
diff --git a/app-i18n/ibus/Manifest b/app-i18n/ibus/Manifest
index a8adb10..2b448d9 100644
--- a/app-i18n/ibus/Manifest
+++ b/app-i18n/ibus/Manifest
@@ -1,4 +1,5 @@
DIST ibus-1.5.10.tar.gz 2169299 SHA256 1d01b7806602875a1f3004f32e1000a39be01f59731d6baf36446498e26f5594 SHA512 2f7f07c20cac5f934f24c3bc99b29efe30aa5ced501ac442a9da16454cb889d946fa262b3495c1778f200c8f62a1fd8d67f47f43ae6ee214d3d392feb6e413c9 WHIRLPOOL 575d5bba84ed8afb608030260b5fbbd47bdfc4ff1368590e0c34b2fed1cf2878e71bdb7b6da286d0b0d5a27f7fcc9e2a02675a86bbc9417c1d060246b7a6acbd
+DIST ibus-1.5.11.tar.gz 2177026 SHA256 49995a298a39a137e65c6ee77811b030850ff344b875f29d4ed088f623a546bc SHA512 7745a06a4dc9502a957bdfa7faba3e6ff857ee102f34acfbc5d1c8ca5935eaf5660ebe6d837ee7bae584818c08a1769cf8a9daa012f87d43a1f10917c04615c2 WHIRLPOOL ae724b6609323e22f6fdff767484ec1259a6e3e4465b1a539cdfaa9178920d23d062d4eb6627fd3b45416d7fa9170a5bf467d6cddd4b1e80ae568a31e851be24
DIST ibus-1.5.5.tar.gz 2063794 SHA256 02ab36af6048399fedbe8d85074b161219b89df5020932df33cf8829764f8aec SHA512 8249d6ee4918b0e0fe030af736eed2260e1376b2fdaf0d819f289e0bd880a5e3874f1fb3d097fc74b9f359822ce16f4dae52a263aa28c2e2ce7bdf671cb2fea9 WHIRLPOOL 33ba90e5cdd54ecd7a03af8c5d2c1d2e8cfc88bfc53b65e5240eb4c60d6138007b754a60e8b1e79c98ce92e299d14f1a0cce445ad40b04e862adf3919401d77d
DIST ibus-1.5.8.tar.gz 2120220 SHA256 cfc562ae73de753dc8cb9ae30fe117286ddd94cd109002108f2eeb47e8101a29 SHA512 428e40be7ebea57832295e76b5c4350351c6d40c5178c57c61c8d6f31e524a315184c3d533ad88592e53ae7c6cb4beed67796ad61910f99f260fc9c243b2fc98 WHIRLPOOL 2fc0059a75b3f4b253770303a8c9c8ae02947153eaf7b9c220e2e10657275293a556b068ba4cad0d27f315b7374ffaedb53b20cd13f8408a3729cfaaea869d78
DIST ibus-1.5.9-upstream-patches-0.tar.xz 30380 SHA256 9efe631008cfad1d59db01a83ae093149b2c827d480705836f0bf8a29706f1e0 SHA512 98c323de9793938d8c0bd646071d0ea7860212e3ae826e97ed0e0a092ec715084529b3a3cee3def63958dd3d56357b2e33e4e3d3946cca90bec3409469cf14d4 WHIRLPOOL 0aaf7aaba36de96525f0339a16df2c435e2f2c5cc6168c9b2da25bd7003af88f6d55ca53ae692c9c611b563ddfcb48a0e19e915f8361ba51a4aac813edc45f41
diff --git a/app-i18n/ibus/ibus-1.5.11.ebuild b/app-i18n/ibus/ibus-1.5.11.ebuild
new file mode 100644
index 0000000..e349271
--- /dev/null
+++ b/app-i18n/ibus/ibus-1.5.11.ebuild
@@ -0,0 +1,191 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+VALA_MIN_API_VERSION="0.20"
+VALA_USE_DEPEND="vapigen"
+# Vapigen is needed for the vala binding
+# Valac is needed when building from git for the engine
+UPSTREAM_VER=
+
+inherit autotools bash-completion-r1 eutils gnome2-utils multilib python-single-r1 readme.gentoo vala virtualx
+
+DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
+HOMEPAGE="http://code.google.com/p/ibus/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="deprecated gconf gtk +gtk3 +introspection nls +python test vala wayland +X"
+REQUIRED_USE="
+ || ( gtk gtk3 X )
+ deprecated? ( python )
+ vala? ( introspection )
+ python? (
+ ${PYTHON_REQUIRED_USE}
+ || ( deprecated ( gtk3 introspection ) ) )" #342903
+
+[[ -n ${UPSTREAM_VER} ]] && \
+ UPSTRAM_PATCHSET_URI="http://dev.gentoo.org/~dlan/distfiles/${P}-upstream-patches-${UPSTREAM_VER}.tar.xz"
+
+SRC_URI="https://github.com/ibus/ibus/releases/download/${PV}/${P}.tar.gz
+ ${UPSTRAM_PATCHSET_URI}"
+
+COMMON_DEPEND="
+ >=dev-libs/glib-2.26:2
+ gnome-base/librsvg:2
+ sys-apps/dbus[X?]
+ app-text/iso-codes
+ >=gnome-base/dconf-0.13.4
+ x11-libs/libnotify
+ gconf? ( >=gnome-base/gconf-2.12:2 )
+ gtk? ( x11-libs/gtk+:2 )
+ gtk3? ( x11-libs/gtk+:3 )
+ python? ( ${PYTHON_DEPS} )
+ X? (
+ x11-libs/libX11
+ x11-libs/gtk+:2 )
+ introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
+ nls? ( virtual/libintl )
+ wayland? ( dev-libs/wayland )"
+RDEPEND="${COMMON_DEPEND}
+ x11-apps/setxkbmap
+ python? (
+ dev-python/pyxdg
+ deprecated? (
+ >=dev-python/dbus-python-0.83
+ dev-python/pygobject:2
+ dev-python/pygtk:2 )
+ gtk3? (
+ dev-python/pygobject:3
+ x11-libs/gdk-pixbuf:2[introspection]
+ x11-libs/pango[introspection]
+ x11-libs/gtk+:3[introspection] )
+ )"
+DEPEND="${COMMON_DEPEND}
+ >=dev-lang/perl-5.8.1
+ dev-util/gtk-doc-am
+ dev-util/intltool
+ virtual/pkgconfig
+ nls? ( >=sys-devel/gettext-0.16.1 )
+ vala? ( $(vala_depend) )"
+
+# stress test in bus/ fails
+# IBUS-CRITICAL **: bus_test_client_init: assertion `ibus_bus_is_connected (_bus)' failed
+RESTRICT="test"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="To use ibus, you should:
+1. Get input engines from sunrise overlay.
+Run \"emerge -s ibus-\" in your favorite terminal
+for a list of packages we already have.
+
+2. Setup ibus:
+$ ibus-setup
+
+3. Set the following in your user startup scripts
+such as .xinitrc, .xsession or .xprofile:
+
+export XMODIFIERS=\"@im=ibus\"
+export GTK_IM_MODULE=\"ibus\"
+export QT_IM_MODULE=\"xim\"
+ibus-daemon -d -x
+"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ # Upstream's patchset
+ if [[ -n ${UPSTREAM_VER} ]]; then
+ EPATCH_SUFFIX="patch" \
+ EPATCH_FORCE="yes" \
+ EPATCH_OPTS="-p1" \
+ epatch "${WORKDIR}"/patches-upstream
+ fi
+
+ # We run "dconf update" in pkg_postinst/postrm to avoid sandbox violations
+ sed -e 's/dconf update/:/' \
+ -i data/dconf/Makefile.{am,in} || die
+ use vala && vala_src_prepare
+
+ eautoreconf
+}
+
+src_configure() {
+ local python_conf
+ if use python; then
+ python_conf="PYTHON=${PYTHON}
+ $(use_enable deprecated python-library)
+ $(use_enable gtk3 setup)"
+ else
+ python_conf="--disable-python-library --disable-setup"
+ fi
+ econf \
+ --enable-dconf \
+ $(use_enable introspection) \
+ $(use_enable gconf) \
+ $(use_enable gtk gtk2) \
+ $(use_enable gtk xim) \
+ $(use_enable gtk3) \
+ $(use_enable gtk3 ui) \
+ $(use_enable nls) \
+ $(use_enable test tests) \
+ $(use_enable X xim) \
+ $(use_enable vala) \
+ $(use_enable wayland) \
+ ${python_conf}
+}
+
+src_test() {
+ unset DBUS_SESSION_BUS_ADDRESS
+ Xemake check || die
+}
+
+src_install() {
+ default
+
+ prune_libtool_files --all
+
+ mv "${ED}"/usr/share/bash-completion/completions/ibus.bash "${T}"
+ rm -rf "${ED}"/usr/share/bash-completion || die
+ newbashcomp "${T}"/ibus.bash ${PN}
+ insinto /etc/X11/xinit/xinput.d
+ newins xinput-ibus ibus.conf
+
+ keepdir /usr/share/ibus/{engine,icons} #289547
+
+ use deprecated && python_optimize
+ use python && use gtk3 && python_optimize
+
+ readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+ use gconf && gnome2_gconf_savelist
+ gnome2_schemas_savelist
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ use gconf && gnome2_gconf_install
+ use gtk && gnome2_query_immodules_gtk2
+ use gtk3 && gnome2_query_immodules_gtk3
+ gnome2_schemas_update
+ gnome2_icon_cache_update
+ readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+ use gtk && gnome2_query_immodules_gtk2
+ use gtk3 && gnome2_query_immodules_gtk3
+ use gconf && gnome2_schemas_update
+ gnome2_schemas_savelist
+ gnome2_icon_cache_update
+}