[gentoo-commits] proj/gnome:master commit in: net-misc/rygel/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     dd5fb0898bffbe6419e16bc6debc63c99ef9763f
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 12 23:02:57 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sat Oct 12 23:39:10 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=dd5fb089

net-misc/rygel: 0.18.4 → 0.20.0

---
 net-misc/rygel/metadata.xml        |  9 ++++
 net-misc/rygel/rygel-0.20.0.ebuild | 88 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/net-misc/rygel/metadata.xml b/net-misc/rygel/metadata.xml
new file mode 100644
index 0000000..49d6804
--- /dev/null
+++ b/net-misc/rygel/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+  <use>
+    <flag name="tracker">Install dependencies for the tracker plugin</flag>
+    <flag name="transcode">Install dependencies for transcoding support</flag>
+  </use>
+</pkgmetadata>

diff --git a/net-misc/rygel/rygel-0.20.0.ebuild b/net-misc/rygel/rygel-0.20.0.ebuild
new file mode 100644
index 0000000..8c39ad2
--- /dev/null
+++ b/net-misc/rygel/rygel-0.20.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.18.4.ebuild,v 1.2 2013/09/08 17:19:38 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="http://live.gnome.org/Rygel"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X nls +sqlite tracker test transcode"
+
+# The deps for tracker? and transcode? are just the earliest available
+# version at the time of writing this ebuild
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	media-plugins/gst-plugins-soup:1.0
+	>=net-libs/gssdp-0.13
+	>=net-libs/gupnp-0.19
+	>=net-libs/gupnp-av-0.11.4
+	>=net-libs/libsoup-2.34:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring
+	)
+	tracker? ( >=app-misc/tracker-0.16:= )
+	transcode? (
+		media-libs/gst-plugins-bad:1.0
+		media-plugins/gst-plugins-twolame:1.0
+		media-plugins/gst-plugins-libav:1.0
+	)
+	X? ( >=x11-libs/gtk+-3:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Maintainer only
+#	>=dev-lang/vala-0.20
+#   dev-libs/libxslt
+
+src_prepare() {
+	# runs gst-plugins-scanner on run with triggers sandbox violation
+	# trying to open dri
+	sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
+		-e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
+		-i tests/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# We defined xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--disable-valadoc \
+		--enable-gst-launch-plugin \
+		--enable-mediathek-plugin \
+		--with-media-engine=gstreamer \
+		$(use_enable nls) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}
+
+src_install() {
+	gnome2_src_install
+	# Autostart file is not placed correctly, bug #402745
+	insinto /etc/xdg/autostart
+	doins "${D}"/usr/share/applications/rygel.desktop
+	rm "${D}"/usr/share/applications/rygel.desktop
+}