[gentoo-commits] proj/gnome:master commit in: dev-libs/atk/

["Ole Reifschneider" <tranquility@gentoo.org>]

commit:     1d74d14320fa98334f05a5ffc9a69407f2b9185d
Author:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 16 18:59:22 2015 +0000
Commit:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
CommitDate: Sat Apr 18 08:49:23 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=1d74d143

Add dev-libs/atk-2.16.0

Package-Manager: portage-2.2.14
Manifest-Sign-Key: 7E8B4D42

 dev-libs/atk/atk-2.16.0.ebuild | 56 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-libs/atk/atk-2.16.0.ebuild b/dev-libs/atk/atk-2.16.0.ebuild
new file mode 100644
index 0000000..c7c225e
--- /dev/null
+++ b/dev-libs/atk/atk-2.16.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/atk/atk-2.14.0.ebuild,v 1.7 2015/03/29 10:29:55 jer Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 multilib-minimal
+
+DESCRIPTION="GTK+ & GNOME Accessibility Toolkit"
+HOMEPAGE="http://projects.gnome.org/accessibility/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="+introspection nls test"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-gtklibs-20140508
+		!app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	dev-util/gtk-doc-am
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	nls? ( sys-devel/gettext )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	if ! use test; then
+		# don't waste time building tests (bug #226353)
+		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+			|| die "sed failed"
+	fi
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		$(multilib_native_use_enable introspection)
+
+	# work-around gtk-doc out-of-source brokedness
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/html docs/html || die
+	fi
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}