[gentoo-commits] proj/gnome:master commit in: app-misc/gnote/

["Priit Laes" <plaes@plaes.org>]

commit:     20b9dde6892ef99346c6bd19ff0184f3b961a83a
Author:     Priit Laes <plaes <AT> plaes <DOT> org>
AuthorDate: Sat Aug 24 14:11:22 2013 +0000
Commit:     Priit Laes <plaes <AT> plaes <DOT> org>
CommitDate: Sat Aug 24 14:11:22 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=20b9dde6

app-misc/gnote: Add 3.9.2 to overlay

---
 app-misc/gnote/gnote-3.9.2.ebuild | 85 +++++++++++++++++++++++++++++++++++++++
 app-misc/gnote/gnote-9999.ebuild  | 63 ++++++++++++++++++++---------
 2 files changed, 128 insertions(+), 20 deletions(-)

diff --git a/app-misc/gnote/gnote-3.9.2.ebuild b/app-misc/gnote/gnote-3.9.2.ebuild
new file mode 100644
index 0000000..a2abc5a
--- /dev/null
+++ b/app-misc/gnote/gnote-3.9.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 readme.gentoo
+if [[ ${PV} = 9999 ]]; then
+	inherit gnome2-live
+fi
+
+DESCRIPTION="Desktop note-taking application"
+HOMEPAGE="http://live.gnome.org/Gnote"
+
+LICENSE="GPL-3+ FDL-1.1"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64 ~x86"
+fi
+IUSE="debug X"
+
+# Automagic glib-2.32 dep
+COMMON_DEPEND="
+	>=app-crypt/libsecret-0.8
+	>=app-text/gtkspell-3.0:3
+	>=dev-cpp/glibmm-2.32:2
+	>=dev-cpp/gtkmm-3.6:3.0
+	>=dev-libs/boost-1.34
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libxml2-2:2
+	dev-libs/libxslt
+	>=sys-apps/util-linux-2.16:=
+	>=x11-libs/gtk+-3.6:3
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+DEPEND="${DEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.35.0
+	virtual/pkgconfig
+"
+if [[ ${PV} = 9999 ]]; then
+	DEPEND="${DEPEND}
+		app-text/yelp-tools"
+fi
+
+src_prepare() {
+	# Do not alter CFLAGS
+	sed 's/-DDEBUG -g/-DDEBUG/' -i configure.ac configure || die
+	gnome2_src_prepare
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_configure() {
+	[[ ${PV} != 9999 ]] && G2CONF="ITSTOOL=$(type -P true)"
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_with X x11-support) \
+		$G2CONF
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}

diff --git a/app-misc/gnote/gnote-9999.ebuild b/app-misc/gnote/gnote-9999.ebuild
index c6a2a46..a2abc5a 100644
--- a/app-misc/gnote/gnote-9999.ebuild
+++ b/app-misc/gnote/gnote-9999.ebuild
@@ -1,12 +1,11 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
-EAPI="4"
+EAPI="5"
 GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
 
-inherit gnome2
+inherit gnome2 readme.gentoo
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
@@ -14,32 +13,35 @@ fi
 DESCRIPTION="Desktop note-taking application"
 HOMEPAGE="http://live.gnome.org/Gnote"
 
-LICENSE="GPL-3+"
+LICENSE="GPL-3+ FDL-1.1"
 SLOT="0"
 if [[ ${PV} = 9999 ]]; then
 	KEYWORDS=""
 else
 	KEYWORDS="~amd64 ~x86"
 fi
-IUSE="debug"
+IUSE="debug X"
 
 # Automagic glib-2.32 dep
 COMMON_DEPEND="
 	>=app-crypt/libsecret-0.8
-	>=dev-cpp/glibmm-2.28:2
-	>=dev-cpp/gtkmm-3.4:3.0
+	>=app-text/gtkspell-3.0:3
+	>=dev-cpp/glibmm-2.32:2
+	>=dev-cpp/gtkmm-3.6:3.0
 	>=dev-libs/boost-1.34
-	>=dev-libs/glib-2.32
+	>=dev-libs/glib-2.32:2
 	>=dev-libs/libxml2-2:2
 	dev-libs/libxslt
-	>=sys-apps/util-linux-2.16
-	>=x11-libs/gtk+-3:3
-	x11-libs/libX11
+	>=sys-apps/util-linux-2.16:=
+	>=x11-libs/gtk+-3.6:3
+	X? ( x11-libs/libX11 )
 "
 RDEPEND="${COMMON_DEPEND}
-	gnome-base/gsettings-desktop-schemas"
+	gnome-base/gsettings-desktop-schemas
+"
 DEPEND="${DEPEND}
 	app-text/docbook-xml-dtd:4.1.2
+	dev-util/desktop-file-utils
 	>=dev-util/intltool-0.35.0
 	virtual/pkgconfig
 "
@@ -49,14 +51,35 @@ if [[ ${PV} = 9999 ]]; then
 fi
 
 src_prepare() {
-	DOCS="AUTHORS ChangeLog NEWS README TODO"
-	G2CONF="${G2CONF}
-		--disable-static
-		$(use_enable debug)"
-	[[ ${PV} != 9999 ]] && G2CONF="${G2CONF} ITSTOOL=$(type -P true)"
-
 	# Do not alter CFLAGS
 	sed 's/-DDEBUG -g/-DDEBUG/' -i configure.ac configure || die
-
 	gnome2_src_prepare
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_configure() {
+	[[ ${PV} != 9999 ]] && G2CONF="ITSTOOL=$(type -P true)"
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_with X x11-support) \
+		$G2CONF
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
 }